[madmasles]

TERMINAL,
Когда- то давно нашел такой скрипт. Он у меня на Windows XP SP3 работает.

читать дальше »

Код:

#RequireAdmin

Local $Reg_Net_Devices = "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Class\{4D36E972-E325-11CE-BFC1-08002bE10318}\"
Local $Reg_Network_Names = "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Network\{4D36E972-E325-11CE-BFC1-08002BE10318}\"
Local $Reg_Network_Names2 = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Network\{4D36E972-E325-11CE-BFC1-08002BE10318}\"

For $n = 1 To 9999
    ;формат названия ветки реестра
    $nn = StringFormat("%04d", Int($n))
    ;проверяем значение в реестре Characteristics
    $Is_Ethernet = RegRead($Reg_Net_Devices & $nn, "Characteristics")
    If $Is_Ethernet = 132 Then
        ;выясняем имя ветки реестра
        $reg_adapter_ID = RegRead($Reg_Net_Devices & $nn, "NetCfgInstanceId")
        ;Имя подключения
        $def_name = RegRead($Reg_Network_Names & $reg_adapter_ID & "\Connection", "Name")
        If $def_name <> "" Then
            $iMsgBoxAnswer1 = MsgBox(36, "Сетевые подключения.", "Найдено подключение по имени:" & @CRLF & "<" & $def_name & ">" & @CRLF & "Изменить имя?")
            Select
                Case $iMsgBoxAnswer1 = 6 ;Yes
                    $nameNew = InputBox("Сетевые подключения.", "Введите новое имя:", "")
                    If Not @error And $nameNew Then
                        RegWrite($Reg_Network_Names & $reg_adapter_ID & "\Connection", "Name", "REG_SZ", $nameNew)
                        RegWrite($Reg_Network_Names2 & $reg_adapter_ID & "\Connection", "Name", "REG_SZ", $nameNew)
                    EndIf
                Case $iMsgBoxAnswer1 = 7 ;No
                    ContinueLoop
            EndSelect
            $iMsgBoxAnswer2 = MsgBox(36, "Сетевые подключения.", "При подключении вывести значок в области уведомлений?")
            Select
                Case $iMsgBoxAnswer2 = 6 ;Yes
                    $pod = 1
                Case $iMsgBoxAnswer2 = 7 ;No
                    $pod = 0
            EndSelect
            RegWrite($Reg_Network_Names & $reg_adapter_ID & "\Connection", "ShowIcon", "REG_DWORD", $pod)
            RegWrite($Reg_Network_Names2 & $reg_adapter_ID & "\Connection", "ShowIcon", "REG_DWORD", $pod)
            $iMsgBoxAnswer3 = MsgBox(36, "Сетевые подключения.", "Уведомлять при ограниченном или отсутствующем подключении?")
            Select
                Case $iMsgBoxAnswer3 = 6 ;Yes
                    $uv = 1
                Case $iMsgBoxAnswer3 = 7 ;No
                    $uv = 0
            EndSelect
            RegWrite($Reg_Network_Names & $reg_adapter_ID & "\Connection", "IpCheckingEnabled", "REG_DWORD", $uv)
            RegWrite($Reg_Network_Names2 & $reg_adapter_ID & "\Connection", "IpCheckingEnabled", "REG_DWORD", $uv)
        EndIf
    EndIf
Next

[TERMINAL]

madmasles, мне только одно показывает, а может поиск как-то можно организовать по реестру?

[Iska]

TERMINAL, попробуйте с помощью Проводника:

читать дальше »

Код:

AutoItSetOption("MustDeclareVars", 1)

Local $oShell  = ObjCreate("Shell.Application")
Local $oFolder = $oShell.NameSpace("shell:ConnectionsFolder")

If IsObj($oFolder) Then
	For $oFolderItem In $oFolder.Items
		If $oFolderItem.Name = "Подключение по локальной сети 2" Then
			$oFolderItem.Name = "Internet"

			$oFolderItem = 0
			ExitLoop
		EndIf
	Next

	$oFolder = 0
Else
	ConsoleWriteError("Can't find folder [Сетевые подключения]")
EndIf

$oShell = 0

Exit(0)

[TERMINAL]

Разобрался, спс