[amel27]

Tosyk, ничего особенного - из лога видно, что процесс был прерван вручную комбинацией Ctrl+C, попробуйте сначала прогнать скрипт без лога, либо уменьшите количество папок - с логом скрипт работает в десятки раз медленней

[Tosyk]

Запустил опять остановился, странно опять остановился на том же самом каталоге на котором останавливался и самый первый скрипт из темы, имя каталога "wp_Zephi_st2_3_Rose". это первый каталог в котором в Material3 присутствует уже упомянутый M01.mat. Сподкнулся он именно на этом файле, т.к в script_only_mover_2.$~1 существует последовательность:

Код:

...
..\_export_\wp_Zephi_st2_1_Sakura\Texture2D
..\_export_\wp_Zephi_st2_1_Sakura\SkeletalMesh
..\_export_\wp_Zephi_st2_1_Sakura\Material3
..\_export_\wp_Zephi_st2_1_Sakura\StaticMesh
..\_export_\wp_Zephi_st2_2_Narcissus\Texture2D
..\_export_\wp_Zephi_st2_2_Narcissus\SkeletalMesh
..\_export_\wp_Zephi_st2_2_Narcissus\Material3
..\_export_\wp_Zephi_st2_2_Narcissus\StaticMesh
..\_export_\wp_Zephi_st2_3_Rose\Texture2D
..\_export_\wp_Zephi_st2_3_Rose\SkeletalMesh

дальше должен быть каталог

Код:

..\_export_\wp_Zephi_st2_3_Rose\Material3

в котором как раз находится первый *.mat - M01.mat! до этого ни в одной папке Material3 нет фалов (результат работы первого скрипта), эти файлы в корне в папке Material3 (напомню их 814)

[amel27]

в котором как раз находится первый *.mat - M01.mat! »

Первый блок кода (тот что формирует файл .$~1) вообще игнорирует файлы - он только перечисляет имена подкаталогов 2-го уровня + "вытаскивает" их структуру без файлов (строка с XCOPY)... Вот этот кусок с закомментированной командой XCOPY:

Код:

@echo off
set root=.\_export_
if not exist "%root%" echo Не найден корневой каталог!& pause>nul& exit

SETLOCAL EnableDelayedExpansion
for %%a in ("%root%") do set "rpth=%%~fa"

type nul >"%~dpn0.$~1"
(for /d %%a in ("%rpth%") do for /d %%b in ("%%~a\*") do for /d %%c in ("%%~b\*") do (
 REM xcopy /t "%%~c\*" ".\%%~nc\"
 >>"%~dpn0.$~1" echo %%~c
))

проверь такой вариант, если пройдёт и файл-список сформируется, попробуй раскомментировать XCOPY и еще раз прогнать

[Tosyk]

запустил скрипт (script_only_structer_4_eng.bat), появилось чёрное окно cmd, во время выполнения появился и рос файл script_only_structer_4_eng.$~1, в нём список папок из _export_

скрипт почему-то проигнорировал 2 последние папки:

Zephi_Yupa2_SS_0038
Zephi_Yupa2_SS_0243

[amel27]

в нём список папок из _export_ »

А вот и неправильно! В нём список подпапок папок из _export_, т.е. если папка ".\_export_\Zephi_Yupa2_SS_0038" не содержит подпапок, то в список и включать нечего... Кстати, как там начет XCOPY?.. Например, команда для "wp_Zephi_st2_3_Rose\Material3" должна получиться такой:

Код:

xcopy /t ".\_export_\wp_Zephi_st2_3_Rose\Material3\*" ".\Material3\"

[Tosyk]

В нём список подпапок папок из _export_ »

да-да, верно, я это и имел ввиду

т.е. если папка ".\_export_\Zephi_Yupa2_SS_0038" не содержит подпапок, то в список и включать нечего... »

как раз папка содержит всё тоже самое, что и остальные

Кстати, как там начет XCOPY? »

т.е. нужно заменить строку из #63

Код:

 REM xcopy /t "%%~c\*" ".\%%~nc\"

на

xcopy /t ".\_export_\wp_Zephi_st2_3_Rose\Material3\*" ".\Material3\" »

?

[amel27]

как раз папка содержит всё тоже самое, что и остальные »

тогда только вывести структуру в файл (dir.txt) и выложить этот файл на обменник:

Код:

dir /b/s/ad .\_export_\* >dir.txt

т.е. нужно заменить строку из #63 »

как уже сказал - "раскомментировать", т.е. убрать REM

xcopy /t ".\_export_\wp_Zephi_st2_3_Rose\Material3\*" ".\Material3\"

эту команду можно проверить и без батника

[Tosyk]

тогда только вывести структуру в файл (dir.txt) и выложить этот файл на обменник »

http://dl.dropbox.com/u/9919707/script_working/dir.txt - вот

как уже сказал - "раскомментировать", т.е. убрать REM »

процесс идёт!

ДОБАВКА: скрипт меня спросил о замене файла M01.mat в корне\Material3, если я нажму да/всё, он просто всё заменит?

xcopy /t ".\_export_\wp_Zephi_st2_3_Rose\Material3\*" ".\Material3\" эту команду можно проверить и без батника »

по окнчании процесса сделаю!

[amel27]

скрипт почему-то проигнорировал 2 последние папки »

да нет, у меня вывел все папки до одной

скрипт меня спросил о замене файла M01.mat в корне\Material3, если я нажму да/всё, он просто всё заменит? »

батник в посте #63 ничего не должен заменять/спрашивать (даже с XCOPY), т.к. он ничего не копирует - только создаёт структуру пустых каталогов

[Tosyk]

как уже сказал - "раскомментировать", т.е. убрать REM »

xcopy /t ".\_export_\wp_Zephi_st2_3_Rose\Material3\*" ".\Material3\" »

всё это работает если в корне нет Material3 с файлами!

извените за ре-пост скрипта, но я уже начинаю запутываться в вариантах, поэтому буду отталкиваться от этого:

Код:

@echo off
set root=.\_export_
if not exist "%root%" echo Can't find root folder!& pause>nul& exit

SETLOCAL EnableDelayedExpansion
for %%a in ("%root%") do set "rpth=%%~fa"

<nul set/p $="Scaning and preparing folders..."
type nul >"%~dpn0.$~1"
(for /d %%a in ("%rpth%") do for /d %%b in ("%%~a\*") do for /d %%c in ("%%~b\*") do (
 xcopy /q/t "%%~c\*" ".\%%~nc\">nul
 >>"%~dpn0.$~1" echo %%~c
))
echo OK& <nul set/p $="Scaning files for moving..."
type nul >"%~dpn0.$~2"
(for /f "usebackq delims=" %%a in ("%~dpn0.$~1") do (
 for /f "delims=" %%b in ('dir/b/s/a-d "%%a\*"') do (set "$b=%%b"
 >>"%~dpn0.$~2" echo !$b:%%a=%~dp0%%~na!?%%~zb?!$b!
)))
echo OK& <nul set/p $="Sorting file list..."
sort /l "C" "%~dpn0.$~2" /o "%~dpn0.$~3"
echo OK& <nul set/p $="Working with file list..."
set "$a="& set "$b="& set/a "$n1=0,$n2=0,$n3=0"
for /f "usebackq tokens=1-3 delims=?" %%a in ("%~dpn0.$~3") do (
 if not "!$a!"=="%%a" (
   move "%%c" "%%a"
   set "$a=%%a"& set "$b=%%b"& set/a "$k=0,$n1+=1"
 ) else if not "!$b!"=="%%b" (
   set/a "$k+=1,$n2+=1"& set "$k=000!$k!"& set "$b=%%b"
   move "%%c" "%%~dpna_!$k:~-4!%%~xa"
   ) else set/a $n3+=1
)
echo OK& <nul set/p $="Deleting source folder..."
set/a "$n0=$n1+$n2+$n3"& rd /s/q "%rpth%"
echo OK& echo.& echo.Processed files all: !$n0!, из них:& echo.
echo.moved    : %$n1%
echo.renamed : %$n2%
echo.copies deleted: %$n3%
ENDLOCAL
echo.& echo Script works complited!
pause>nul

Запустил его, по окончании я отпишу результат