[wolkow70]

kotkovets,

Пришлось некоторым образом изменить функцию, но вроде все работает...

Код:

UninstPage custom un.INSTFILES_LEAVE
;
Section Uninstall  Uninstall
SectionIn 1 RO
;
RMDir /r "$INSTDIR"
SetAutoClose true
SectionEnd
;
Section /o "Un.Перезагрузка Проводника Windows"  RestartExplorer
SectionIn 1
ExecWait 'taskkill /F /IM explorer.exe' $0
DetailPrint "taskkill exit: [ $0 ]"
Sleep 500
StrCmp $0 0 0 +2
Exec "explorer.exe"
Delete "$INSTDIR\DefragglerShell.dll"
RMDir /r "$INSTDIR"
SectionEnd
;
Function un.INSTFILES_LEAVE
${If} ${FileExists} "$INSTDIR\DefragglerShell.dll" 
RMDir /r /REBOOTOK "$INSTDIR"
SetRebootFlag true
${Else}
SetRebootFlag false 
${EndIf}
FunctionEnd

То есть, перенес комманду RMDir /r /REBOOTOK "$INSTDIR" из Uninstall в саму функцию un.INSTFILES_LEAVE. Таким образом, если Пользователь не выбрал секцию RestartExplorer, то залоченный файл остается на месте и не прописывается на удаление. Зато, затем он все равно удаляется с перезагрузкой через комманду функции. Получается как бы вариант стандартного удаления.
Но если, пользователь выбрал секцию RestartExplorer, то залоченный файл удаляется без перезагрузки. А флаг REBOOTOK в этом случае не срабатывает, в результате файл не прописывается на удаление после перезагрузки.
Только вот не знаю имеет ли смысл в функции рядом ставить комманды
RMDir /r /REBOOTOK "$INSTDIR"
SetRebootFlag true
Может SetRebootFlag true можно тогда и не использовать?

[kotkovets]

wolkow70, функция un.INSTFILES_LEAVE выполняется ВСЕГДА!
Проверяет наличие файлика DefragglerShell.dll и на основе проверки "решает" показывать стр. перезагрузки сейчас или нет!
И принудительно устанавливает флаги перезагрузки - банальная перестраховка.

Код:

${If} ${FileExists} "$INSTDIR\DefragglerShell.dll" 
      Delete /REBOOTOK "$INSTDIR\DefragglerShell.dll"
      SetRebootFlag true
${Else}
      SetRebootFlag false 
${EndIf}

И еще один момент, если удаление задано с флагом /REBOOTOK, но файлы или файл удалились удачно,
установщик устанавливает флаг перезагрузки - false,
если неудачное удаление(по каким то причинам) установщик устанавливает флаг перезагрузки - true
Это легко проверить инсценировкой ситуации, например создать архив и держать архив открытым программой архиватором, то вы не сможете удалить архив, файл занят:

Код:

  Delete /REBOOTOK "$EXEDIR\Linker.zip"
  Ifrebootflag 0 +2
      MessageBox MB_OK "true" IDOK
  Ifrebootflag +2
     MessageBox MB_OK "false" IDOK

---
А уже на страничке финиша, если true - установщик предложит перезагрузку.
если false - установщик не предложит перезагрузку.
---
И еще важный аспект, если вы ловите в скрипте флаг пререзагрузки, не забудьте снова установить
предыдущий флаг перезагрузки при необходимости, потому что команда Ifrebootflag
определяет состояние флага и после определения сбрасывает в false или в неопределенное состояние.

Код:

  Delete /REBOOTOK "$EXEDIR\Linker.zip"
  Ifrebootflag 0 +3
      MessageBox MB_OK "true" IDOK
      SetRebootFlag true
  Ifrebootflag +3
      MessageBox MB_OK "false" IDOK
      SetRebootFlag false

Что вам нужно, решаете сами, поэтому поводу я вам разжевал все и повторяться не буду.

[wolkow70]

функция un.INSTFILES_LEAVE выполняется ВСЕГДА! »

Это и замечательно! Это и позволило перенести в нее флаг /REBOOTOK.
Проблема заключалась в том, что при наличии флага /REBOOTOK в самой секции инсталляции после удаления программы с применением RestartExplorer файлик прописывался в реестре на удаление. И в с случае переустановки программы (без перезагрузки) удалялся после перезагрузки уже из папки новой установки. Удаление же этого ключа приводило к тому, что при удалении без применения RestartExplorer папка с залоченным файлом оставалась на месте после перезагрузки.
Перенос флага /REBOOTOK в функцию позволил применять RestartExplorer для удаления файла вообще без флага /REBOOTOK (так как при уже при фактическом отсутствии файлика срабатывает второе условие (Else). В результате файл на удаление в реестре не прописывается и можно сразу переустанавливать программу без опасения удаления файлика после перезагрузки.
Вот в чем заключалась проблема, которую пришлось решать.

Delete /REBOOTOK "$INSTDIR\DefragglerShell.dll"
SetRebootFlag true
Перестраховки здесь, на мой взгляд, нет. Так как SetRebootFlag true ставит флаг перезагрузки для финишной страницы, но не прописывает в реестр запись на удаление файла после перезагрузки. Как я понял это делает только флаг /REBOOTOK. поэтому он нужен, но пришлось перенести его в другое место для сохранения возможности двух вариантов деинсталляции.

[wolkow70]

Товарищи, подскажите как вылезти из засады:

Function .onInit
;
MessageBox MB_YESNO|MB_ICONQUESTION "ВНИМАНИЕ!$\n\
$\nЕсли у вас открыты окна браузеров Internet Explorer, Mozilla Firefox, Opera, Chrome закройте их перед продолжением установки. \
$\nВ противном случае, они будут закрыты принудительно! \
$\nЭто избавит от конфликтов интеграции программы. \
$\n$\nПРОДОЛЖИТЬ ?" /SD IDYES IDNO Note
;
KillProcDLL::KillProc "opera.exe"
Sleep 700
KillProcDLL::KillProc "firefox.exe"
Sleep 700
KillProcDLL::KillProc "chrome.exe"
Sleep 700
KillProcDLL::KillProc "IEXPLORE.EXE"
Sleep 700
Note:
Abort # выйти из программы.
FunctionEnd

По любому происходит аборт. Без /SD еще получается перевести стрелки. А с ним фиг. Справка не помогла.

[kotkovets]

А с ним фиг. Справка не помогла »

Хреново Вы ее читаете:

Если в команде не указан ни один из идентификаторов, установщик возвращает их в 0 (по умолчанию). Максимум возможно задать два идентификатора кнопок, не указанный индетификатор кнопки возвратится в 0.

По любому происходит аборт »

А вы всегда на эту команду выйдете однозначно, подумайте почему!?
Такое впечатление, что вы не понимаете, че и пишите то
---
При тихом режиме нажмется кнопка "нет" :

Код:

  IfSilent NOTE
  MessageBox MB_YESNO 'Какую кнопку нажать?' IDNO NOTE
      MessageBox MB_OK 'Вы нажали кнопку "да"'
      Goto END
  NOTE:
      MessageBox MB_OK 'Вы нажали кнопку "нет"'
      Abort
  END:

или так аналогично:

Код:

MessageBox MB_YESNO 'Какую кнопку нажать?' /SD IDNO IDYES YES
    MessageBox MB_OK 'Вы нажали кнопку "нет"'
    Quit
YES:
    MessageBox MB_OK 'Вы нажали кнопку "да"'

Если у вас открыты окна браузеров Internet Explorer, Mozilla Firefox, Opera, Chrome»

Так вы их проверяйте, что они открыты(открыт один из них), а то тупо просто мочится - вообще жесть!
Такой кодинг неприемлем ИМХО
Такое мочилово неприятно грубыми последствиями, достаточно предупреждать юзера, если у вас открыты окна браузеров Internet Explorer, Mozilla Firefox, Opera, Chrome, и все! иначе выход! Юзер сам закроет, что ему нужно и когда!

[wolkow70]

А вы всегда на эту команду выйдете однозначно, подумайте почему!? »

Abort # выйти из программы.
FunctionEnd

Это мне понятно. Мне не понятно как обойти abort в данном случае.

Так вы их проверяйте, что они открыты (открыт один из них), а то тупо просто мочится - вообще жесть! За такой кодинг я бы я**а натянул на одно место Такое мочилово неприятно грубыми последствиями, достаточно предупреждать юзера, если у вас открыты окна браузеров Internet Explorer, Mozilla Firefox, Opera, Chrome, и все! иначе выход! Юзер сам закроет, что ему нужно и когда! »

Юзеры бывают разные, и я не себя имею в виду. Кроме того, речь идет об адаптации под тихую установку, значит принудительное закрытие окон допустимо, если юзер сам их не закрыл.
Никаких грубых последствий такого мочилова я не наблюдал.

[kotkovets]

Кроме того, Вы следите за своей фразеологией, »

Если я столь грубо выразился, то приношу извинения...
выражаюсь вполне чотко и ясно

Юзеры бывают разные »

Это ясно, не нужно думать головой установщика и навязывать это юзеру.

Мне не понятно как обойти abort в данном случае »

последовательность, уважаемый забыли и прыжок,
если не нужно прерывание, примеры выше

[Aster]

Добрый день. Есть вопрос по программе NSIS.
Возникла следующая проблемка с функцией проверки файла.
Только, пожалуйста, не отправляйте меня читать справку, т.к я с ней ознакомился, там действительно есть описание функции проверки файла, но мне это не помогло. И я хотел бы попросить вас, если такое возможно, написать мне чёткий пример кода, который решил бы мою проблему. Заранее благодарю!

А суть вопроса следующая:
Необходимо внедрить в установщик функцию проверки на наличие конкретного файла (а лучше двух или нескольких конкретных файлов) в той папке, которую пользователь указал в окне "выбор папки для установки". Т.е пользователь выбирает папку, заметьте именно ВЫБИРАЕТ папку, т.е инсталлятор должен ему позволить выбрать папку и нажать ОК. Итак папка выбрана. Теперь пользователь нажимает кнопку "Далее" (заметьте кнопка "Далее" должна быть АКТИВНА в любом случае (ранее у меня почему-то получалось так, что если в выбранной папке нет файла, то кнопка "Далее" неактивна, т.е нажать её нельзя). И вот именно в этом месте, после того как пользователь выбрал папку и нажал кнопку "Далее" и должна срабатывать функция проверки файлов. Если файлы в указанной папке найдены, то установка продолжится и перейдёт на след.страницу инсталлера, если же файлов в папке не обнаружено, то необходимо чтобы появлялось уведомляющее окно с сообщением вида "В указанном Вами каталоге отстуствуют компоненты игры YYY. Пожалуйста, укажите правильный каталог". Уведомление должно быть только с кнопкой ОK, после нажатия которой пользователь мог бы изменить каталог для установки и вновь нажать "Далее". Такая проверка мне нужна для того, чтобы пользователь не смог распаковать мой дистрибутив ни в какой другой каталог, кроме как в каталог с игрой YYY.

Это ещё не всё, так как помимо указанной проверки, мне ещё нужна другая проверка - проверка на какую версию игры пользователь собирается установить мой дистрибутив. Необходимо чтобы проверка выявляла наличие у пользователя чистой (неперепатченной) версии игры, т.е чтобы пользователь мог установить мой дистрибутив только на чистую версию игры. Принцип должен быть такой. Необходимо, чтобы проверка срабатывала в тот же момент, что и предыдущая, т.е после выбора папки для установки и нажатия кнопки "Далее". Принцип: проверка должна выявить наличие в выбранной папке конкретных файлов (других файлов, никак не связанных с предыдущей проверкой) и если файлы обнаружены - должно всплывать уведомление вида "Компоненты игры YYY были ранее изменены. Установка приложение возможна только поверх оригинального дистрибутива. Пожалуйста, переустановите игру".

И последнее, наверное, самое простое.
Необходимо, чтобы при запуске инсталлятора, совершалась ориентация на ключ реестра.
Т.е если ключ реестра обнаружен - инсталлятор запускается. Если нет - появлялось бы всплывающее окно с кнопками ДА и НЕТ, вида: "На вашем компьютере не обнаружено установленной игры YYY. Убедитесь, что устанавливали дистрибутив игры. Продолжить установку?" Суть: инсталлятор выявляет есть ли у пользователя вообще установленная игра. Однако, ключ реесстра может и отсуствовать, если юзер качал игру с винта на винт, поэтому даже если ключ не обнаружен, должна быть возможность продолжить установку.

Надеюсь на Вашу помощь, ребят. Уважаю ваш труд, справка по NSIS действительно внушительная и виден громадный объём проделанной работы.
Что касается моих вопросов, на мой взгляд вопросы про этим проверкам также могли бы быть наиболее подробно описаны в вашей справке. Думаю, это было бы интересно.

Благодарю за внимание.
С уважением, Aster.

[kotkovets]

Уважаю ваш труд, справка по NSIS действительно внушительная и виден громадный объём проделанной работы »

Спасибо на добром слове.

Такая проверка мне нужна для того, чтобы пользователь не смог распаковать мой дистрибутив ни в какой другой каталог, кроме как в каталог с игрой YYY. »

В таком случае страничка выбора директории неуместна.
на примере 7-zip девятой версии

читать дальше »

Код:

!include "MUI2.nsh"
!include "FileFunc.nsh"

InstallDirRegKey HKCU "Software\7-Zip" "Path" ;берем путь из реестра, в противном случае ниже код.
InstallDir "$PROGRAMFILES\7-zip"

!insertmacro MUI_PAGE_WELCOME
  !define MUI_PAGE_CUSTOMFUNCTION_LEAVE LEAVE_COMPONENTS ;функция будет выполнена при закрытии странички компонентов
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE English

Name "Test"
OutFile "Test.exe"
ShowInstDetails show

Function LEAVE_COMPONENTS
  ${IfNot} ${FileExists} "$INSTDIR\7z.exe"
  ${OrIfNot} ${FileExists} "$INSTDIR\7z.dll" ;логика ИЛИ-НЕ ;при необходимости пишем еще раз на указанный ваш файл
      MessageBox MB_OK "Не найден один из файлов!" IDOK
      Abort ;прерывание
  ${Else} 
     ;Здесь можно писать код проверки версии файлов и изменения файлов
     ${GetFileVersion} "$INSTDIR\7z.exe" $0 ; выявляем версию файла
     StrCpy $0 $0 1 ;берем из версии первую циферку(один первый символ)
     ;сравниваем версию
     ${If} $0 != 9
        MessageBox MB_OK "Это не 9 версия файла 7z" IDOK
        Abort
     ${EndIf}
     ;сравниваем пропатченный файл или нет плагом MD5
     ;;
     ;;

  ${EndIf}
FunctionEnd

Section MAIN
SectionEnd
Section MAIN_1
SectionEnd

Принцип: проверка должна выявить наличие в выбранной папке конкретных файлов (других файлов, никак не связанных с предыдущей проверкой) и если файлы обнаружены - должно всплывать уведомление вида "Компоненты игры YYY были ранее изменены »

На офф. сайте найдите плагин MD5 и сверьте хэш-сумму оригинала, если не сходится прерывание.

[wolkow70]

последовательность, уважаемый забыли и прыжок, если не нужно прерывание, примеры выше »

Оба ваших примера в моем случае не работают, точнее говоря работают при обычной установке. но при тихой не работают. Потому как, мне в тихом режиме нужно нажать кнопку "да", а не "нет, что реализуют приведенные вами примеры. А это и не удается сделать, так как в этом случае abort не перепрыгнуть.