[Vadikan]

PS ещё не интегрировался в мою жизнь, так что пока оно коряво. Из батника запускается выполнение скрипта PS, а оттуда опять команда cmd »

В этом нет ничего корявого. Команды PS вовсе не обязательно выполнять в консоли PS, главное - результат.

[SendMessage]

Ну тогда для коллекции батник еще:

Код:

for /f "skip=1" %%i in ('wmic path Win32_logicaldisk.name^="%systemdrive%" get size') do if %%i gtr 32212254720 (command1) else (command2)

Ах ты ж.
Petya V4sechkin, совсем забыл.

[Petya V4sechkin]

SendMessage, ага, я тоже хотел сделать батник, но CMD понимает только 32-битные целые числа (поэтому сравнение с 32212254720 невозможно).

[Morpheus]

Vadikan, всё же я переделал команды под PS.
SendMessage, спасибо за попытку! Вариант с батником был бы тоже интересен.

[amel27]

тогда уж как-то так:

Код:

@echo off
SETLOCAL EnableDelayedExpansion

set $z=0& for /f "skip=1 tokens=1,2" %%a in (
'"wmic logicaldisk where name="%SystemDrive%" get size,volumename"'
) do if not "%%b"=="" set "$z=%%a"& set/a "$z=!$z:~,-9!+0"

if %$z% gtr 32 (command1) else command2

[Vadikan]

Все равно крутимся вокруг Win32_LogicalDisk

Исправил заголовок темы.

P.S. Вот PS скрипт для создания отчета о месте на всех дисках системы. Его надо допиливать под свои нужды, но идея сбора инфы понятна http://powershell.com/cs/media/p/1617.aspx

[SendMessage]

CMD понимает только 32-битные целые числа (поэтому сравнение с 32212254720 невозможно). »

Вот попробовал обойти (неоптимизировано, правда):

Код:

setlocal enabledelayedexpansion
for /f "skip=1" %%i in ('wmic path Win32_logicaldisk.name^="%systemdrive%" get size') do (
set size=%%i
set /a sizeM=!size:~0,-9!+0
set /a sizeL=!size:~-9!+0
)
if !sizeM! gtr 32 (
echo command1
) else ( 
if !sizeM! equ 32 (
if !sizeL! gtr 212254720 (echo command1) else (echo command2)
) else (
echo command2
)
)

Вроде по тестам работает правильно.

Ага, тут уже есть. И не такое громоздкое.

[amel27]

попробовал обойти »

а нужна ли такая точность?.. кстати, сравнивать вроде как можно не только числа, но и строки (если они одинаковой длины), поэтому достаточно перед сравнением дополнить строку слева нулями до 18 символов (максимум для 64-битного числа):

Код:

@echo off
SETLOCAL EnableDelayedExpansion

set $z=0& for /f "skip=1 tokens=1,2" %%a in (
'"wmic logicaldisk where name="%SystemDrive%" get size,volumename"'
) do if not "%%b"=="" set "$z=000000000000000000%%a"& set "$z=!$z:~-18!"

if "%$z%" gtr "000000032212254720" (command1) else command2

[Morpheus]

SendMessage, спасибо, но не срабатывает, оба раза выдаёт command2.
amel27, спасибо, работает.

[Vadikan]

Morpheus, посмотрел внимательнее синтаксис PS и сократил скрипт в 9 с пяти строк до трех