[MKN]

kotkovets,
Макет такой :

Код:

Section -Post
Exec "App1.exe"

Exec "App2.exe"

ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\App3" "Path"
Exec "$R0\App3.exe"

SectionEnd

App1 должно запускаться первым, затем App2, после получения пути - App3.

Все эти проги должны работать одновременно. App3 создаёт файл либо "сама" либо после запуска извне App4.
Как только появится этот файл, App1 и App2 становятся не нужны, но App3 должно оставаться открытым.

[kotkovets]

Как все запутано!
Здесь организован бесконечный цикл, до тех пор, пока не появится файлик Txt.txt
Для четвертого запуска app.exe или продолжения скрипта нужно время "жизни" цикла

Код:

!include "LogicLib.nsh"
---
Section -Post
Exec "App1.exe"
Exec "App2.exe"
ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\App3" "Path"
Exec "$R0\App3.exe"
 ${Do}
  StrCpy $0 0
  IfFileExists "$Temp\Txt.txt" 0 +2
  StrCpy $0 1
  ${If} $0 == 1
        Quit
  ${EndIf}
${LoopUntil} $0 == 1

SectionEnd

[kotkovets]

Последнее время мне часто задают вопросы: как поместить свой текст описания, в зависимости от выбранного языка установщика?
Для этих целей служит команда LangString

Код:

 LangString message ${LANG_ENGLISH} "English message"
 LangString message ${LANG_FRENCH} "French message"
 LangString message ${LANG_KOREAN} "Korean message"
 MessageBox MB_OK "A translated message: $(message)"

В отличии от определения констант (defines) использующие изогнутые скобы - {}, здесь используются круглые скобки - ().
Всегда устанавливайте текст описания строки для каждого языка в вашем скрипте.
Пример многоязычного инсталлятора посмотрите C:\Program Files\NSIS\Examples\Modern UI\MultiLanguage.nsi

читать дальше »

Код:

  !include "MUI2.nsh"
  Caption "MultiLanguage Modern UI Test"
  Name "MultiLanguage Test"
  OutFile "Test MultiLanguage.exe"
;--------------------------------
 !define MUI_WELCOMEPAGE_TITLE "$(WELCOMEPAGE_TITLE)"
 !define MUI_WELCOMEPAGE_TEXT "$(WELCOMEPAGE_TEXT)"
;--------------------------------
 !define MUI_FINISHPAGE_TITLE "$(FINISHPAGE_TITLE)"
 !define MUI_FINISHPAGE_TEXT "$(FINISHPAGE_TEXT)"
;--------------------------------
  !define MUI_COMPONENTSPAGE_SMALLDESC
;--------------------------------
  !insertmacro MUI_PAGE_WELCOME
  !insertmacro MUI_PAGE_COMPONENTS
  !insertmacro MUI_PAGE_INSTFILES
  !insertmacro MUI_PAGE_FINISH
;--------------------------------
  !insertmacro MUI_LANGUAGE "Russian" ;first language is the default language
  !insertmacro MUI_LANGUAGE "English" 
  !insertmacro MUI_RESERVEFILE_LANGDLL
;--------------------------------
 Function .onInit
   !insertmacro MUI_LANGDLL_DISPLAY
 FunctionEnd
;--------------------------------
 Section "$(NAME_SECTION)" SecDummy
    MessageBox MB_ICONINFORMATION|MB_OK "$(Text_MessageBox)"
 SectionEnd
 
;--------------------------------------------------------------------
;Текст описания странички приветствия
LangString WELCOMEPAGE_TITLE ${LANG_RUSSIAN} "ДОБРО ПОЖАЛОВАТЬ!"
LangString WELCOMEPAGE_TITLE ${LANG_ENGLISH} "WELCOME!"
LangString WELCOMEPAGE_TEXT ${LANG_RUSSIAN} "Это пример показывает как поместить свой текст описания в \
                                            зависимости от выбранного языка инсталлятора!$\r$\n$\r$\n$_CLICK"
LangString WELCOMEPAGE_TEXT ${LANG_ENGLISH} "This example shows how to put your text descriptions, \
                                             depending on the selected language installer!$\r$\n$\r$\n$_CLICK"
;--------------------------------------------------------------------
;Текст описания странички завершения
LangString FINISHPAGE_TITLE ${LANG_RUSSIAN} "ЭТО СТРАНИЦА ЗАВЕРШЕНИЯ!"
LangString FINISHPAGE_TITLE ${LANG_ENGLISH} "COMPLETION OF THIS PAGE!"
LangString FINISHPAGE_TEXT ${LANG_RUSSIAN} "Теперь вы знаете как поместить свой текст описания в \
                                            зависимости от выбранного языка установщика!$\r$\n$\r$\nНажмите кнопку $\"Готово$\" \
                                            для выхода из программы установки."
                                            
LangString FINISHPAGE_TEXT ${LANG_ENGLISH} "Now you know how to put your descriptive text depending on \
                                            the language of the installer!$\r$\n$\r$\nClick Finish to close this wizard."
;--------------------------------------------------------------------
;Текст сообщения
LangString TEXT_MESSAGEBOX ${LANG_RUSSIAN} "Выбран Русский язык установщика!$\r$\n ID языка: $LANGUAGE"
LangString TEXT_MESSAGEBOX ${LANG_ENGLISH} "The English language installer!$\r$\n ID language: $LANGUAGE"
;--------------------------------------------------------------------
;Текст названия(имя) секции
LangString SECTION ${LANG_RUSSIAN} "Русское описание секции"
LangString SECTION ${LANG_ENGLISH} "The English description of section"
;Текст описания секции
LangString NAME_SECTION ${LANG_RUSSIAN} "Это русское название секции"
LangString NAME_SECTION ${LANG_ENGLISH} "This is the english name of the section"
;Макрос, который показавает текст описания секции
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SecDummy} $(SECTION)
!insertmacro MUI_FUNCTION_DESCRIPTION_END

[MaGoth]

kotkovets, Наверное стоит указать что данный пример кода будет корректно работать в Нсис (кодировка Анси) только в случае использования связки английский/русский, не более.
Для всех остальных случаев потребуется использовать версию Нсис - Юникод...


MfG MaGoth, WoG.ru-Community.

[kotkovets]

Наверное стоит указать что данный пример кода будет корректно работать в Нсис (кодировка Анси) только в случае использования связки английский/русский, не более »

Это с чего так? добавь C:\Program Files\NSIS\Examples\Modern UI\MultiLanguage.nsi константу:

Код:

!define MUI_LANGDLL_ALLLANGUAGES

И будут тебе все языки, доступны в ANSI-NSIS, большинство пользователей используют ANSI сборку NSIS.
A Юникод в частности, в этом случае, добавляет поддержку "экзотических" языков. А многие русскоязычные пользователи крайне редко будут добавлять такую возможность, лично мне - ни к чему,
достаточно английского языка, что бы тебя поняли многие

[MKN]

Кто нибудь работал с плагином nsisFirewall 1.2 ? (http://wiz0u.free.fr/prog/nsisFirewall/)

У меня возникла необходимость при установке, занести в список разрешённых связку "программа-файл".
Плагин nsisFirewall показался самым подходящим для этого, т.к. позволяет :

Add an application to Windows Firewall exception list Remove an application from Windows Firewall exception list

Но не работает...

Даже при компиляции собственного примера из архива плагина - ошибка...

Invalid command: nsisFirewall::AddAuthorizedApplication Error in script "C:\Program Files\NSIS\Examples\nsisFirewall\Sample.nsi" on line 15 -- aborting creation process

Есть ли иные способы работы с Firewall (для всех ОС) ?

[kotkovets]

Есть ли иные способы работы с Firewall (для всех ОС) ? »

Для ANSI версии NSIS - копируешь файл nsisFirewall.dll в C:\Program Files\NSIS\Plugins
Для Unicod версии NSIS - копируешь файл nsisFirewallW.dll в C:\Program Files\NSIS\Unicod\Plugins (или как там).
Работает нормально, как на XP, так и на 7 (не проверял на x64 ОС)
В 7 смотри Дополнительные параметры>Правила для входящих поключений - что изменилось.

читать дальше »

Код:

Name "Sample nsisFirewall"
OutFile "Sample.exe"
ShowInstDetails show	

Section "Main program"
	;Добавляет в список исключений
	nsisFirewall::AddAuthorizedApplication "$WINDIR\Notepad.exe" "nsisFirewall Test"
	Pop $0
	IntCmp $0 0 +3
	MessageBox MB_OK "A problem happened while adding program to Firewall exception list (result=$0)"
	Return
	Exec "rundll32.exe shell32.dll,Control_RunDLL firewall.cpl"
	MessageBox MB_OK "Program added to Firewall exception list.$\r$\n(close the control panel before clicking OK)"
	;Удаляет из списка исключений
	nsisFirewall::RemoveAuthorizedApplication "$WINDIR\Notepad.exe"
	Pop $0
	IntCmp $0 0 +3
	MessageBox MB_OK "$0"
	Return
	Exec "rundll32.exe shell32.dll,Control_RunDLL firewall.cpl"
	MessageBox MB_OK "Program removed to Firewall exception list"
SectionEnd

[MaGoth]

kotkovets, Хм, или я не понял или ты, одно из двух.
В анси кодировках текста нет возможности использовать более 2х языков, например скрипт *.nsi а в нем содержатся строки текста на русском и на английском, да здесь проблем не будет ни каких. А если как у меня - 8 языков, русский испанский немецкий и прочии и все строки текста находятся в одном *.nsi файле скрипта ?!
Имхо, в этом случае MultiLanguage.nsi летит в трубу вместе с компилятором Нсис Анси.

И будут тебе все языки, доступны в ANSI-NSIS, большинство пользователей используют ANSI сборку NSIS.

Это не так, возможно они и будут, но когда юзер станет юзать свой или другой язык в инсталлере, то вместо текста будут кракозябры по всему инсталлеру.

A Юникод в частности, в этом случае, добавляет поддержку "экзотических" языков. А многие русскоязычные пользователи крайне редко будут добавлять такую возможность, лично мне - ни к чему, достаточно английского языка, что бы тебя поняли многие.

Опять эта песня про "экзотические языки", они тут совершенно не причем.
Проблема в другом, с Юникодом все тексты - всегда и везде, будут отображаться корректно, вне зависимости от языка Системы, или того что выбрал пользователь в диалоге инсталлятора.


MfG MaGoth, WoG.ru-Community.

[kotkovets]

В анси кодировках текста нет возможности использовать более 2х языков, например скрипт *.nsi а в нем содержатся строки текста на русском и на английском, да здесь проблем не будет ни каких. А если как у меня - 8 языков, русский испанский немецкий и прочии и все строки текста находятся в одном *.nsi файле скрипта ?! »

Касательно выше цитаты, RTFM!

читать дальше »

Код:

 !include "MUI2.nsh"
  Caption "MultiLanguage Modern UI Test"
  Name "MultiLanguage Test"
  OutFile "Test MultiLanguage.exe"
;--------------------------------
 !define MUI_WELCOMEPAGE_TITLE "$(WELCOMEPAGE_TITLE)"
;--------------------------------
  !define MUI_COMPONENTSPAGE_SMALLDESC
;--------------------------------
  !insertmacro MUI_PAGE_WELCOME
  !insertmacro MUI_PAGE_INSTFILES
;--------------------------------
!define MUI_LANGDLL_ALLLANGUAGES
;--------------------------------
  !insertmacro MUI_LANGUAGE "Russian" ;first language is the default language
  !insertmacro MUI_LANGUAGE "English"
  !insertmacro MUI_LANGUAGE "German"
  !insertmacro MUI_LANGUAGE "Spanish"
  !insertmacro MUI_LANGUAGE "Indonesian"
  
  !insertmacro MUI_RESERVEFILE_LANGDLL
;--------------------------------
 Function .onInit
   !insertmacro MUI_LANGDLL_DISPLAY
 FunctionEnd
;--------------------------------
 Section
 SetAutoClose true
 SectionEnd
;--------------------------------------------------------------------
;Текст описания странички приветствия
LangString WELCOMEPAGE_TITLE ${LANG_RUSSIAN} "ДОБРО ПОЖАЛОВАТЬ!"
LangString WELCOMEPAGE_TITLE ${LANG_ENGLISH} "WELCOME!"
LangString WELCOMEPAGE_TITLE ${LANG_GERMAN} "WILLKOMMEN!"
LangString WELCOMEPAGE_TITLE ${LANG_SPANISH} "BIENVENIDO!"
LangString WELCOMEPAGE_TITLE ${LANG_INDONESIAN} "SELAMAT DATANG!"

Проблема в другом, с Юникодом все тексты - всегда и везде, будут отображаться корректно »

Это и так ясно, приведенные выше пример использования языков, будет корректно отображаться везде.

[MKN]

Ещё раз о плагине nsisFirewall.

Что то ведёт он себя на W7 странно и не стабильно. Использовал другой плагин - Simple Firewall Plugin

http://nsis.sourceforge.net/NSIS_Simple_Firewall_Plugin , к которому пока нет вопросов.