[Iska]

petr_al, озвучьте Вашу ОС.

Смещение указывается в байтах. Вам, кстати, оно нужно?

offset=N Смещение в байтах для начала нового раздела. Если смещение не указано, раздел начинается с начала свободного пространства на диске. Для дисков с основной загрузочной записью (MBR) значение смещения зависит от цилиндров. Смещение округляется до ближайшей границы цилиндра. Например, если указано смещение 27 Мбайт, а размер цилиндра 8 Мбайт, смещение округляется до границы 24 Мбайт.

[petr_al]

Да нет не нужно!!! Мне главное понять сам принцип создания разделов именно в примерах!!!!

ОС Wn XP на виртуальнике!!!

[Anton04]

Мне главное понять сам принцип создания разделов именно в примерах!!!! »

Тут гораздо больше чем надо, но зато всё есть...

DiskTune.cmd

читать дальше »

@echo off
cls

Title Настройка разделов жесткого диска

rem echo Ждем 60 секунд, чтобы на оптическом приводе не осталось открытых файлов...
rem %~dp0delay 60000

rem Удаление файла-отчета, если такой существует
if exist volinfo.txt (
echo Удаление старого файла отчета...
echo.
erase volinfo.txt
)

rem Создание нового файла отчета по каждой букве диска
echo Создание файла отчета по каждой букве диска.
echo Пожалуйста, подождите...
echo.
for %%i in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
fsutil fsinfo drivetype %%i: >> volinfo.txt
)

rem Анализ созданного отчета
rem F: - Компакт-дисковод
rem A: - Съемный диск
rem D: - Жесткий диск
rem 1 2 3
rem A B C
set fdds=0
set hdds=0
set cds=0
echo Обнаружены следующие накопители:
for /f "tokens=1-4 delims=- " %%A in (volinfo.txt) do (
if "%%B"=="Компакт" (
echo %%A - Оптический привод
set /a cds+=1
)
if "%%B"=="Жесткий" (
echo %%A - Раздел жесткого диска
set /a hdds+=1
)
if "%%B"=="Съемный" (
echo %%A - Съемный диск
set /a fdds+=1
)
)
echo.
echo Жестких дисков - %hdds%
echo Съемных дисков - %fdds%
echo Оптических приводов - %cds%
echo.

set fulltune=1
if %hdds% gtr 1 (set fulltune=0)
if %fdds% gtr 1 (set fulltune=0)

if "%fulltune%"=="0" (
echo Назначаем оптическому приводу букву X
echo Дождитесь завершения операции...
echo.
diskpart /s withd.txt
echo Назначаем метку системному тому...
echo.
label C: SYS
echo ВНИМАНИЕ!
echo Слишком много жестких или съемных дисков.
echo Настройка разделов выполнена не полностью!
echo.
echo Можно настроить разделы вручную или отключить
echo дополнительные накопители и попробовать снова.
color 0C
echo.
echo
echo
echo
) else (
echo Назначаем оптическому приводу букву X,
echo создаем на жестком диске дополнительный раздел на все свободное место,
echo в дополнительном разделе создаем логический диск D на все свободное место.
echo Дождитесь завершения операций...
echo.
diskpart /s withoutd.txt
echo Форматируем созданный логический диск в NTFS. Размер кластера 32 Kb.
echo Дождитесь завершения операций...
echo.
format D: /FS:NTFS /Q /A:32k /Y
echo Назначаем метки томам...
echo.
label C: SYS
label D: DATA
echo Все операции завершены.
echo.
)

withd.txt

читать дальше »

select volume=0
assign letter=X noerr

withoutd.txt

читать дальше »

select volume=0
assign letter=X noerr
select disk=0
create partition extended
create partition logical
assign letter=D noerr