CMD/BAT - [решено] список каталогов, где находятся 2 и более файлов

amel27 · Отправлено: **10:32, 27-02-2010** | #2

Цитата neprotiv:

по 2 (и более) *.txt или по 2 (и более) *.doc »

Код:

@Echo Off

Set DIR=C:\TEST
Set MSK=*.txt *.doc

For /R "%DIR%" %%i In (.) Do If /I Not "%DIR%\."=="%%i" (
 Set ERR=& PUSHD %%i
 For /F %%a In ('2^>Nul DIR /B/A-D *.txt^|Find /C /V ""') Do If %%a GTR 1 Set ERR=1
 For /F %%a In ('2^>Nul DIR /B/A-D *.doc^|Find /C /V ""') Do If %%a GTR 1 Set ERR=1

 POPD& If Defined ERR Echo %%i
)

neprotiv · Отправлено: **10:53, 27-02-2010** | #3

чтото не то....не работает...не выдает ошибку, не создает список
amel27, у вас оно точно работает?

amel27 · Отправлено: **11:05, 27-02-2010** | #4

Цитата neprotiv:

у вас оно точно работает?»

тестовое окружение:

Код:

C:\TEST\папка1\файл1.txt
C:\TEST\папка1\файл2.txt
C:\TEST\папка1\файл3.doc

C:\TEST\папка2\файл1.txt
C:\TEST\папка2\файл2.doc

C:\TEST\папка3\файл1.txt
C:\TEST\папка3\файл2.doc
C:\TEST\папка3\файл3.doc

результат работы скрипта (на консоли):

Код:

C:\TEST\папка1\.
C:\TEST\папка3\.

как перенаправить вывод в файл:

Код:

test.cmd >test.log

neprotiv · Отправлено: **11:37, 27-02-2010** | #5

хм..странно но заработало...большое вам спасибо за помощь

neprotiv · Отправлено: **13:09, 27-02-2010** | #6

amel27, работает..но както не правильно.
показывает нужные директории и консоль закрывается
а если добавить эту строку:
test.cmd >test.log

то оно както странно сохраняет. на консоле показывает директории (и никуда не исчезает),
но когда открываешь лог то оно показывает сначала одну название папки, потом две, потом три итд.
а как только доходит до последней папки сразу все сначала записывается лог, при этом на консоле ничего не пишется

проверте это просто скопировав эти три тестовые папки по нескольку раз пожалуйста

amel27 · Отправлено: **15:33, 27-02-2010** | #7

Цитата neprotiv:

скопировав эти три тестовые папки по нескольку раз пожалуйста »

куда скопировав?.. давайте полный (воспроизводимый) расклад:
структура папок, входные параметры, результат работы батника/лог

neprotiv · Отправлено: **04:05, 28-02-2010** | #8

при запуске сот строкой - test.cmd > test.log
на консоле видно что проверяет. как только закончило проверку так сразу создается лог файл. но он сохраняется бесконечно. вот так

текст в лог файое: (после того как сразу создался файл)
C:\TEST\папка1\.

потом обновляется (через секунду или 3)
C:\TEST\папка1\.
C:\TEST\папка3\.

потом (через секунду или 3)
C:\TEST\папка1\.
C:\TEST\папка3\.
C:\TEST\папка5\.

а когда эти папки заканчиваются то вновь переписывается лог и вновь показывает
C:\TEST\папка1\.

а на консоле как показывало так и показывает
C:\TEST\папка1\.
C:\TEST\папка3\.
C:\TEST\папка5\.

если закрыть test.cmd то в лог файле сохранится лишь та часть информации которая успела сохранится

тот батник. который вы написали плюс одна строчка в конце. извините. я в этом только начинаю разбиратся.может не туда строчку скопировал

@Echo Off

Set DIR=C:\TEST
Set MSK=*.txt *.doc

For /R "%DIR%" %%i In (.) Do If /I Not "%DIR%\."=="%%i" (
Set ERR=& PUSHD %%i
For /F %%a In ('2^>Nul DIR /B/A-D *.txt^|Find /C /V ""') Do If %%a GTR 1 Set ERR=1
For /F %%a In ('2^>Nul DIR /B/A-D *.doc^|Find /C /V ""') Do If %%a GTR 1 Set ERR=1

POPD& If Defined ERR Echo %%i
)

test.cmd > test.log

amel27 · Отправлено: **10:49, 28-02-2010** | #9

Цитата neprotiv:

плюс одна строчка в конце »

эта строчка не из батника, а строка запуска этого батника
если нужно сразу из батника в файл, то можно так:

Код:

@Echo Off

Set DIR=C:\TEST
Set LOG=C:\TEST\TEST.LOG

For /R "%DIR%" %%i In (.) Do If /I Not "%DIR%\."=="%%i" (
 Set ERR=& PUSHD %%i
 For /F %%a In ('2^>Nul DIR /B/A-D *.txt^|Find /C /V ""') Do If %%a GTR 1 Set ERR=1
 For /F %%a In ('2^>Nul DIR /B/A-D *.doc^|Find /C /V ""') Do If %%a GTR 1 Set ERR=1

 POPD& If Defined ERR Echo %%i >>"%LOG%"
)

neprotiv · Отправлено: **01:08, 01-03-2010** | #10

amel27, большое вам спасибо. теперь работает как часы
спасибо