[Creat0R]

Код:

#include <File.au3>

_FileCreateShortcut(@ScriptDir & "\Folder\подфолдерс", "*.exe")

Func _FileCreateShortcut($sPath, $sFilter, $sWorkDir="", $sArgs="", $sDesc="", $sIcon="", $sHotKey="", $iIconID=0, $iState=0)
    $aFiles = _FileListToArray($sPath, $sFilter, 1)
    If @error Then Return SetError(1, 0, 0)

    For $i = 1 To $aFiles[0]
        FileCreateShortcut( _
            $sPath & "\" & $aFiles[$i], _
            $sPath & "\" & StringRegExpReplace($aFiles[$i], "\.[^\.]*$", "") & ".lnk", _
            $sWorkDir, $sArgs, $sDesc, $sIcon, $sHotKey, $iIconID, $iState)
    Next
EndFunc

[madmasles]

А у меня таким образом создается ярлык на папку, а через него получаю доступ ко всем подпапкам и файлам внутри.

Код:

FileCreateShortcut("MyFolder", "MyShortcut.lnk")

Creat0R,
У меня, почему-то, при использовании Вашей функции создаются ярлыки с именем filelnk. Поставил точку перед "lnk"

Код:

...StringRegExpReplace($aFiles[$i], "\.[^\.]*$", "") & ".lnk"...

и стало все в порядке. Почему? Точка ведь в исключениях или нет?

[semiono]

Есть проблема! Я думал сразу понятно будет....
Программы в папках лежат

Ну да я тут сам сморозил

подфолдерс \ все файлы *.exe"

можно подумать что все exe в одной папке лежат.

Но надо так:
Общий_рут\Папка_проги1\???.EXE
Общий_рут\Папка_проги2\???.EXE
Общий_рут\Папка_проги3\???.EXE

Так обычно и встречается часто. И понятно что поиск тут сложней, поэтому я и не берусь "думать"
Ярлыки лучше в общую папку слить, например на рабочий стол - %UserProfile%\Desktop
хотя это не принципиально, лишь бы они в одной паки были.

Заранее благодарю!!!

А у меня таким образом создается ярлык на папку, а через него получаю доступ ко всем подпапкам и файлам внутри. »

Поэтому и надо что у меня в подпапках дальше добираться

[madmasles]

У меня так получилось:

Код:

$avArray = _FileSearch(@ScriptDir & "\Folder", "*.exe")
DirCreate(@DesktopDir & "\MyShortcut")
For $i = 1 To $avArray[0]
    $name = StringTrimRight(StringTrimLeft($avArray[$i], StringInStr($avArray[$i], "\", "", -1)), 4)
    FileCreateShortcut($avArray[$i], @DesktopDir & "\MyShortcut\" & $name & ".lnk")
Next

Func _FileSearch($sPath, $sFileMask)
    Local $iPID, $sStdOutRead, $aRet

    $iPID = Run(@ComSpec & ' /C Dir "' & $sPath & '\' & $sFileMask & '" /S /B /A RASH', @SystemDir, @SW_HIDE, 6)

    While 1
        $sStdOutRead &= StdoutRead($iPID)
        If @error <> 0 Then ExitLoop
    WEnd

    $aRet = StringSplit(StringStripCR(StringStripWS($sStdOutRead, 3)), @LF)
    Return SetError(@error, 0, $aRet)
EndFunc   ;==>_FileSearch

PS
Функция Creat0R _FileSearch($sPath, $sFileMask)

PPS
Если в пути встречаются русские буквы, то не работает.

[madmasles]

Вот так нормально отрабатывает с русскими буквами в путях:

Код:

#include <Encoding.au3>

$avArray = _FileSearch(@ScriptDir & "\Folder", "*.exe")
DirCreate(@DesktopDir & "\MyShortcut")
For $i = 1 To $avArray[0]
    $name = StringTrimRight(StringTrimLeft($avArray[$i], StringInStr($avArray[$i], "\", "", -1)), 4)
    FileCreateShortcut(_Encoding_CyrillicTo1251($avArray[$i]), @DesktopDir & "\MyShortcut\" & $name & ".lnk")
Next

Func _FileSearch($sPath, $sFileMask)
    Local $iPID, $sStdOutRead, $aRet

    $iPID = Run(@ComSpec & ' /C Dir "' & $sPath & '\' & $sFileMask & '" /S /B /A RASH', @SystemDir, @SW_HIDE, 6)

    While 1
        $sStdOutRead &= StdoutRead($iPID)
        If @error <> 0 Then ExitLoop
    WEnd

    $aRet = StringSplit(StringStripCR(StringStripWS($sStdOutRead, 3)), @LF)
    Return SetError(@error, 0, $aRet)
EndFunc   ;==>_FileSearch

UDF от Creat0R Encoding_UDF.zip

[Creat0R]

Поставил точку перед "lnk" »

Да, это я упустил.

Вот так нормально отрабатывает с русскими буквами в путях »

А если просто добавить chcp 1251 & перед Dir?

[semiono]

Если в пути встречаются русские буквы, то не работает. »

Русские буквы в файлах втопку! Я даже с пробелами борюсь у себя. А скрипт лично мне самому надо.
Надеюсь уже не глючит, тему закрываю. Спасибо_!

[madmasles]

semiono,
Вы лучше проверьте, а то у меня работает, а у Вас не будет.
Во втором варианте ( с #include <Encoding.au3>) у меня нет проблем ни с русскими буквами, ни с пробелами в путях.

[semiono]

madmasles, я запустил скрипт (забыл путь указать реальный) и у меня один shortcut на столе создался с именем .lnk усказывает на MyComputer Но потом всё наладил! Это просто инфа к дебуг информации )
Второй скрипт я не проверял, у меня <Encoding.au3> нету, а на форум я что-то не зарегистрировался,
неужели semiono кто-то там юзает или это я был не помню Потом проверю, а инклюд лучше бы в личку сюда было. Но спасибо полюбому! П.С. Не знаю толку от меня на автоит.ру никакого, даже стыдно региться... Лишь для своей пользы чтоль