DrWeb 5.x/6.x/7.x/8.x/9.x

otsheln1k · Отправлено: **20:37, 05-03-2011** | #**201**

cleric1985_n,

я не использую в своих сетях альтернативные от MS фаерволы, мешают нормальному администрированию. MS-овский при наличии соответствующих прав, можно включать и отключать удаленно, выполняя необходимые административные задачи.

На предыдущей странице XXXler, приводил необходимые ключи к стандартному установщику...попробуйте их использовать...

wadimus · Отправлено: **15:38, 11-05-2011** | #**202**

друзья, покритикуйте статеечку. её написал для форума ннм-клуба.
ссылка на оригинальный пост тут:

версии DrWeb-а, учавствующие там на 18.03.11
появились новые версии на 10.05.11, порядок сборки инсталлчтора от этого не изменился

сам пост (многа букав!

) тут:

Nun-Nun · Конфигурация компьютера

wadimus,

Интересная информация. Только требуется одно уточнение: если для всего репака нужен всего один ключ, то разве такой универсальный существует, чтобы подходил одновременно к разным версиям DrWeb-а? Помню, когда-то пробовал офключ от простой версии DrWeb-а подсунуть версии типа DrWeb Pro, но облом вышел - точно не помню, что там было, но по-моему то ли вылезло сообщение, что ключ не тот, то ли, что установлен будет не DrWeb Pro, а обычная версия.

wadimus · Отправлено: **22:23, 12-05-2011** | #**204**

Nun-Nun, решаемо!
перестройка репака.

- ложим рядом с репаком свой ключ drweb32.key

- config.txt для создания sfx-ехе-файла тогда будет таким

Код:

RunProgram="hidcon:cmd /c if exist \"%%S\\%KeyFile%\" copy /y \"%%S\\%KeyFile%\" \"%%T\\%KeyFile%\""

если есть рядом файл drweb32.key, то он скопируется во временную папку после распаковки архива, ну и потом начнется установка антивируса с подхватом этого файла

volk1234 · Конфигурация компьютера

Народ подскажите, как автоматизировать удаление drweb 6.0

Строка

Код:

msiexec /x{код продукта}

работает.
Но это не "тихое удаление". ключ /qb работает, ключ /qr- нет т.к. не появляется окно отключения самозащиты.

Вопрос в другом - как определить {код продукта} поскольку он может быть разным. Он разный для разных релизов или меняется произвольно?

otsheln1k · Отправлено: **10:07, 23-05-2011** | #**206**

volk1234,

Скрипт позволяет искать строки деинсталляции для любых программ, так и не довел до ума когда-то, но работает:

после запуска, на приглашение - "введите имя программы для деинсталляции", ввести "dr.web" (без кавычек)
скрипт найдет имя и выведет на экран (возможно, что будет более одной копии программы, остатки от старых инсталляций)

Спросит, что дальше делать, путем выбора "0","1","3" - можно выйти, уточнить поиск или продолжить работу.
По окончании работы будет получен - ключ продукта и строка деинсталляции из реестра.

gora · Конфигурация компьютера

"Зеркало", для возможности обновления установленного DrWeb. Содержит х64 и х86 версии файлов.
Возможно, кому то окажется полезным...

Инструкция по созданию "зеркала":

1 Создаем две папки 64 и 86

2 В каждую из них копируем по три файла из установленного в системе DrWeb:
DrWebUpW.exe
update.drl
ru-drweb.dwl
Файлы одинаковы для х64 и х86 версий и могут быть скопированы из любого установленного DrWeb

3 Рядом с папками кладем файлы:
agent.key - файл ключа (название произвольное)
DrWebUpdate.bat - сам скрипт, текст см. ниже
notcopy.txt - список файлов не подлежащих копированию, текст см. ниже (примечание с)

4 Запускаем DrWebUpdate.bat, выбираем 0 и ждем окончания создания "зеркала". "Зеркало" можно создать на флешке и потом производить обновление DrWeb любой разрядности даже на машинах не имеющих выхода в сеть.

5 После завершения создания "зеркала" повторно запустите DrWebUpdate.bat и выберите 1. Произойдет обновление установленного в системе DrWeb, но уже без использования сети.

Примечание:
a. Для создания и работы "зеркала" требуется до 500 МБ свободного места на диске, на котором расположено зеркало. Учитывайте это при выборе флешки.

b. Первые три пункта инструкции требуется выполнить только один раз при создании зеркала.

c. Для уменьшения трафика и времени при обновлении "зеркала" одинаковые для х64 и х86 версий скачиваются только один раз при обновлении х64 версии, а затем просто копируются в папку 86. Различающиеся файлы (список которых находится в notcopy.txt) скачиваются при обновлении х86 версии.

d. Маркерный файл LastUpdate_06.06.2011_08-53.upd создается автоматически и содержит в имени дату/время последнего обновления "зеркала" из сети в формате dd.MM.yyyy_HH-mm. Удобно для контроля последнего обновления.

"Зеркало" исправно работает у меня уже около двух лет.

DrWebUpdate.bat:

Код:

@Echo Off
:: (c) gora, oszone.net
:: Кодировка файла кириллица DOS (866)
:: =================================================================================================
:: Составлено по информации полученной из официальных источников (http://www.sald.ru/faq/)
:: =================================================================================================
:: Структура папок\файлов для создания зеркала
:: 64-
::    \_DrWebUpW.exe
::    \_update.drl
::    \_ru-drweb.dwl
:: 86-
::    \_DrWebUpW.exe
::    \_update.drl
::    \_ru-drweb.dwl
:: DrWebUpdate.bat
:: agent.key
:: notcopy.txt
:: LastUpdate_06.06.2011_08-53.upd
:: =================================================================================================
:: Предусмотрена возможность для запуска с ключами без интерактивного выбора операции пользователем:
:: DrWebUpdate.bat 0	Обновление 'зеркала' DrWeb из сети
:: DrWebUpdate.bat 1	Обновление DrWeb из 'зеркала' (без сети)
:: =================================================================================================
If "%~1"=="0" GoTo :inet
If "%~1"=="1" GoTo :local
:input
CLS
Call :_detectOS
If Not Exist "%PF%\DrWeb\DrWebUpW.exe" Echo    В системе не обнаружен DrWeb
Echo.
Echo    0 - Обновить 'зеркало' DrWeb из сети
Echo.
If Exist "%PF%\DrWeb\DrWebUpW.exe" Echo    1 - Обновить DrWeb из 'зеркала' (без сети)
Echo.
Echo.

Set /P key=^-^>
Echo.
If "%key%"=="0" GoTo :inet
If "%key%"=="1" If Exist "%PF%\DrWeb\DrWebUpW.exe" GoTo :local
GoTo :input

:inet
If Exist 64 Call :load 64
xCopy 64\* 86 /I /D /Y /EXCLUDE:notcopy.txt>Nul
If Exist 86 Call :load 86
Echo.
Echo    'Зеркало' DrWeb ОБНОВЛЕНО из сети!
If "%Time:~0,1%"==" " (Set tt=0%Time:~1,1%-%Time:~3,2%) Else Set tt=%Time:~0,2%-%Time:~3,2%
Del *.upd 2>Nul
CD.>LastUpdate_%Date%_%tt%.upd
Ping -n 4 localhost>Nul
Exit

:local
Call :_detectOS
If Not Exist "%PF%\DrWeb\DrWebUpW.exe" Echo В системе не обнаружен DrWeb& Ping -n 4 localhost>Nul% Exit
If Not Exist %xOS% Echo В зеркале нет файлов для %xOS% системы& Ping -n 4 localhost>Nul% Exit
"%PF%\DrWeb\DrWebUpW.exe" /GO /URL:"%~dp0%xOS%"
Echo.
Echo    DrWeb (x%xOS%) ОБНОВЛЕН из 'зеркала' (без сети)!
Ping -n 4 localhost>Nul
Exit

:load
Copy %1\DrWebUpW.exe>Nul
Copy %1\update.drl>Nul
DrWebUpW.exe /GO /UA /LNG:%1\ru-drweb.dwl /DIR:"%~dp0%1"
Del update.drl
Del DrWebUpW.exe
Echo    x%1 - OK
Echo.
GoTo :EOF

:_detectOS
Set xOS=86& Set PF=%ProgramFiles%
If Defined PROCESSOR_ARCHITEW6432 (Set xOS=64) Else (If "%PROCESSOR_ARCHITECTURE%"=="AMD64" Set xOS=64)
If %xOS%==64 Set PF=%ProgramFiles(x86)%
GoTo :EOF

notcopy.txt:

Код:

drweb32.lst
drwebaf.sys
drwebpf.sys
drwebsp64.dll
drwreg.exe
drwsxtn64.dll
dwprot.sys
frwl_notify.exe
frwl_set.exe
frwl_svc.exe
spiderg3.sys
timestamp
update.drl

q1q1 · Отправлено: **22:51, 18-06-2011** | #**208**

Не прочитал дома содержимое bat файла, который создал в кодировке Windows 1251, а на работе столкнулся с иероглифами, а средств для смены кодировки рядом не оказалось - тут же перевел сообщения с русского на английский.
Прилагаю файлы, которые должны лежать рядом с папками 86 и 64.
info.txt - информационный файл, где описана последовательность действий

Oleg48 · Отправлено: **11:24, 19-06-2011** | #**209**

q1q1, а чем тебе сообщение gora непонравилось?

Nun-Nun · Конфигурация компьютера

q1q1,

Какой смысл имеет выложенный Вами DrWebUpdate.bat в кодировке 1251 ? Насколько помню bat-ники, во избежание проблем, делают в кодировке 866.