[решено] Рекурсивный поиск файла

Iska · Отправлено: **19:51, 04-02-2010** | #31

К сожалению, такой способ не сработает, поскольку несмотря на то, что chcp выполнится, и кодовая страница сменится…

Creat0R · Конфигурация компьютера

Цитата Iska:

узнает об этом изменении только команда в следующей строке, а не в текущей »

Оказывается что в таком образе даже следующая строка не принимает кодовую страницу, я пробовал создавать временный бат-файл с двумя строками, что при выводе в поток, что при выводе в файл, код. страница не меняется

madmasles · Конфигурация компьютера

Iska,
Creat0R,
Значит я был прав насчет Encoding_UDF. А то я расстроился, думал опять руки кривые.

Iska · Отправлено: **21:15, 04-02-2010** | #34

Цитата Creat0R:

Оказывается что в таком образе даже следующая строка не принимает кодовую страницу, я пробовал создавать временный бат-файл с двумя строками, что при выводе в поток, что при выводе в файл, код. страница не меняется

Хмм… Речь только про пакетные файлы? Или в трактовке чтения вывода в AutoIt? А то я что-то запутался. Для пакетных файлов у меня такое работает:

Creat0R, если не сложно, приведите Ваш код, как Вы пробовали.

Creat0R · Конфигурация компьютера

Цитата Iska:

приведите Ваш код, как Вы пробовали »

Примерно так:

Код:

$sBat = _
    '@echo off' & @CRLF & _
    'chcp 1251 > nul' & @CRLF & _
    'dir /b "' & @DesktopDir & '\*.txt"'

$hFile = FileOpen("test_dir.bat", 2)
FileWrite($hFile, $sBat)
FileClose($hFile)

$sSdOutRead = ""
$iPid = Run(@DesktopDir & '\test_dir.bat', @DesktopDir, @SW_HIDE, 2)

While 1
    $sSdOutRead &= StdoutRead($iPid)
    If @error <> 0 Then ExitLoop
WEnd

ConsoleWrite($sSdOutRead & @CRLF)

Но я ошибся немного, при тестах с выводом в файл я забыл убрать флаг указывающий на вывод в поток

- Так работает:

Код:

#include <Array.au3>

$aReturn = _FileSearch(@DesktopDir, "*.txt")
_ArrayDisplay($aReturn)

Func _FileSearch($sPath, $sFileMask)
    Local $sBatContent, $sBatFile, $sTmpFile, $hFile, $sRet, $aRet

    $sBatFile = @TempDir & "\~FileSearch.bat"
    $sTmpFile = @TempDir & "\~FileSearch.tmp"

    $sBatContent = _
        '@ECHO OFF' & @CRLF & _
        'CHCP 1251 > Nul' & @CRLF & _
        'Dir "' & $sPath & '\' & $sFileMask & '" /S /B /A RASH>"%Temp%\~FileSearch.tmp'

    $hFile = FileOpen($sBatFile, 2)
    FileWrite($hFile, $sBatContent)
    FileClose($hFile)

    RunWait($sBatFile, @TempDir, @SW_HIDE)
    $sRet = FileRead($sTmpFile)

    FileDelete($sBatFile)
    FileDelete($sTmpFile)

    $aRet = StringSplit(StringStripCR(StringStripWS($sRet, 3)), @LF)
    Return SetError(@error, 0, $aRet)
EndFunc

80971815772 · Отправлено: **03:14, 05-02-2010** | #36

есть - ф-ция у Креатора,мне она очень понравилась.Но в чем проблема...

Код:

Func _FileSearch($sPath, $sMask="*")
    If Not StringInStr(FileGetAttrib($sPath & "\"), "D") Then Return SetError(1, 0, 0)

    Local $hSearch, $sFindNext, $sFilePath, $iPathIsFolder, $i = 0, $sRet = -1
    Local $sRegExpFilter = StringReplace(StringReplace(StringReplace($sMask, ".", "\."), "*", ".*"), "?", ".")
    Local $iMax_Ret_Paths = 10000
    Local $aPathesArr[$iMax_Ret_Paths+1] = [1, $sPath]

    While $i < $aPathesArr[0]
        $i += 1

        $hSearch = FileFindFirstFile($aPathesArr[$i] & "\*")
        If $hSearch = -1 Then ContinueLoop

        While 1
            $sFindNext = FileFindNextFile($hSearch)
            If @error Then ExitLoop

            $sFilePath = $aPathesArr[$i] & "\" & $sFindNext
            $iPathIsFolder = StringInStr(FileGetAttrib($sFilePath & "\"), "D")

            If $iPathIsFolder Then
                If $aPathesArr[0] >= $iMax_Ret_Paths Then
                    $iMax_Ret_Paths *= 2
                    ReDim $aPathesArr[$iMax_Ret_Paths+1]
                EndIf

                $aPathesArr[0] += 1
                $aPathesArr[$aPathesArr[0]] = $sFilePath
            ElseIf StringRegExp($sFindNext, "(?i)\A" & $sRegExpFilter & "\z") Then
                $sRet = $sFilePath
                ExitLoop
            EndIf
        WEnd

        FileClose($hSearch)
        If $sRet <> -1 Then ExitLoop
    WEnd

    Return SetError(Number($sRet = -1), 0, $sRet)
EndFunc

можно ли както сделать,чтобы ф-ция не останавливалась только на том файле,которая нашла и запоминала путь каждого файла?
для чего мне это : хочетса сделать архив,в котором будут все найдены файлы с полными путями.

потому что пока вот что получилось... :

Код:

 	 FileCopy(_FileSearch("c:\","test.ini"),"c:\temp.ini")
	 $OF = ("c:\temp.ini")
	_ZipAdd ("c:\temp.zip",$OF)
	 FileDelete ($OF)

но это не очень удачливо просто .
может ктото , чтото посоветует..)

,kkkkkkkk

Creat0R · Конфигурация компьютера

80971815772, в оригинале эта функция таки возвращала полный список:

Код:

#include <Array.au3>

$aFiles = _FileSearch(@DesktopDir, "*.txt")

_ArrayDisplay($aFiles)

Func _FileSearch($sPath, $sMask="*")
    If Not StringInStr(FileGetAttrib($sPath & "\"), "D") Then Return SetError(1, 0, 0)

    Local $hSearch, $sFindNext, $sFilePath, $iPathIsFolder, $i = 0, $sRet = ""
    Local $sRegExpFilter = StringReplace(StringReplace(StringReplace($sMask, ".", "\."), "*", ".*"), "?", ".")
    Local $iMax_Ret_Paths = 10000
    Local $aPathesArr[$iMax_Ret_Paths+1] = [1, $sPath]

    While $i < $aPathesArr[0]
        $i += 1

        $hSearch = FileFindFirstFile($aPathesArr[$i] & "\*")
        If $hSearch = -1 Then ContinueLoop

        While 1
            $sFindNext = FileFindNextFile($hSearch)
            If @error Then ExitLoop

            $sFilePath = $aPathesArr[$i] & "\" & $sFindNext
            $iPathIsFolder = StringInStr(FileGetAttrib($sFilePath & "\"), "D")

            If $iPathIsFolder Then
                If $aPathesArr[0] >= $iMax_Ret_Paths Then
                    $iMax_Ret_Paths *= 2
                    ReDim $aPathesArr[$iMax_Ret_Paths+1]
                EndIf

                $aPathesArr[0] += 1
                $aPathesArr[$aPathesArr[0]] = $sFilePath
            ElseIf StringRegExp($sFindNext, "(?i)\A" & $sRegExpFilter & "\z") Then
                $sRet &= $sFilePath & @CRLF
            EndIf
        WEnd

        FileClose($hSearch)
    WEnd

    $sRet = StringSplit(StringStripWS($sRet, 3), @CRLF, 1)
    If @error Then Return SetError(1, 0, -1)

    Return $sRet
EndFunc

amel27 · Отправлено: **12:14, 05-02-2010** | #38

Цитата Creat0R:

забыл убрать флаг указывающий на вывод в поток »

может всё-таки через поток?..

Код:

#include <Array.au3>

$aReturn = _FileSearch(@DesktopDir, "*.txt")
_ArrayDisplay($aReturn)

Func _FileSearch($sPath, $sFileMask)
    Local $sOut = StringToBinary("0"& @CRLF, 2), $aOut
    Local $hDir = Run(@ComSpec & ' /U/C DIR "'& $sPath &'\'& $sFileMask &'" /S/B/A-D', @SystemDir, @SW_HIDE, 6)

    While 1
        $sOut &= StdoutRead($hDir, False, True)
        If @error Then ExitLoop
    Wend

    $aOut = StringRegExp(BinaryToString($sOut,2), "[^\r\n]+", 3)
    If @error Then Return SetError(1)

    $aOut[0] = UBound($aOut)-1
    Return $aOut
EndFunc

Creat0R · Конфигурация компьютера

Цитата amel27:

может всё-таки через поток? »

Супер! про ключ /U я и забыл совсем. А вот что делает «StringToBinary("0"& @CRLF, 2)» в начале?

Цитата Creat0R:

что делает «StringToBinary("0"& @CRLF, 2)» в начале? »

Кажется понял, это для добавления счётчика в нулевой элемент - хитро

madmasles · Конфигурация компьютера

amel27,
Creat0R,
Объясните, пожалуйста, про ключ /U . В справках ничего про него не нашел.