[Foreigner]

vivera864864,
Взять содержимое чего? Файлов? И приведи пример как должно быть в итоге.

[vivera864864]

Foreigner, да файлов
ну например в первой строке первого файла
C:\tmp.txt
его содержимое: exit
нужно чтобы во втором должно быть
1. exit

как-то так

и так с каждой строкой, их конечное кол-во неизвестно

[Foreigner]

vivera864864,

Код:

@echo off
setlocal

for /f "tokens=*" %%i in (list.txt) do call:echo "%%i"
goto:eof

:echo
set /a cnt+=1

1>>result.txt (

    0>nul set /p="%cnt%. "
    type %1

)

как-то так

[vivera864864]

Foreigner, Нумерует первую строку и всё

и надо копировать и нумеровать СОДЕРЖИМОЕ каждого файла

[Foreigner]

vivera864864,

и надо копировать и нумеровать СОДЕРЖИМОЕ »

В исходных файлах из списка ( из list.txt ) по одной строке? Поставь вопрос шире. Объясни. Если в исходных файлах больше одной строки в каждом, то:

Код:

@echo off
setlocal

for /f "tokens=*" %%i in ( list.txt ) do (

    for /f "tokens=*" %%j in (' type "%%i" ') do call:echo "%%j"

)
goto:eof

:echo
set /a cnt+=1

0>nul 1>>result.txt (

    set /p="%cnt%. "
    set /p="%~1"
    echo.

)

[vivera864864]

Foreigner, Вот это то что я искал спасибо громадное))))))))

[Foreigner]

vivera864864,
Одно маленькое замечание. Этот батник не будет корректно работать если в строке присутствуют "poison symbols" ( % = ( ) ! < > )
С помощью sed этот вопрос решается:

Код:

@echo off
setlocal

for /f "tokens=*" %%i in ( list.txt ) do 1>>res.tmp findstr /v "^$" "%%i"
findstr /n "." res.tmp | 1>result.txt sed "s/^\([0-9]*\):\(.*\)$/\1. \2/g"
del res.tmp

[amel27]

тогда до кучи:

Код:

(for /f "usebackq tokens=*" %%a in ("list.txt") do @type "%%a"
)|findstr/n $ >result.txt

С помощью sed этот вопрос решается »

батником тоже можно решить использованием DelayedExpansion

[Foreigner]

amel27,

findstr/n $ >result.txt »

Здесь нумерация будет с двоеточием, а по условию было с точкой и пробелом после номера строки. И пустые строки тоже попадут в конечный файл.