[sawe]

Это кто вам такое сказал то? смысл здесь в чем? »

Справка от версии 1,68 до 2,10 и обзывается makensis.html

[kotkovets]

sawe, Я не знаю как в предыдущих версиях, может наследие...
Местные регистры - означает, что эти переменные работают, только в пределах одной секции или функции - потом значение этих переменных уничтожается (как и в компиляторах си, делфи)
глобальные значения - т.е эти переменые, значения можно использовать любой функцией или макросом в пределах установщика.
Однако все значения этих переменных использовать можно любой функцией или любым макросом.

[sawe]

Я не знаю как в предыдущих версиях, может наследие... »

До второй версии была даже поддержка Unix-ов, чем выгодно отличалась от других.

[wolkow70]

Уважаемый kotkovets, не подскажите по какой причине может не компилироваться такой макрос дерегистрации:

Код:

!macro UnRegisterExtension extenstion
Push $1
Push $2
StrCpy $ClassName "FastStone.${extenstion}"
ReadRegStr $1 HKLM "SOFTWARE\Classes\.${extenstion}" ""
StrCmp $1 "$ClassName" 0 RestoreProgid
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "" 
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "PerceivedType" 
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "Content Type"
DeleteRegKey HKLM "SOFTWARE\Classes\$ClassName"
;
ReadRegStr $1 HKLM "SOFTWARE\Classes\.${extenstion}" "FastStone.bak"
WriteRegStr HKLM "SOFTWARE\Classes\.${extenstion}" "" $1
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "FastStone.bak"
 ;
RestoreProgid:
;
ReadRegStr $2 HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "FastStone.bak"
WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "Progid" $2
DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "FastStone.bak"
;
Pop $1
Pop $2
!macroend

Ошибка вылазит такая:

StrCpy $ClassName "FastStone.TIFF" () ()
ReadRegStr $1 HKLM\SOFTWARE\Classes\.TIFF\
StrCmp "$1" "$ClassName" equal=0, nonequal=RestoreProgid
DeleteRegValue: HKLM\SOFTWARE\Classes\.TIFF\
DeleteRegValue: HKLM\SOFTWARE\Classes\.TIFF\PerceivedType
DeleteRegValue: HKLM\SOFTWARE\Classes\.TIFF\Content Type
DeleteRegKey: HKLM\SOFTWARE\Classes\$ClassName
ReadRegStr $1 HKLM\SOFTWARE\Classes\.TIFF\FastStone.bak
WriteRegStr: HKLM\SOFTWARE\Classes\.TIFF\=$1
DeleteRegValue: HKLM\SOFTWARE\Classes\.TIFF\FastStone.bak
Error: label "RestoreProgid:" already declared in section
Error in macro UnRegisterExtension on macroline 15
Error in script "D:\NSIS\FastStoneView.nsi" on line 769 -- aborting creation process

[kotkovets]

по какой причине может не компилироваться »

вы в одной секции, вызываете макрос несколько раз, получается вставка кода макроса в секцию и в макросе есть безусловный переход по метке - это противоречит синтаксису NSIS: совпадение безусловных переходов по имени не допускается! (Error: label "RestoreProgid:" already declared in section)
Здесь нужно применять условные переходы или логическую конструкцию.

Код:

!include logiclib.nsh
--
--
StrCpy $ClassName "FastStone.${extenstion}"
ReadRegStr $1 HKLM "SOFTWARE\Classes\.${extenstion}" ""
${If} $1 == "$ClassName"
     DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "" 
     DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "PerceivedType"
    ---
    ---
${Else}
   ReadRegStr $2 HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "FastStone.bak"
   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "Progid" $2
   DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "FastStone.bak"    
${EndIf}
---
---

[wolkow70]

Спасибо за ответ. Пока я его ждал, еще попробовал сделать так:

Код:

!macro UnRegisterExtension extenstion
Push $1
Push $2
StrCpy $ClassName "FastStone.${extenstion}"
;
ReadRegStr $1 HKLM "SOFTWARE\Classes\.${extenstion}" ""
StrCmp $1 "$ClassName" 0 +2
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "" 
;
StrCmp $1 "$ClassName" 0 +3
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "PerceivedType" 
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "Content Type"
;
StrCmp $1 "$ClassName" 0 +2
DeleteRegKey HKLM "SOFTWARE\Classes\$ClassName"
;
StrCmp $1 "$ClassName" 0 +4
ReadRegStr $1 HKLM "SOFTWARE\Classes\.${extenstion}" "FastStone.bak"
WriteRegStr HKLM "SOFTWARE\Classes\.${extenstion}" "" $1
DeleteRegValue HKLM "SOFTWARE\Classes\.${extenstion}" "FastStone.bak"
;
;;RestoreProgid
;
ReadRegStr $2 HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "FastStone.bak"
WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "Progid" $2
DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "FastStone.bak"
;
Pop $1
Pop $2
!macroend

В таком виде тоже все работает.

И все таки не понятно почему безусловные переходы совпадают?
Ведь дерегистрация каждого расширения вызывается отдельной коммандой:
!insertmacro UnRegisterExtension "WMF"
!insertmacro UnRegisterExtension "TIFF"
!insertmacro UnRegisterExtension "TIF"
!insertmacro UnRegisterExtension "TGA"
Я так понимаю, что макрос каждый раз запускается снова для выполнения комманд, или во что-то не врубился?

[kotkovets]

В таком виде тоже все работает »

здесь уже условные переходы, отсчет идет относительно оператора сравнения, но это очень не удобно - при каждом изменении макроса приходится подсчитывать переходы, что бы условия переходов соблюдались

И все таки не понятно почему безусловные переходы совпадают? »

потому что, компилятор код макроса "вставляет" в секцию, из которой вызывается макрос.

Я так понимаю, что макрос каждый раз запускается снова для выполнения комманд, или во что-то не врубился? »

конечно!

[wolkow70]

потому что, компилятор код макроса "вставляет" в секцию, из которой вызывается макрос. »

Вот это я и не учел. Но, я ориентировался на пример из справки:
http://nsis.sourceforge.net/File_Association

Код:

!macro UnRegisterExtension_
  !verbose push
  !verbose ${_FileAssociation_VERBOSE}
 
  Exch $R1 ;desc
  Exch
  Exch $R0 ;ext
  Exch
  Push $0
  Push $1
 
  ReadRegStr $1 HKCR $R0 ""
  StrCmp $1 $R1 0 NoOwn ; only do this if we own it
  ReadRegStr $1 HKCR $R0 "backup_val"
  StrCmp $1 "" 0 Restore ; if backup="" then delete the whole key
  DeleteRegKey HKCR $R0
  Goto NoOwn
 
Restore:
  WriteRegStr HKCR $R0 "" $1
  DeleteRegValue HKCR $R0 "backup_val"
  DeleteRegKey HKCR $R1 ;Delete key with association name settings
 
NoOwn:
 
  Pop $1
  Pop $0
  Pop $R1
  Pop $R0
 
  !verbose pop
!macroend

Который почему-то работает. Наверное, он вызывается по другому.

[kotkovets]

Который почему-то работает. Наверное, он вызывается по другому. »

Вызывается макрос через ${CallArtificialFunction} RegisterExtension_, ${CallArtificialFunction} - описан в хедере Util.nsh. Офигительный хедер, очень помогает, особенно в циклах.
Вот вы попробуйе в FileAssociation.nsh заменить ${CallArtificialFunction} на !insertmacro и вы получите конфликт по именам переходов

[wolkow70]

Вызывается макрос через ${CallArtificialFunction} RegisterExtension_, ${CallArtificialFunction} - описан в хедере Util.nsh. Офигительный хедер, очень помогает, особенно в циклах. »

В оригинальном скрипте VLC нет FileAssociation.nsh и нет комманды ${CallArtificialFunction} RegisterExtension_, мне вообще не понятно как он работает, а ведь работает (проверял неоднократно)...