[sawe]

вот код 105 диалога из ресхака »

читать дальше »

Код:

105 DIALOGEX 0, 0, 440, 285
STYLE DS_FIXEDSYS | DS_CENTER | WS_MINIMIZEBOX | WS_POPUP | WS_CAPTION | WS_SYSMENU
CAPTION ""
LANGUAGE LANG_ENGLISH, SUBLANG_ENGLISH_US
FONT 8, "MS Shell Dlg"
{
   CONTROL "", 1099, STATIC, SS_LEFT | WS_CHILD | WS_GROUP, 0, 0, 440, 253 
   CONTROL "", 1055, STATIC, SS_LEFT | WS_CHILD | WS_VISIBLE, 0, 253, 440, 32 
   CONTROL "", 1018, STATIC, SS_LEFT | WS_CHILD, 0, 0, 440, 252 
   CONTROL "", 1044, STATIC, SS_LEFT | WS_CHILD, 0, 0, 440, 252 
   CONTROL "", 1256, STATIC, SS_LEFT | WS_CHILD | WS_VISIBLE | WS_GROUP, 8, 260, 96, 15 
   CONTROL "", 1028, STATIC, SS_LEFT | WS_CHILD | WS_VISIBLE | WS_GROUP, 8, 260, 97, 15 
   CONTROL "", 3, BUTTON, BS_PUSHBUTTON | WS_CHILD | WS_VISIBLE | WS_GROUP | WS_TABSTOP, 281, 258, 67, 18 
   CONTROL "", 1, BUTTON, BS_PUSHBUTTON | WS_CHILD | WS_VISIBLE | WS_TABSTOP, 362, 258, 67, 18 
   CONTROL "", 2, BUTTON, BS_PUSHBUTTON | WS_CHILD | WS_VISIBLE | WS_GROUP | WS_TABSTOP, 116, 258, 67, 18 
}

Вместо 1018 или 1044, которые могут Вам ещё пригодится, использовал 1099, контрол 1055 используйте для подложки цвета в тон вашего основного.
Также рекомендую использовать плагин SkinnedControls

[MKN]

kotkovets,
Всё-таки никак не решён вопрос - как произвести все необходимые действия на одной единственной кастомной странице ?
И выбор чекбоксов и выполнение задачи с индикацией прогресса. Не создавая более никаких других страниц !

[kotkovets]

MKN, а в чем проблема? рисуем страничку со всем необходимым, обрабатываем события, снимаем статусы чекбоксов или радиобутонов, назначаем событию функцию и в этой же назначенной функции изменяем позиции бара
и делаем все необходимые действия, оставаясь на этой же странице.

Код:

Function Install
  ${NSD_GetState} $CheckBox1 $Check1 ;снимаем статус чекбокса
  ${NSD_GetState} $RadioButton1 $rButton1 ;снимаем статус радиобатона
  ;;;
  ${If} $Check1 == 1 ;к примеру если отмечен чебокс_1
      ;пишем нужные команды, если отмечен чекбокс_1
  ${EndIf}
  ;;;
  ${If} $rButton1 == 1 ;к примеру если отмечен чебокс_1
      ;пишем нужные команды, если отмечен радиобатон_1
  ${EndIf}
   ;;
   ;;
FunctionEnd

Я уже привел кучу примеров и разложил все по полочкам, чет тут сложного, банальные действия.
А чтобы не морочиться прогрессом, используем стандартную страничку установки

читать дальше »

Код:

!include "MUI2.nsh"

Page Custom pre post
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE Russian
OutFile "test.exe"
ShowInstDetails show

var dialog
var RadioButton1
var RadioButton2
var RadioButton3
var RadioButton4

var CheckBox1
var CheckBox2
var CheckBox3
var CheckBox4

var Check1
var Check2
var Check3
var Check4

var rButton1
var rButton2
var rButton3
var rButton4

var Button
var Button1

Function pre
   nsDialogs::Create 1018
   Pop $dialog
	${NSD_CreateRadioButton} 0 0 40% 6% "Группа_1, Радио_1"
		Pop $RadioButton1
	${NSD_SetState} $RadioButton1 1 ;Группа_1, радио_1 при показе странички, делаем отмеченным
	${NSD_CreateRadioButton} 0 12% 40% 6% "Группа_1, Радио_2"
		Pop $RadioButton2
		${NSD_AddStyle} $RadioButton1 ${WS_GROUP} ;определяем группу переключений 1
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	${NSD_CreateRadioButton} 50% 0 40% 6% "Группа_2, Радио_1"
		Pop $RadioButton3
	${NSD_SetState} $RadioButton3 1 ;Группа_2, радио_1 при показе странички, делаем отмеченным
	${NSD_CreateRadioButton} 50% 12% 40% 6% "Группа_2, Радио_2"
		Pop $RadioButton4
		${NSD_AddStyle} $RadioButton3 ${WS_GROUP} ;определяем группу переключений 2
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	${NSD_CreateButton} 0u 35u 138u 15u `Кнопка переключений радиобутонов`
	        Pop $Button
        ${NSD_OnClick} $Button ButtonClick
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ${NSD_CreateCheckBox} 0 65u 56u 12u "Чебокс_1"
               Pop $CheckBox1
        ${NSD_CreateCheckBox} 0 85u 56u 12u "Чебокс_2"
               Pop $CheckBox2
        ${NSD_CreateCheckBox} 150u 65u 56u 12u "Чебокс_3"
               Pop $CheckBox3
        ${NSD_CreateCheckBox} 150u 85u 56u 12u "Чебокс_4"
               Pop $CheckBox4
          ;все чебоксы отмечены
        ${NSD_SetState} $CheckBox1 1
        ${NSD_SetState} $CheckBox2 1
        ${NSD_SetState} $CheckBox3 1
        ${NSD_SetState} $CheckBox4 1
	${NSD_CreateButton} 0u 100u 138u 15u `Кнопка переключений чекбоксов`
	      Pop $Button1
        ${NSD_OnClick} $Button1 ButtonClickCheckBox
    nsDialogs::Show
FunctionEnd

Function ButtonClick ;функция обработки события нажатия кнопки
  Pop $Button
  ${NSD_GetState} $RadioButton1 $rButton1
  ${NSD_GetState} $RadioButton2 $rButton2
  ${NSD_GetState} $RadioButton3 $rButton3
  ${NSD_GetState} $RadioButton4 $rButton4
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ;Логика И-ИЛИ для группы 1
  ${If} $rButton1 == 1
  ${AndIf} $rButton2 == 0
      ${NSD_SetState} $RadioButton1 0
      ${NSD_SetState} $RadioButton2 1
  ${Else}
      ${NSD_SetState} $RadioButton1 1
      ${NSD_SetState} $RadioButton2 0
  ${EndIf}
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ;Логика И-ИЛИ для группы 2
  ${If} $rButton3 == 1
  ${AndIf} $rButton4 == 0
      ${NSD_SetState} $RadioButton3 0
      ${NSD_SetState} $RadioButton4 1
  ${Else}
      ${NSD_SetState} $RadioButton3 1
      ${NSD_SetState} $RadioButton4 0
  ${EndIf}
FunctionEnd

Function ButtonClickCheckBox
   Pop $Button1
   ;снимаем статусы чекбоксов:
   ${NSD_GetState} $CheckBox1 $Check1
   ${NSD_GetState} $CheckBox2 $Check2
   ${NSD_GetState} $CheckBox3 $Check3
   ${NSD_GetState} $CheckBox4 $Check4
   ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   ;Логика ИЛИ-ИЛИ для чекбоксов
   ${If} $Check1 == 1
   ${Orif} $Check2 == 1
   ${Orif} $Check3 == 1
   ${Orif} $Check4 == 1
        ${NSD_SetState} $CheckBox1 0
        ${NSD_SetState} $CheckBox2 0
        ${NSD_SetState} $CheckBox3 0
        ${NSD_SetState} $CheckBox4 0
   ${Else}
        ${NSD_SetState} $CheckBox1 1
        ${NSD_SetState} $CheckBox2 1
        ${NSD_SetState} $CheckBox3 1
        ${NSD_SetState} $CheckBox4 1
   ${EndIf}
FunctionEnd

Function post
  ;снимаем статусы радибутонов:
  ${NSD_GetState} $RadioButton1 $rButton1
  ${NSD_GetState} $RadioButton2 $rButton2
  ${NSD_GetState} $RadioButton3 $rButton3
  ${NSD_GetState} $RadioButton4 $rButton4
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
     ;снимаем статусы чекбоксов:
   ${NSD_GetState} $CheckBox1 $Check1
   ${NSD_GetState} $CheckBox2 $Check2
   ${NSD_GetState} $CheckBox3 $Check3
   ${NSD_GetState} $CheckBox4 $Check4
FunctionEnd

Section ""
   ${If} $Check1 == 1
       MessageBox MB_ICONINFORMATION|MB_OK "Отмечен чекбокс_1" IDOK
   ${EndIf}
   ;;;
   ${If} $Check2 == 1
       MessageBox MB_ICONINFORMATION|MB_OK "Отмечен чекбокс_2" IDOK
   ${EndIf}
   ;;;
   ${If} $Check3 == 1
       MessageBox MB_ICONINFORMATION|MB_OK "Отмечен чекбокс_3" IDOK
   ${EndIf}
   
   ;;;
   ${If} $Check4 == 1
        MessageBox MB_ICONINFORMATION|MB_OK "Отмечен чекбокс_4" IDOK
   ${EndIf}
   
   ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   
   ${If} $rButton1 == 1
        MessageBox MB_ICONINFORMATION|MB_OK "Отмечен радибутон_1" IDOK
   ${EndIf}
   ;;;
   ${If} $rButton2 == 1
        MessageBox MB_ICONINFORMATION|MB_OK "Отмечен радибутон_2" IDOK
   ${EndIf}
   ;;;
   ${If} $rButton3 == 1
       MessageBox MB_ICONINFORMATION|MB_OK "Отмечен радибутон_3" IDOK
   ${EndIf}

   ;;;
   ${If} $rButton4 == 1
       MessageBox MB_ICONINFORMATION|MB_OK "Отмечен радибутон_4" IDOK
   ${EndIf}
SectionEnd

[MKN]

kotkovets,
Вроде разобрался с этим моментом (полтыщи строк, путаюсь очень...). Спасибо. Теперь никак не получается закрыть кастомную страницу (по сути закрыть скрипт, выйти из него) после :

Код:

MessageBox MB_OK "Файл успешно создан!" IDOK

Т.е. по окончании работы.
Почему то вообще не действует :

Код:

Section
SetAutoClose true
SectionEnd

[kotkovets]

Теперь никак не получается закрыть кастомную страницу (по сути закрыть скрипт, выйти из него) после : Код: MessageBox MB_OK "Файл успешно создан!" IDOK »

Добавь в конце функции "волшебную" команду

Код:

SendMessage $HWNDPARENT 0x408 1 0

Циферка 1 - означает переместиться на страничку вперед...

Код:

Function CreateFile
    ;---
    MessageBox MB_OK "Файл успешно создан!" IDOK
    SendMessage $HWNDPARENT 0x408 1 0
FunctionEnd

[sawe]

Было несколько решений реализации страницы Readme, наконец решил переделать по нормальному из страницы лицензии.
PageReadme_NSIS.zip

----

[kotkovets]

sawe, Все хорошо, но есть серьезные недостатки,

Код:

!include "MUI2.nsh"
!insertmacro MUI_PAGE_README "Читать.txt"
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "Russian"
ShowInstDetails show
OutFile test.exe

Section
SectionEnd

Смотрим лог компилятора:

Код:

4 warnings:
  LangString "MUI_INNERTEXT_README_BOTTOM" is not set in language table of language Russian
  LangString "MUI_TEXT_README_TITLE" is not set in language table of language Russian
  LangString "MUI_TEXT_README_SUBTITLE" is not set in language table of language Russian
  LangString "MUI_INNERTEXT_README_TOP" is not set in language table of language Russian

О чем это говорит? У вас не определены настройки по умолчанию, если в скрипте не задать константы.
Например, я в скрипте не указал цвет

Код:

!define  MUI_READMEPAGE_BGCOLOR

то в хидере, делаем проверку на наличие этой константы и если она не указана, объявлем константу и задаем значение константы по умолчанию.

Код:

!ifndef  MUI_READMEPAGE_BGCOLOR
  !define  MUI_READMEPAGE_BGCOLOR 0xFFFFFF
!endif

Дальше не стал смотреть... sawe в топку! Дорабатывайте!!!

[yyv]

sawe, подскажите, как мне подложить картинку в нужный мне контрол к примеру в 1055?
вот я рисую страничку используя nsDialogs::Create
не важно 1018 или 1044 или 1099
нарисовал, отобразил
как в контрол 1055 вставить нужную картинку? это нужно PRE функцию вызывать? или как?
вроде что-то получилось....

[sawe]

подскажите, как мне подложить картинку в нужный мне контрол к примеру в 1055? »

Если к контролу, то он должен иметь следующий вид:
----------
CONTROL "", 1055, STATIC, SS_BITMAP | WS_CHILD | WS_VISIBLE, X, X, X, X
----------
Если я не ошибаюсь, то MUI2 функция PRE занята. Откройте NSIS\Contrib\Modern UI 2\Interface.nsh
и посмотрите, как реализуется следующее
----------
SetBrandingImage /IMGID=1055 /RESIZETOFIT "$PLUGINSDIR\картинка.bmp"
----------
или универсальный макрос

читать дальше »

Код:

!macro BIMAGE IMAGE PARMS
       Push $0
       GetTempFileName $0
       File /oname=$0 "${IMAGE}"
      SetBrandingImage /IMGID=1055 /RESIZETOFIT "картинка.bmp"
       Delete $0
       Pop $0
!macroend 

!define SMUI_PAGE_CUSTOMFUNCTION_SHOW BGImage

Function BGImage
  !insertmacro BIMAGE "картинка.bmp" /RESIZETOFIT
FunctionEnd

В nsDialogs, если рисунок не перекрывается ни чем, делается просто

читать дальше »

Код:

 Var Dialog
 Var BitmapX
 Var BitmapX_Image

Function CustomShow
      nsDialogs::Create 1018
      Pop $Dialog
      
      ${NSD_CreateBitmap} 10u 6u 30u 30u ""
      Pop $BitmapX
      ${NSD_SetImage} $BitmapX "$PLUGINSDIR\картинка.bmp" $BitmapX_Image
;-----
  nsDialogs::Show
FunctionEnd

----

Смотрим лог компилятора: »

это связано с тем, что в каждый языковой файл следует добавить скорее всего английский README, или чухай затылок!
По быстрячку не прошло, бум карпеть!

[yyv]

sawe,
получилось
в этот момент там было очень много мата и слюней радости, ибо уже более трех дней бьюсь с этой проблемой
вот мой контрол

Код:

   CONTROL "", 1139, STATIC, SS_BITMAP | WS_CHILD | WS_VISIBLE, 0, 250, 462, 43

а во так я делаю нужый мне фон нижнего края

Код:

 
GetDlgItem  $back $HWNDPARENT 1139
SetCtlColors $back 0x000000 0xEBEBEB

вопрос теперь в другом

как мне сделать фон в BrandingText нужным мне?
использую BrandingURL plug-in
пробую

Код:

 
GetDlgItem $0 $HWNDPARENT 1028
SetCtlColors $0  0x000000 0xEBEBEB

и здесь это вариант не проходит
фон системный серый...