[архив].: NSIS

MKN · Отправлено: **08:52, 04-10-2011** | #**1691**

kotkovets,

Несколько вопросов по кастомной странице :

Поясни пожалуйста назначение Function Directory в твоём примере. (И почему то без неё, выбор директории установки работает, а с ней - ругань при компиляции...)

И где в коде должна быть запись : Page custom SelectDirectory Directory ?
Ведь пользовательская страница уже создана записью типа : Page custom fnCustomInit fnCustomDestroy

Каким образом осуществляется зависимое (ИЛИ-ИЛИ) переключение чекбоксов (двух и более) в коде кастомной страницы ?

Почему при создании GroupBox имеем только надпись над группой, а не сам чекбокс, как при создании на обычной странице,(отключающий\включающий все чекбоксы, входящие в группу) ? Что для этого надо сделать ?

Как реализовать отметку всех имеющихся на странице чекбоксов при помощи одной (или двух ?) кнопки ?
Т.е. имеется несколько десятков чекбоксов (в группах в том числе). Нажал кнопку - все отмечены. Ещё раз нажал (или нажал вторую кнопку ?) - отметки сняты.

kotkovets · Конфигурация компьютера

Цитата MKN:

И где в коде должна быть запись : Page custom SelectDirectory Directory »

В начале кода, где идет объявление страниц..
Page custom pre post
pre - имя функции[Функция которая будет выполнена при выполнении своей странички]
post - имя функции[Функция которая будет выполнена при закрытии странички]
Таким образом можно объявлять множесто своих страничек, эти странички
и команды, функции в страничках - не работают при тихом режиме.

Цитата MKN:

Каким образом осуществляется зависимое (ИЛИ-ИЛИ) переключение чекбоксов (двух и более) в коде кастомной страницы ? »

Если ты имеешь в виду чекбоксы - то такое переключение сложно в реализации.
Флажок-точка(радиобутоны) - системные контролы, зависимое переключение получается через системные ресурсы
Если радиобутонов много, можно объединить в свои группы переключений.
http://nsis.sourceforge.net/NsDialogs_FAQ (How to create two groups of RadioButtons)

Цитата MKN:

Как реализовать отметку всех имеющихся на странице чекбоксов при помощи одной (или двух ?) кнопки ?
Т.е. имеется несколько десятков чекбоксов (в группах в том числе). Нажал кнопку - все отмечены. Ещё раз нажал (или нажал вторую кнопку ?) - отметки сняты. »

Нужно реализовавать функции обработки событий. В справочнике по NSIS рассказано как это делать.
http://nsis.sourceforge.net/NsDialogs_FAQ
nsDialogs::OnClick [хэндл контрола] [имя функции]
Определять статусы контролов, как первоначальные, так при обработке событий
${NSD_SetState} [хэндл контрола] 1 - статус отмеченный, 0 - наоборот
В функции, которая будет выполнена при закрытии странички удобно снимать статусы чекбоксов, радиобутонов
${NSD_GetState} [хэндл контрола] $var
$var = 0 -> чекбокс, радиобутон не отмечен, 1 -> наоборот

kotkovets · Конфигурация компьютера

MKN, Пример к всему вышесказанному, будет полезно всем:

Код:

!include "MUI2.nsh"

Page Custom pre post
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE Russian
OutFile "test.exe"
ShowInstDetails show

var dialog
var RadioButton1
var RadioButton2
var RadioButton3
var RadioButton4

var CheckBox1
var CheckBox2
var CheckBox3
var CheckBox4

var Check1
var Check2
var Check3
var Check4

var rButton1
var rButton2
var rButton3
var rButton4

var Button
var Button1

Function pre
   nsDialogs::Create 1018
   Pop $dialog
	${NSD_CreateRadioButton} 0 0 40% 6% "Группа_1, Радио_1"
		Pop $RadioButton1
	${NSD_SetState} $RadioButton1 1 ;Группа_1, радио_1 при показе странички, делаем отмеченным
	${NSD_CreateRadioButton} 0 12% 40% 6% "Группа_1, Радио_2"
		Pop $RadioButton2
		${NSD_AddStyle} $RadioButton1 ${WS_GROUP} ;определяем группу переключений 1
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	${NSD_CreateRadioButton} 50% 0 40% 6% "Группа_2, Радио_1"
		Pop $RadioButton3
	${NSD_SetState} $RadioButton3 1 ;Группа_2, радио_1 при показе странички, делаем отмеченным
	${NSD_CreateRadioButton} 50% 12% 40% 6% "Группа_2, Радио_2"
		Pop $RadioButton4
		${NSD_AddStyle} $RadioButton3 ${WS_GROUP} ;определяем группу переключений 2
	;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
	${NSD_CreateButton} 40u 40u 140u 15u `Кнопка переключений радиобутонов`
	        Pop $Button
        ${NSD_OnClick} $Button ButtonClick
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ${NSD_CreateCheckBox} 0 65u 56u 12u "Чебокс_1"
               Pop $CheckBox1
        ${NSD_CreateCheckBox} 0 85u 56u 12u "Чебокс_2"
               Pop $CheckBox2
        ${NSD_CreateCheckBox} 150u 65u 56u 12u "Чебокс_3"
               Pop $CheckBox3
        ${NSD_CreateCheckBox} 150u 85u 56u 12u "Чебокс_4"
               Pop $CheckBox4
          ;все чебоксы отмечены
        ${NSD_SetState} $CheckBox1 1
        ${NSD_SetState} $CheckBox2 1
        ${NSD_SetState} $CheckBox3 1
        ${NSD_SetState} $CheckBox4 1
	${NSD_CreateButton} 40u 105u 140u 15u `Кнопка переключений чекбоксов`
	      Pop $Button1
        ${NSD_OnClick} $Button1 ButtonClickCheckBox
    nsDialogs::Show
FunctionEnd

Function ButtonClick ;функция обработки события нажатия кнопки
  Pop $Button
  ${NSD_GetState} $RadioButton1 $rButton1
  ${NSD_GetState} $RadioButton2 $rButton2
  ${NSD_GetState} $RadioButton3 $rButton3
  ${NSD_GetState} $RadioButton4 $rButton4
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ;Логика И-ИЛИ для группы 1
  ${If} $rButton1 == 1
  ${AndIf} $rButton2 == 0
      ${NSD_SetState} $RadioButton1 0
      ${NSD_SetState} $RadioButton2 1
  ${Else}
      ${NSD_SetState} $RadioButton1 1
      ${NSD_SetState} $RadioButton2 0
  ${EndIf}
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ;Логика И-ИЛИ для группы 2
  ${If} $rButton3 == 1
  ${AndIf} $rButton4 == 0
      ${NSD_SetState} $RadioButton3 0
      ${NSD_SetState} $RadioButton4 1
  ${Else}
      ${NSD_SetState} $RadioButton3 1
      ${NSD_SetState} $RadioButton4 0
  ${EndIf}
FunctionEnd

Function ButtonClickCheckBox
   Pop $Button1
   ;снимаем статусы чекбоксов:
   ${NSD_GetState} $CheckBox1 $Check1
   ${NSD_GetState} $CheckBox2 $Check2
   ${NSD_GetState} $CheckBox3 $Check3
   ${NSD_GetState} $CheckBox4 $Check4
   ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   ;Логика ИЛИ-ИЛИ для чекбоксов
   ${If} $Check1 == 1
   ${Orif} $Check2 == 1
   ${Orif} $Check3 == 1
   ${Orif} $Check4 == 1
        ${NSD_SetState} $CheckBox1 0
        ${NSD_SetState} $CheckBox2 0
        ${NSD_SetState} $CheckBox3 0
        ${NSD_SetState} $CheckBox4 0
   ${Else}
        ${NSD_SetState} $CheckBox1 1
        ${NSD_SetState} $CheckBox2 1
        ${NSD_SetState} $CheckBox3 1
        ${NSD_SetState} $CheckBox4 1
   ${EndIf}
FunctionEnd

Function post
  ;снимаем статусы радибутонов:
  ${NSD_GetState} $RadioButton1 $rButton1
  ${NSD_GetState} $RadioButton2 $rButton2
  ${NSD_GetState} $RadioButton3 $rButton3
  ${NSD_GetState} $RadioButton4 $rButton4
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
     ;снимаем статусы чекбоксов:
   ${NSD_GetState} $CheckBox1 $Check1
   ${NSD_GetState} $CheckBox2 $Check2
   ${NSD_GetState} $CheckBox3 $Check3
   ${NSD_GetState} $CheckBox4 $Check4
FunctionEnd

Section ""
   DetailPrint "состояние Чебокс_1 == $Check1"
   DetailPrint "состояние Чебокс_2 == $Check2"
   DetailPrint "состояние Чебокс_3 == $Check3"
   DetailPrint "состояние Чебокс_4 == $Check4"
   DetailPrint "========================================"
   DetailPrint "========================================"
   DetailPrint "состояние Группа_1, Радио_1 == $rButton1"
   DetailPrint "состояние Группа_1, Радио_2 == $rButton2"
   DetailPrint "состояние Группа_2, Радио_1 == $rButton3"
   DetailPrint "состояние Группа_2, Радио_2 == $rButton4"
SectionEnd

MKN · Отправлено: **17:57, 04-10-2011** | #**1694**

Что то не вышло использовать для $INSTDIR (InstallDir "$SysDrive:\App") переменную системного диска по способу
StrCpy $SysDrive $WINDIR 2 в Function .onInit.
Есть ли какие иные способы для $INSTDIR ?

зы А почему собственно в NSIS нет переменной системного диска ?

kotkovets · Конфигурация компьютера

Цитата MKN:

зы А почему собственно в NSIS нет переменной системного диска ? »

А зачем, если есть системные???
Почитай синтаксис StrCpy - очень полезно для разбора строк, советую!
открываем справку по nsis -> Перевод справки NSIS -> ExpandEnvStrings
В справке почти все есть, для создания среднестатического дистрибутива!

Код:

 
 Function .OnInit
  ExpandEnvStrings $INSTDIR "%SYSTEMDRIVE%\App"
FunctionEnd

InstallDir "$INSTDIR"

Красиво и со вкусом!

MKN · Отправлено: **09:34, 05-10-2011** | #**1696**

Подскажите , как решить такую задачу :
Создал прогресс бар на кастомной странице :

Код:

Var ProgressBar1
${NSD_CreateProgressBar} координаты-размеры ""
Pop $ProgressBar1

А как заставить его "действовать", т.е. отображать реальный ход установки, после клика на "Установить" ?
В примерах всюду какой то Timer применяют... Или это для демонстрационной автономной "презентации" ?

ps Хорошо бы дополнить справочник по NSIS, в разделе кастомные страницы, расширенным описанием и конкретными примерами для разных вариантов установок. А то сейчас по этому вопросу, информации обзорна и крайне скупа...

kotkovets · Конфигурация компьютера

Цитата MKN:

А как заставить его "действовать", т.е. отображать реальный ход установки, после клика на "Установить" ? »

После каждой команды изменяем позицию прогресса на 10%
и снимаем позицию бара - помещаем текст позиции над баром.

Код:

SendMessage $PROGBAR ${PBM_SETPOS} 0 10
SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
${NSD_SetText} $Text $1%

Код:

!include LogicLib.nsh
!include nsDialogs.nsh

Name "nsDialogs Timer Example"
OutFile "nsDialogs Timer Example.exe"
XPStyle on

Var DIALOG
Var TEXT
Var PROGBAR
Var Button

Page custom nsDialogsPage

Function CreateFile
        Pop $Button
        FileOpen $4 text.txt a
        
  	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	SendMessage $PROGBAR ${PBM_SETPOS} 0 0
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	
	Sleep 500 ;пауза для наглядности
	SendMessage $PROGBAR ${PBM_DELTAPOS} 10 0
	SendMessage $PROGBAR ${PBM_GETPOS} 0 0 $1
	${NSD_SetText} $Text $1%
	FileWrite $4 "${__FUNCTION__} $1$\r$\n"
	FileClose $4
	
	MessageBox MB_OK "Файл успешно создан!" IDOK
FunctionEnd

Function nsDialogsPage
	nsDialogs::Create 1018
	Pop $DIALOG
	${NSD_CreateLabel} 0u 0u 100% 9u ""
	Pop $TEXT
	${NSD_CreateProgressBar} 0u 10u 100% 12u "99"
	Pop $PROGBAR
	${NSD_CreateButton} 90u 70u 70u 12u "Создать файл"
	Pop $Button
	${NSD_OnClick} $Button CreateFile
	nsDialogs::Show
FunctionEnd

Section
SectionEnd

sawe · Отправлено: **14:46, 05-10-2011** | #**1698**

То есть, можно сделать и обратное продвижение бара?

MKN · Отправлено: **15:19, 05-10-2011** | #**1699**

kotkovets,
Пример с баром красивый и наглядный, но это ведь будет отдельная задача, выполняемая при клике на конкретную новую кнопку "Создать файл", на имеющейся кастомной странице.

А как быть , если на этой странице уже есть куча чекбоксов, с поставленной для них задачей, исходя из их состояния ?
А задача эта будет выполнена так, как уже указано в Function fnCustomDestroy (причём после закрытия страницы, т.е после нажатия стандартной кнопки "Установить")...

А если надо, чтобы задачи связанные с состоянием чекбоксов, были выполнены при нажатии кнопки "Создать файл" (Или всё таки можно при нажатии кнопки "Установить" ?) с индикацией прогресс баром, при открытой странице ?
Получается надо как то перестроить все действия ? Как ?

kotkovets · Конфигурация компьютера

Цитата sawe:

То есть, можно сделать и обратное продвижение бара? »

Все что угодно..
Пример использования таймера - системный цикл, который порождает отдельный поток основной программы, "многопоточное приложение",
на примере таймер обновляет время частотой в 200 миллисекунд

Цитата MKN:

(Или всё таки можно при нажатии кнопки "Установить" ?) »

А чет ты привязался к кнопке установить? Мы работаем с кастомными страничками, стандартная страничка установки отбой! по логике,работаем с баром своим, подумай по чему!
Создаем еще страничку свою с прогрессом, типа нажали кнопку, неужели так трудно подумать и включить мозг

и конечная стандартная страничка финиша........