Новости
Видео
Microsoft
Windows 10
Железо
Программы
Форум

Имя пользователя:
Пароль:  
Помощь | Регистрация | Забыли пароль?  | Правила  

Компьютерный форум OSzone.net » Автоматическая установка Windows » Автоматическая установка Windows 11 / 10 / 8 / 7 / Vista » 7 / 2008 R2 - Созданиие мультиязычного установочного диска Windows 7 SP1 x86 или x64

1 2 3 11 Следующая > Последняя »
Ответить
Настройки темы
7 / 2008 R2 - Созданиие мультиязычного установочного диска Windows 7 SP1 x86 или x64

Аватара для alegz81

Старожил


Сообщения: 164
Благодарности: 47


Конфигурация

Профиль | Отправить PM | Цитировать

Изменения
Автор: alegz81
Дата: 27-03-2015
Описание: Обновление до актуального состояния
Создание установочного диска Windows 7 SP1 EN RU TR x86 или x64

ВНИМАНИЕ. Если вы работаете в 64-х битной системе, то создать файл каталога (.clg) для Windows x86 у вас не получится. (инфо)

Подготовка

Вот то что мне понадобилось для работы:
1. Установочный диск Microsoft Windows AIK для Windows 7 v 2.0 (у меня русская версия).
2. Дополнение к Microsoft Windows AIK для Windows 7 (waik_supplement_ru-ru.iso). Не обязательно.
3. VMware Workstation 11.0.0 (виртуалка).
4. Оригинальный установочный диск или образ Windows 7 SP1 EN x86 или Windows 7 SP1 EN x64.
5. Языковые пакеты для Windows 7 SP1 (Я собирал диск с тремя языками – английский, русский и турецкий. Соответственно я использовал русский и турецкий пакеты. ВНИМАНИЕ пакеты для х86 и х64 разные.).
6. Эмулятор CD-DVD (Alcohol 120%).
7. Редактор SciTE (версия 3.2.5 .99Ru) или FAR.
8. Обновления для Windows 7 SP1. Можно взять здесь, здесь, или с помощью этой программы.
9. Драйвера для контролера жестких дисков и USB 3.0 от Intel (99% компьютеров с которыми я имею дело сделаны на базе Intel).

Установите Microsoft Windows AIK для Windows 7.

После этого, если он у вас есть, смонтируйте образ waik_supplement_ru-ru.iso или вставьте в дисковод диск с ним.
Запустите командную строку от имени Администратора и выполните команду
Код: Выделить весь код
xcopy F:\ "C:\Program Files\Windows AIK\Tools\PETools" /E /H /R /Y
Где F:\ это привод с waik_supplement_ru-ru.iso.

Рекомендую установить в виртуальную машину Windows 7 SP1 x86, необходимые инструменты и все манипуляции проводить в ней.
Это гарантирует отсутствие конфликтов и ошибок из-за других программ. Так же виртуальные машины позволяют создавать снимки состояний.
Поставил Windows, установил все необходимое, настроил - создал снимок состояния.
Теперь в любой момент можно вернуться к чистой и подготовленной системе.

В статье показываю все на примере Windows 7 Ultimate SP1 x86, но все так же работает и на других редакциях и архитектурах.
Надо создать структуру папок для работы.
Вот текст батника который это делает:
Код: Выделить весь код
@echo off
SET work=%CD%\window7SP1_x86
:Start
ECHO.
ECHO Этот командный файл создает структуру папок для
ECHO работы над автоматической установкой Windows 7.
ECHO.
ECHO Для начала просто нажмите любую клавишу.
PAUSE > NUL
:CreateFolders
CLS
ECHO.
ECHO Создание папок . . .
IF NOT EXIST %work%\NUL MKDIR %work%
IF NOT EXIST %work%\DVD\NUL MKDIR %work%\DVD
IF NOT EXIST %work%\drv\NUL MKDIR %work%\drv
IF NOT EXIST %work%\ISO\NUL MKDIR %work%\ISO
IF NOT EXIST %work%\Logs\NUL MKDIR %work%\Logs
IF NOT EXIST %work%\Mount\NUL MKDIR %work%\Mount
IF NOT EXIST %work%\wim\NUL MKDIR %work%\wim
IF NOT EXIST %work%\Sandbox\NUL MKDIR %work%\Sandbox
IF NOT EXIST %work%\Updates\NUL MKDIR %work%\Updates
IF NOT EXIST %work%\xml\NUL MKDIR %work%\xml
IF NOT EXIST %work%\bootwim\NUL MKDIR %work%\bootwim
IF NOT EXIST %work%\bootwim\lp\NUL MKDIR %work%\bootwim\lp
IF NOT EXIST %work%\bootwim\mount\NUL MKDIR %work%\bootwim\mount
IF NOT EXIST %work%\winrewim\NUL MKDIR %work%\winrewim
IF NOT EXIST %work%\winrewim\mount\NUL MKDIR %work%\winrewim\mount
IF NOT EXIST %work%\mui\NUL MKDIR %work%\mui
ECHO.
ECHO Процесс создания структуры папок завершен!
pause
exit
Сохраните его в файл с названием Windows7SP1-x86.cmd в DOS(OEM866) кодировке. Это можно сделать с помощью FARа или SciTE. Скопируйте файл в то место где вы хотите создать папки и запустите. А для windows x64 сохраните в файл с названием Windows7SP1-x64.cmd, и измените строчку «SET work=%CD%\window7_x32» на «SET work=%CD%\window7SP1_x64».
Копируем весь установочный диск windows в папку ..\DVD.
В папке ..\mui я создал две папки «ru-RU» и «tr-TR», в которые соответственно и поместил языковые пакеты для Windows 7 sp1.
Напоминаю что языковые пакеты для x86 и x64 разные, и друг к другу не подходят.
Языковые пакеты для WinPE находятся на установочном диске Microsoft Windows AIK для Windows 7 в папке WinPE_LangPacks\x86 для x86, а в WinPE_LangPacks\amd64 для x64. Так же новые версии пакетов находятся на диске waik_supplement_ХХ-ХХ.iso в папке \X86\WINPE_FPS для x86, а в H:\AMD64\WINPE_FPS для x64.
Если же вы установили waik_supplement_ХХ-ХХ.iso, то языковые пакеты находятся в C:\Program Files\Windows AIK\Tools\PETools\x86\WinPE_FPs для x86, а в C:\Program Files\Windows AIK\Tools\PETools\amd64\WinPE_FPs для x64.
Я взял папки «ru-ru» и «tr-tr», и скопировал их в ..\bootwim\lp, переименовав файлы lp_ru-ru.cab и lp_tr-tr.cab в lp.cab.
В папке ..\drv создал папку sata в которую распаковал содержимое f6flpy-x86.zip (для архитектуры х64 - f6flpy-x64.zip).
Теперь все что касается USB 3.0

У компании Intel есть два контролера USB 3.0.
Первый используется с процессорами 2-го и 3-го поколений.
Второй с процессорами 4-го и 5-го поколений.
И драйвера разные. Но идентификатор одинаковый. Если интегрировать оба драйвера, то при определенной ситуации получим BSOD.
А интегрировать надо.
Большинство ноутбуков приходят теперь вообще без USB 2.0, а некоторые и без устройства для чтения CD, DVD и т.д. Так что приходиться устанавливать систему через USB.
Так же надо помнить о WinRE. Без драйверов USB 3.0 не будут работать ни тачпад, ни клавиатура, ни любая usb-периферия.
Пока решения нет. Я интегрирую драйвер для процессоров 4-го и 5-го поколений.
В папке ..\drv создал папку usbGen4-5 и скопировал туда файлы из папок ..\Drivers\Win7\x86 и ..\Drivers\HCSwitch\x86 архива Intel(R)_USB_3.0_eXtensible_Host_Controller_Driver_3.0.4.65.zip


Модификация дистрибутива

Для модификации я подготовил батник Win7Build.cmd
В батнике надо изменить параметр wd указывающий на папку с рабочим окружением -> set wd=D:\window7sp1_x86
Для временных файлов используется %wd%\Sandbox\.
Все логи записываются в %wd%\Logs\.
Перед каждым отключением образа, делается пауза.
Перед изменением install.wim, батник покажет информацию об имеющихся в нем образах и их индексах и попросит указать нужный.
Win7Build.cmd надо сохранить в DOS(OEM866) кодировке.
Запускаем с правами Администратора «Командная строка средств развертывания», и запустить батник из нее.
Например так
Код: Выделить весь код
D:\tools\Win7Build.cmd
Win7Build.cmd

Код: Выделить весь код
@Echo off
::Alegz81 2015

rem папка с рабочим окружением
set wd=D:\window7sp1_x86

ECHO Этот командный файл интегрирует языковые пакеты и драйвера в дистрибутив Windows 7 SP1
ECHO.
ECHO Выбрана папка %wd%
ECHO Для начала просто нажмите любую клавишу.
PAUSE > NUL

DEL /Q %wd%\DVD\sources\ei.cfg
DEL /Q %wd%\DVD\sources\install_*.clg

cls
::================boot.wim====================
ECHO .
ECHO Создаю резервную копию %wd%\bootwim\boot.wim.bak
copy /Y %wd%\DVD\sources\boot.wim %wd%\bootwim\boot.wim.bak
ECHO .
ECHO Просмотр имеющихся образов и их индексы в boot.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Get-WIMInfo /WimFile:%wd%\DVD\sources\boot.wim
::================index 1=====================
ECHO .
ECHO Подключение первого образа WinPE(index:1)
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-Wim /WimFile:%wd%\DVD\sources\boot.wim /index:1 /MountDir:%wd%\bootwim\mount
ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl
ECHO .
ECHO Установка языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\lp.cab /PackagePath:%wd%\bootwim\lp\tr-tr\lp.cab
ECHO .
ECHO Установка локализации пакетов
rem winpe-scripting, winpe-srt, winpe-wds-tools, winpe-wmi
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-scripting_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-scripting_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-srt_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-srt_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wds-tools_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wds-tools_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wmi_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wmi_tr-tr.cab
ECHO .
ECHO Создание нового файла lang.ini
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Gen-LangINI /distribution:%wd%\bootwim\mount
ECHO .
ECHO Установка драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Driver /Driver:%wd%\drv\sata
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Driver /Driver:%wd%\drv\usbGen4-5
ECHO .
ECHO Просмотр установленных пакетов и драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Packages
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Drivers /Format:List
ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl
ECHO Работа над первым образом boot.wim закончена
ECHO Что бы отключить образ с сохранением нажмите любую клавишу
pause > NUL
cls
ECHO Отключение образа с сохранением всех изменений
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\bootwim\mount /Commit

::================index 2=====================
ECHO .
ECHO Подключение второго образа WinPE (index:2)
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-Wim /WimFile:%wd%\DVD\sources\boot.wim /index:2 /MountDir:%wd%\bootwim\mount
ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl
ECHO .
ECHO Установка языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\lp.cab /PackagePath:%wd%\bootwim\lp\tr-tr\lp.cab
ECHO .
ECHO Установка локализации пакетов
rem winpe-scripting, winpe-setup-client, winpe-setup, winpe-srt, winpe-wds-tools, winpe-wmi
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-scripting_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-scripting_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-setup-client_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-setup-client_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-setup_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-setup_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-srt_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-srt_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wds-tools_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wds-tools_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wmi_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wmi_tr-tr.cab
ECHO .
ECHO Создание нового файла lang.ini
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Gen-LangINI /distribution:%wd%\bootwim\mount

ECHO .
ECHO Установка драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Driver /Driver:%wd%\drv\sata
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Driver /Driver:%wd%\drv\usbGen4-5
ECHO .
ECHO Просмотр установленных пакетов и драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Packages
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Drivers /Format:List
ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl
ECHO Работа над вторым образом boot.wim закончена
ECHO Что бы отключить образ с сохранением нажмите любую клавишу
pause > NUL
cls
ECHO Отключение образа с сохранением всех изменений
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\bootwim\mount /Commit

::================optimisation=================
ECHO .
ECHO Оптимизация образа boot.wim
Imagex /LogFile %wd%\Logs\imagex.log /Export %wd%\DVD\sources\boot.wim 1 %wd%\bootwim\boot[opt].wim
Imagex /LogFile %wd%\Logs\imagex.log /Export %wd%\DVD\sources\boot.wim 2 %wd%\bootwim\boot[opt].wim
ECHO .
ECHO Копирую новый boot.wim в %wd%\DVD\sources
copy /Y %wd%\bootwim\boot[opt].wim %wd%\DVD\sources\boot.wim
::================end boot.wim=================
ECHO Работа над boot.wim закончена
ECHO Начинаем работать с install.wim
pause
cls

::================install.wim==================
ECHO .
ECHO Просмотр имеющихся образов и их индексы в %wd%\DVD\sources\install.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Get-WIMInfo /WimFile:%wd%\DVD\sources\install.wim
ECHO .
set /P indx="Укажите индекс нужного образа -> "
ECHO Подключение образа № %indx%
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-WIM /WimFile:%wd%\DVD\sources\install.wim /index:%indx% /MountDir:%wd%\Mount
ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\Mount /Get-Intl
ECHO .
ECHO Установка языков
Dism /LogPath:%wd%\Logs\DISM.log /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\mui\ru-ru\lp.cab /PackagePath:%wd%\mui\tr-tr\lp.cab
ECHO .
ECHO Создание нового файла lang.ini
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\Mount /Gen-LangINI /distribution:%wd%\DVD
ECHO .
ECHO Установка драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\Mount /Add-Driver /Driver:%wd%\drv\sata
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\Mount /Add-Driver /Driver:%wd%\drv\usbGen4-5
ECHO .
ECHO Просмотр установленных драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\Mount /Get-Drivers /Format:List

::================winRE.wim===================
ECHO .
ECHO Изменение WinRE
ECHO .
ECHO Копирую WinRE.wim из %wd%\Mount\Windows\System32\Recovery\ в %wd%\winrewim
copy /Y %wd%\Mount\Windows\System32\Recovery\winRE.wim %wd%\winrewim
ECHO .
ECHO Просмотр имеющихся образов и их индексы в %wd%\winREwim\Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Get-WIMInfo /WimFile:%wd%\winrewim\winRE.wim
ECHO .
ECHO Подключение первого образа Winre.wim(index:1)
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-Wim /WimFile:%wd%\winrewim\winRE.wim /index:1 /MountDir:%wd%\winrewim\mount
ECHO .
ECHO Установка драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winrewim\mount /Add-Driver /Driver:%wd%\drv\sata
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winrewim\mount /Add-Driver /Driver:%wd%\drv\usbGen4-5
ECHO .
ECHO Просмотр установленных драйверов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winrewim\mount /Get-Drivers /Format:List
ECHO Работа над WinRE.wim закончена
ECHO Что бы отключить образ с сохранением нажмите любую клавишу
pause > NUL
cls
ECHO Отключение образа с сохранением всех изменений
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\winrewim\mount /Commit
ECHO .
ECHO Оптимизация образа WinRE.wim
Imagex /LogFile %wd%\Logs\imagex.log /Export %wd%\winrewim\winRE.wim 1 %wd%\winrewim\winRE[opt].wim
ECHO .
ECHO Копирую новый WinRE.wim в %wd%\Mount\Windows\System32\Recovery\
copy /Y %wd%\winrewim\winRE[opt].wim %wd%\Mount\Windows\System32\Recovery\winRE.wim
::================end winRE.wim===============

ECHO Работа над install.wim закончена
ECHO Что бы отключить образ с сохранением нажмите любую клавишу
pause > NUL
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\Mount /Commit

ECHO Работа закончена
ECHO Что бы выйти нажмите любую клавишу
pause > NUL

exit /b 0


Файл ответов

должен называться «AUTOUNATTEND.XML», и лежать в ..\DVD.
Запускаем «Диспетчер образов системы Windows», всё так же с правами Администратора. Открываем наш Install.wim(..\DVD\sources) – Файл-Выбрать образ Windows. Потом выбираем нужную версию Windows (у меня ULTIMATE). Появится предупреждение о том что файл каталога не найден или устарел , и его надо создать заново. Говорим «Да», и очень долго ждем. Может показаться что компьютер завис, но это не так, процедура очень долгая, особенно на слабых машинах. После завершения операции можно создавать файл ответов.
Прилагаю свой файл ответов:

x86
Код: Выделить весь код
<?xml version="1.0" encoding="utf-8"?>
<unattend xmlns="urn:schemas-microsoft-com:unattend">
    <settings pass="windowsPE">
        <component name="Microsoft-Windows-International-Core-WinPE" processorArchitecture="x86" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <SetupUILanguage>
                <WillShowUI>Always</WillShowUI>
            </SetupUILanguage>
        </component>
        <component name="Microsoft-Windows-Setup" processorArchitecture="x86" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <DiskConfiguration>
                <WillShowUI>Always</WillShowUI>
            </DiskConfiguration>
            <UserData>
                <AcceptEula>true</AcceptEula>
            </UserData>
            <ImageInstall>
                <OSImage>
                    <InstallFrom>
                        <MetaData wcm:action="add">
                            <Key>/IMAGE/INDEX</Key>
                            <Value>5</Value>
                        </MetaData>
                    </InstallFrom>
                </OSImage>
            </ImageInstall>
        </component>
    </settings>
    <settings pass="offlineServicing">
        <component name="Microsoft-Windows-LUA-Settings" processorArchitecture="x86" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <EnableLUA>false</EnableLUA>
        </component>
    </settings>
    <settings pass="specialize">
        <component name="Microsoft-Windows-Security-Licensing-SLC-UX" processorArchitecture="x86" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <SkipAutoActivation>true</SkipAutoActivation>
        </component>
        <component name="Microsoft-Windows-Deployment" processorArchitecture="x86" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <RunSynchronous>
                <RunSynchronousCommand wcm:action="add">
                    <Order>1</Order>
                    <Path>cmd /c "FOR %i IN (C D E F G H I J K L N M O P Q R S T U V W X Y Z) DO IF EXIST %i:\CD.ROM SETX DiskRoot %i: -m"</Path>
                    <Description>DVD Letter</Description>
                </RunSynchronousCommand>
            </RunSynchronous>
        </component>
    </settings>
    <settings pass="oobeSystem">
        <component name="Microsoft-Windows-Shell-Setup" processorArchitecture="x86" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <OOBE>
                <HideEULAPage>true</HideEULAPage>
                <HideWirelessSetupInOOBE>true</HideWirelessSetupInOOBE>
                <NetworkLocation>Home</NetworkLocation>
                <ProtectYourPC>3</ProtectYourPC>
                <SkipMachineOOBE>false</SkipMachineOOBE>
                <SkipUserOOBE>true</SkipUserOOBE>
            </OOBE>
            <TimeZone>West Asia Standard Time</TimeZone>
            <StartPanelOff>true</StartPanelOff>
            <ShowWindowsLive>true</ShowWindowsLive>
        </component>
    </settings>
    <cpi:offlineImage cpi:source="wim:d:/window7sp1_x86/dvd/sources/install.wim#Windows 7 ULTIMATE" xmlns:cpi="urn:schemas-microsoft-com:cpi" />
</unattend>
x64
Код: Выделить весь код
<?xml version="1.0" encoding="utf-8"?>
<unattend xmlns="urn:schemas-microsoft-com:unattend">
    <settings pass="windowsPE">
        <component name="Microsoft-Windows-International-Core-WinPE" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <SetupUILanguage>
                <WillShowUI>Always</WillShowUI>
            </SetupUILanguage>
        </component>
        <component name="Microsoft-Windows-Setup" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <DiskConfiguration>
                <WillShowUI>Always</WillShowUI>
            </DiskConfiguration>
            <UserData>
                <AcceptEula>true</AcceptEula>
                <FullName></FullName>
                <Organization></Organization>
            </UserData>
            <ImageInstall>
                <OSImage>
                    <InstallFrom>
                        <MetaData wcm:action="add">
                            <Key>/IMAGE/INDEX</Key>
                            <Value>4</Value>
                        </MetaData>
                    </InstallFrom>
                </OSImage>
            </ImageInstall>
        </component>
    </settings>
    <settings pass="offlineServicing">
        <component name="Microsoft-Windows-LUA-Settings" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <EnableLUA>false</EnableLUA>
        </component>
    </settings>
    <settings pass="specialize">
        <component name="Microsoft-Windows-Security-Licensing-SLC-UX" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <SkipAutoActivation>true</SkipAutoActivation>
        </component>
        <component name="Microsoft-Windows-Deployment" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <RunSynchronous>
                <RunSynchronousCommand wcm:action="add">
                    <Order>1</Order>
                    <Path>cmd /c "FOR %i IN (C D E F G H I J K L N M O P Q R S T U V W X Y Z) DO IF EXIST %i:\CD.ROM SETX DiskRoot %i: -m"</Path>
                    <Description>DVD Letter</Description>
                </RunSynchronousCommand>
            </RunSynchronous>
        </component>
    </settings>
    <settings pass="oobeSystem">
        <component name="Microsoft-Windows-Shell-Setup" processorArchitecture="amd64" publicKeyToken="31bf3856ad364e35" language="neutral" versionScope="nonSxS" xmlns:wcm="http://schemas.microsoft.com/WMIConfig/2002/State" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
            <OOBE>
                <HideEULAPage>true</HideEULAPage>
                <HideWirelessSetupInOOBE>true</HideWirelessSetupInOOBE>
                <NetworkLocation>Home</NetworkLocation>
                <ProtectYourPC>3</ProtectYourPC>
                <SkipMachineOOBE>false</SkipMachineOOBE>
                <SkipUserOOBE>true</SkipUserOOBE>
            </OOBE>
            <TimeZone>West Asia Standard Time</TimeZone>
            <ShowWindowsLive>true</ShowWindowsLive>
            <StartPanelOff>true</StartPanelOff>
        </component>
    </settings>
    <cpi:offlineImage cpi:source="wim:d:/window7sp1_x64/dvd/sources/install.wim#Windows 7 ULTIMATE" xmlns:cpi="urn:schemas-microsoft-com:cpi" />
</unattend>

В нём оставлена возможность выбора языка для установки, выбора диска и раздела для установки, ввод имени пользователя (не хотелось делать всех User), сетевая безопасность (ProtectYourPC) равна 3, т.е. выключена. Еак же отключен UAC.
У меня устанавливается Ultimate, это указывается здесь - 1windowsPE в x86_Microsoft-Windows-Setup__neutral-ImageInstal-OSImage-InstallFrom-MetaData-Key-/IMAGE/INDEX и Value-5(то есть устанавливать по индексу образа. Ultimate номер 5, а в x64 - 4 ).
Так же установлен часовой пояс GMT+5 (West Asia Standard Time), если хотите поменять, то это здесь - x86_Microsoft-Windows-Shell-Setup_neutral-TimeZone, который добавляется к 7 oobeSystem. Значения TimeZone можно посматреть в REGEDIT здесь - HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Time Zones.
И ещё у меня в 4specialize определяется буква DVD-привода по файлу CD.ROM, и ему назначается переменная %DiskRoot%. Что бы это заработало создайте файл-пустышку «CD.ROM» (например создайте файл Блокнота и переименуйте его, согласившись с изменением расширения), и поместите его в ..\DVD. Я ещё создавал там папку Install, и сложил туда всё что хотел установить автоматом (кряк windows7,твики и т.д.). Потом в x86_Microsoft-Windows-Shell-Setup_neutral-FirstLogonCommand, который добавляется к 7 oobeSystem создаю команды, типа такой «cmd /c %DiskRoot%\Install\setupProg.exe».
Если будете делать свой файл ответов, то в нём обязательно должно быть вот так - x86_Microsoft-Windows-International-Core-WinPE_neutral-SetupUILanguage-WillShowUI-Always в 1windowsPE. Эта настройка заставляет всегда показывать окно выбора языка для системы. Ну и для x64 вместо «x86_», будет «amd64_».

Создание загрузочного образа Windows 7

Запускаем с правами Администратора «Командная строка средств развертывания».
Указываем рабочую папку для удобства
Код: Выделить весь код
set wd=D:\window7_x86
Создание загрузочного образа x86
Код: Выделить весь код
oscdimg -h -lWindows7sp1x86 -n -m -oc -b"%wd%\DVD\boot\etfsboot.com" %wd%\DVD %wd%\ISO\windows7SP1_x86.iso
Создание загрузочного образа x64
Код: Выделить весь код
oscdimg -h -lWindows7sp1x64 -n -m -oc -b"%wd%\DVD\boot\etfsboot.com" %wd%\DVD %wd%\ISO\windows7SP1_x64.iso

Остальное в процессе создания
Здесь статья про Windows 8.1

Альтернативы, обсуждающиеся в этой теме:
Lego Project - набор для создания AIO x86-x64 от CtrlSoft

Отправлено: 14:33, 27-12-2009

 

Пользователь


Сообщения: 141
Благодарности: 9

Профиль | Отправить PM | Цитировать

Хотел объединить несколько изданий, но встал опрос и не нашел на него ответа на форуме. у меня при установке требует драйвера на контроллер. загрузочный PE взят от х86 (какой стоит брать лучше - не знаю...). При попытке установить х86 издание - говорит что не установит, так как нужны драйверы на контроллер. При выборе х64 издания - начинает установку без вопросов (при установке из под винды, но кажется тот же эффект будет при старте с DVD). и собственник сам вопрос: какой PE брать за основу и как быть с драйверами, когда разная разрядность (PE и Windows из образа)?
Это сообщение посчитали полезным следующие участники:

Отправлено: 11:03, 11-01-2010 | #2



Для отключения данного рекламного блока вам необходимо зарегистрироваться или войти с учетной записью социальной сети.

Если же вы забыли свой пароль на форуме, то воспользуйтесь данной ссылкой для восстановления пароля.


Аватара для CtrlSoft

Ветеран


Сообщения: 569
Благодарности: 169

Профиль | Сайт | Отправить PM | Цитировать

izakiel, MS рекомендует взять за основу дистрибутив х86 и туда (в образе WIM) экспортировать х64-издания.
Пример "экспорта" - http://forum.oszone.net/post-1000866-169.html

-------
Windows 7 AIO x86-x64

Отправлено: 13:07, 11-01-2010 | #3


Аватара для hvintik

Новый участник


Сообщения: 44
Благодарности: 9

Профиль | Отправить PM | Цитировать

Нужно совершить Export через утилиту ImageX
Imagex.exe /export E:\win7x64\Sources\install.wim 5 E:\win7-All\Sources\install.wim "Windows 7 Ultimate x64"
Imagex.exe /export E:\win7x86\Sources\install.wim 5 E:\win7-All\Sources\install.wim "Windows 7 Ultimate x86"

-------
если хотите сказать спасибо, просто ткните на "Полезное сообщение" под понравившимся постом.

Последний раз редактировалось hvintik, 12-01-2010 в 19:25.

Отправлено: 15:31, 11-01-2010 | #4


Аватара для alegz81

Старожил


Сообщения: 164
Благодарности: 47

Профиль | Отправить PM | Цитировать

Вложения
Тип файла: rar AUTOUNATTEND_OSZone.rar
(1.1 Kb, 920 просмотров)

Решил создать этот мануал потому что на сайте такого нет. В принципе, этот мануал можно рассматривать в более широком смысле как пошаговое руководство по созданию диска автоматической установки Windows.
Раньше создавал сборки только Windows XP, Windows Vista не пользовался и сборок не делал. Так что опыта в этом не было, приходилось пользоваться OSZone.net, справкой WAIK, головой и высоко научным методом ТЫКА. Когда начинал работу над этой сборкой у меня стояла Windows XP sp2 RU. Вот в ней я и пробовал, хотя в WAIKе прямо сказано что XP использовать нельзя, но мы же всё лучше знаем . Так вот там ПРАВИЛЬНО написано, лучше даже и не пробуйте слишком много проблем. Пришлось ставить VMware и разворачивать на ней Windows Vista sp1 RU и в ней всё мутить. Сейчас у меня Windows 7 x86 Ultim RU которую я сделал.

Итак приступим.
Подготовка:

Вот то что мне понадобилось для работы:
1. Установочный диск Microsoft Windows AIK для Windows 7 (у меня русская версия)
2. VMware Workstation 6.0 (виртуалка)
3. Оригинальный установочный диск Windows 7 EN x86 или Windows 7 EN x64
4. Языковые пакеты для Windows 7 (Я собирал диск с тремя языками – английский, русский и турецкий. Соответственно я использовал русский и турецкий пакеты. ВНИМАНИЕ пакеты для х86 и х64 разные. )
5. Эмулятор CD-DVD (Alcohol 120%)
6. Редактор SciTE (версия 1.79 .66 RU) или FAR
7. Последняя off-line версия сайта OSZone.net

Установите Microsoft Windows AIK для Windows 7.

Теперь надо создать структуру папок для работы.
Вот текст батника который это делает:
Код: Выделить весь код
@echo off
:Start
ECHO.
ECHO Этот командный файл создает структуру папок для
ECHO работы над автоматической установкой Windows 7.
ECHO.
ECHO Для начала просто нажмите любую клавишу.
PAUSE > NUL
:CreateFolders
CLS
ECHO.
ECHO Создание папок . . .
SET work=%CD%\window7_x32
IF NOT EXIST %work%\NUL MKDIR %work%
IF NOT EXIST %work%\DVD\NUL MKDIR %work%\DVD
IF NOT EXIST %work%\ISO\NUL MKDIR %work%\ISO
IF NOT EXIST %work%\Logs\NUL MKDIR %work%\Logs
IF NOT EXIST %work%\Mount\NUL MKDIR %work%\Mount
IF NOT EXIST %work%\wim\NUL MKDIR %work%\wim
IF NOT EXIST %work%\Sandbox\NUL MKDIR %work%\Sandbox
IF NOT EXIST %work%\Updates\NUL MKDIR %work%\Updates
IF NOT EXIST %work%\xml\NUL MKDIR %work%\xml
IF NOT EXIST %work%\bootwim\NUL MKDIR %work%\bootwim
IF NOT EXIST %work%\bootwim\lp\NUL MKDIR %work%\bootwim\lp
IF NOT EXIST %work%\bootwim\mount\NUL MKDIR %work%\bootwim\mount
IF NOT EXIST %work%\mui\NUL MKDIR %work%\mui
ECHO.
ECHO Процесс создания структуры папок завершен!
pause
exit
Сохраните его в файл с названием Windows7-32.cmd в DOS(OEM866) кодировке. Это можно сделать с помощью FARа или SciTE. Скопируйте файл в то место где вы хотите создать папки и запустите, учтите что на диске который вы будете использовать должно быть минимум 5 Гб свободного места. А для windows x64 сохраните в файл с названием Windows7-64.cmd, и измените строчку «SET work=%CD%\window7_x32» на «SET work=%CD%\window7_x64».
Копируем весь установочный диск windows в папку ..\DVD.

Вся работа делится на два этапа. С начала будем модифицировать Windows PE, а потом уже сам Windows 7.
Модификация Windows PE:

Windows PE (WinPE) - это операционная система в минимальной конфигурации, предназначенная для подготовки компьютера к установке Windows. А по простому это то что ставит Windows на комп. Копируем файл boot.wim из ..\DVD\sources в ..\bootwim, а файл boot.wim из ..\DVD\sources переименовываем в boot.wim.bac и перемещаем в ..\wim. Если что-либо не получится с первого раза и вы испортите файл, то у вас есть его резервная копия. Теперь нам понадобятся языковые пакеты для WinPE, они находятся на установочном диске Microsoft Windows AIK для Windows 7 в папке WinPE_LangPacks\x86 для x86, а в WinPE_LangPacks\amd64 для x64. Я взял папки «ru-ru» и «tr-tr», и скопировал их в ..\bootwim\lp.
В boot.wim находятся два образа, и модифицировать надо оба. Запускаем с правами Администратора «Командная строка средств развертывания».
Указываем рабочую папку для удобства, пишем - set wd=H:\window7_x32 (это у меня, вы подправляете под себя).
Просмотр имеющихся образов и их индексы в boot.wim
Код: Выделить весь код
Dism /Get-WIMInfo /WimFile:%wd%\bootwim\boot.wim
Подключение первого образа (index:1)
Код: Выделить весь код
Dism /Mount-Wim /WimFile:%wd%\bootwim\boot.wim /index:1 /MountDir:%wd%\bootwim\mount
Просмотр установленных языков
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Get-Intl
Просмотр установленных пакетов
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Get-Packages
У меня показывает что язык один EN, и пять пакетов – WinPE, winpe-scripting, winpe-srt, winpe-wds-tools, winpe-wmi. Нужно добавить язык для каждого пакета.
Установка языков
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\lp.cab /PackagePath:%wd%\bootwim\lp\tr-tr\lp.cab
Установка пакетов
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-scripting_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-scripting_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-srt_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-srt_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wds-tools_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wds-tools_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wmi_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wmi_tr-tr.cab
Теперь можно опять посмотреть установленные языки и пакеты для контроля. Если всё правильно, то идём дальше.
Создание нового файла lang.ini (Это нужно что бы WinPE «увидел» языки.)
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Gen-LangINI /distribution:%wd%\bootwim\mount
Отключение образа с сохранением всех изменений
Код: Выделить весь код
Dism /unmount-Wim /MountDir:%wd%\bootwim\mount /Commit
Повторить всё для индекса 2.
ВНИМАНИЕ во втором образе пакетов больше, будьте внимательны.

Подключение второго образа (index:2)
Код: Выделить весь код
Dism /Mount-Wim /WimFile:%wd%\bootwim\boot.wim /index:2 /MountDir:%wd%\bootwim\mount
Просмотр установленных языков
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Get-Intl
Просмотр установленных пакетов
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Get-Packages
У меня показывает что язык один EN, и семь пакетов – WinPE, winpe-scripting, winpe-setup-client, winpe-setup, winpe-srt, winpe-wds-tools, winpe-wmi.
Установка языков
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\lp.cab /PackagePath:%wd%\bootwim\lp\tr-tr\lp.cab
Установка пакетов
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-scripting_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-scripting_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-setup-client_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-setup-client_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-setup_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-setup_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-srt_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-srt_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wds-tools_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wds-tools_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\winpe-wmi_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\winpe-wmi_tr-tr.cab
Теперь можно опять посмотреть установленные языки и пакеты для контроля. Если всё правильно, то идём дальше.
Создание нового файла lang.ini
Код: Выделить весь код
Dism /image:%wd%\bootwim\mount /Gen-LangINI /distribution:%wd%\bootwim\mount
Отключение образа с сохранением всех изменений
Код: Выделить весь код
Dism /unmount-Wim /MountDir:%wd%\bootwim\mount /Commit
Можно сравнить размеры нашего boot.wim с оригинальным. У меня так – 137Мб и 170Мб. Теперь копируем наш boot.wim в ..\DVD\sources.

Модификация Windows 7:

Для тех кто делал в работе перерыв и закрывал «Командная строка средств развертывания», не забывайте о вводе «set wd=H:\window7_x32» при новом запуске, а то будет куча ошибок.

Ну, а теперь переходим к самому вкусному.
Подготовка.
Напоминаю что языковые пакеты для x86 и x64 разные, и друг к другу не подходят. У меня названия пакетов были какие-то не произносимые, и я их переименовал в lp.cab. В папке ..\mui я создал две папки «ru-RU» и «tr-TR», в которые соответственно и поместил пакеты. Теперь можно и начать.
Просмотр имеющихся образов и их индексы в install.wim
Код: Выделить весь код
Dism /Get-WIMInfo /WimFile:%wd%\DVD\sources\install.wim
Я работаю только с ULTIMATE, ну а вы можете с той версией Windows Которая вам нужна.
Подключение образа ULTIMATE (в х86 индекс равен 5, а в х64 равен 4)
Код: Выделить весь код
Dism /Mount-WIM /WimFile:%wd%\DVD\sources\install.wim /index:5 /MountDir:%wd%\Mount    (х86)

Dism /Mount-WIM /WimFile:%wd%\DVD\sources\install.wim /index:4 /MountDir:%wd%\Mount    (х64)
Надеюсь все поняли – ПИСАТЬ ТО ЧТО В СКОБКАХ НЕ НАДО!!!
Просмотр установленных языков
Код: Выделить весь код
Dism /image:%wd%\Mount /Get-Intl
Кстати в Windows уже вставлено несколько пакетов. Можете на них посмотреть
Код: Выделить весь код
Dism /image:%wd%\Mount /Get-Packages
Установка языков
Код: Выделить весь код
Dism /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\mui\ru-RU\lp.cab /PackagePath:%wd%\mui\tr-TR\lp.cab
Параметр /ScratchDir:%wd%\Sandbox указывает на папку для временных файлов. Если его убрать, то будет использована %TEMP%.

Теперь можно опять посмотреть установленные языки и пакеты, и если всё в порядке –
Отключение образа с сохранением всех изменений
Код: Выделить весь код
Dism /unmount-Wim /MountDir:%wd%\Mount /Commit
У меня на компе все это занимает примерно 45 мин. Но это ещё не всё.
Теперь запускаем «Диспетчер образов системы Windows», всё так же с правами Администратора. Открываем наш Install.wim(..\DVD\sources) – Файл-Выбрать образ Windows. Потом выбираем нужную версию Windows (у меня ULTIMATE). Появится предупреждение о том что файл каталога устарел, и его надо создать заново. Говорим «Да», и очень долго ждем. Может показаться что компьютер завис, но это не так, процедура очень долгая, особенно на слабых машинах. После завершения операции можно создавать файл ответов.
На эту тему есть свой раздел, так что подробно об этом не буду, только напомню он должен называться «AUTOUNATTEND.XML», и лежать в ..\DVD. Прилагаю свой файл ответов. В нём оставлена возможность выбора языка для установки, выбора диска и раздела для установки, ввод имени пользователя (не хотелось делать всех User), сетевая безопасность (ProtectYourPC) равна 3, т.е. выключена . У меня устанавливается Ultimate, это указывается здесь - 1windowsPE в x86_Microsoft-Windows-Setup__neutral-ImageInstal-OSImage-InstallFrom-MetaData-Key-/IMAGE/INDEX и Value-5(то есть устанавливать по индексу образа. Ultimate номер 5, а в x64 - 4 ). Так же установлен часовой пояс GMT+5, если хотите поменять, то это здесь - x86_Microsoft-Windows-Shell-Setup_neutral-TimeZone, который добавляется к 7 oobeSystem. Значения TimeZone можно посматреть в REGEDIT здесь - HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Time Zones. И ещё у меня в 4specialize определяется буква DVD-привода по файлу CD.ROM, и ему назначается переменная %DiskRoot%. Что бы это заработало создайте файл-пустышку «CD.ROM» (например создайте файл Блокнота и переименуйте его, согласившись с изменением расширения), и поместите его в ..\DVD. Я ещё создавал там папку Install, и сложил туда всё что хотел установить автоматом (кряк windows7,твики и т.д.). Потом в x86_Microsoft-Windows-Shell-Setup_neutral-FirstLogonCommand, который добавляется к 7 oobeSystem создаю команды, типа такой «cmd /c %DiskRoot%\Install\setupProg.exe».
Если будете делать свой файл ответов, то в нём обязательно должно быть вот так - x86_Microsoft-Windows-International-Core-WinPE_neutral-SetupUILanguage-WillShowUI-Always в 1windowsPE. Эта настройка заставляет всегда показывать окно выбора языка для системы. Ну и для x64 вместо «x86_», будет «amd64_».

Интеграция обновлений в Windows 7:

Если у вас нет обновлений, то можете перейти к созданию загрузочного образа.
Обновления для windows имеют расширение MSU.
У меня было 49 файлов в 3-х категориях - критические, важные и обновления для .Net.
В папке ..\Updates я создал папки Critical, Important и NET, в которые и разложил обновления.
Запускаем с правами Администратора «Командная строка средств развертывания». Не забываем про «set wd=H:\window7_x32».
Подключение образа
Код: Выделить весь код
Dism /Mount-WIM /WimFile:%wd%\DVD\sources\install.wim /index:5 /MountDir:%wd%\Mount
Просмотр установленных пакетов
Код: Выделить весь код
Dism /image:%wd%\Mount /Get-Packages
установка обновлений
Код: Выделить весь код
Dism /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\Updates\Critical /PackagePath:%wd%\Updates\Important /PackagePath:%wd%\Updates\NET
Отключение образа с сохранением всех изменений
Код: Выделить весь код
Dism /unmount-Wim /MountDir:%wd%\Mount /Commit
Теперь надо обновить файл каталога. Запускаем «Диспетчер образов системы Windows», всё так же с правами Администратора. Открываем наш Install.wim(..\DVD\sources) – Файл-Выбрать образ Windows. Потом выбираем нужную версию Windows (у меня ULTIMATE).
После того, как каталог обновится и образ откроется, в ветке Packages появятся подветки hotFix, Update и т.д. В которых и можно посмотреть установленные обнавления.

Создание загрузочного образа Windows 7:

Запускаем с правами Администратора «Командная строка средств развертывания». Не забываем про «set wd=H:\window7_x32».
Создание загрузочного образа x86
Код: Выделить весь код
oscdimg -n -m -o -b"C:\Program Files\Windows AIK\Tools\PETools\x86\boot\etfsboot.com" %wd%\DVD %wd%\ISO\windows7_x86.iso
Создание загрузочного образа x64
Код: Выделить весь код
oscdimg -n -m -o -b"C:\Program Files\Windows AIK\Tools\PETools\amd64\boot\etfsboot.com" %wd%\DVD %wd%\ISO\windows7_x64.iso
Если у вас WAIK установлен не в C:\Program Files, то корректируем путь.


Вот так у нас появился 3-х язычный диск Windows 7 Ultimate EN RU TR, с возможностью выбора языка установки, места установки, имени пользователя и его пароля. Так как ключ продукта в файл ответа не введён, то появится окно где его предложат ввести. Ключ можно не вводить, а галочку с пункта об автоматической регистрации Windows по Internet снять, и получите систему на 30 дней. Ну а там уж сами, сами ).

Сборку Windows x86 по приведенному рецепту я создал в декабре 2009. Она была поставлена на большое количество компов, как десктопов, так и ноутов. Везде работает отлично, ни каких косяков и проблем. Сборку Windows x64 сделал месяц назад. Установил на четырёх компах. Пока проблем нет. Сейчас работаю над диском Windows7 x86+x64.

Осталось только проверить.
Устанавливаем VMware Workstation и Alcohol 120%. Монтируем наш образ на виртуальный привод. Создаём в VMware виндовус, и ставим. Одно но, таким образом удастся проверить только Windows x86. А вот x64 не пойдёт, нужна реальная машина, но если ваша система x64, то всё пойдёт.
А под конец один совет – если вы ставите Windows 7 на машину в первый раз, то обязательно из программы установки удалите тот раздел на который будете ставить, и создайте его заново. При этом вам будет предложено создать скрытый раздел на 100Мб, куда будет записан виндовский загрузчик.
Хочу поблагодарить Мишу за установочный диск Windows 7 EN x86, и за русский языковой пакет для x86. Так же большое спасибо Мердану за установочный диск Windows 7 EN x64, установочный диск Microsoft Windows AIK для Windows 7, обновления для Windows 7 x86 и x64 и за языковые пакеты для x64. И благодарность группе "Linkin Park", чья музыка способствует усилению мозговой активности.
Ну вот и всё. Надеюсь этот мануал, а вернее статья кому-нибудь будут полезны. Если найдёте неточности или ошибки, а так же мысли об улучшении приведенного здесь, то сообщите. Всегда готов учиться.

Последний раз редактировалось alegz81, 10-09-2010 в 18:50. Причина: добавлено описание интеграции обновлений

Это сообщение посчитали полезным следующие участники:

Отправлено: 04:42, 15-03-2010 | #5


Пользователь


Сообщения: 85
Благодарности: 11

Профиль | Отправить PM | Цитировать

Цитата alegz81:
Сейчас работаю над диском Windows7 x86+x64. »
Разобрался куда при сборке класть два разных файла ответов (для х86 и х64)?

Отправлено: 02:03, 05-05-2010 | #6


(*.*)


Сообщения: 36538
Благодарности: 6689

Профиль | Сайт | Отправить PM | Цитировать

Цитата north7:
Разобрался куда при сборке класть два разных файла ответов (для х86 и х64)? »
ответ

-------
Канал Windows 11, etc | Чат @winsiders

Это сообщение посчитали полезным следующие участники:

Отправлено: 10:09, 05-05-2010 | #7


Пользователь


Сообщения: 107
Благодарности: 10

Профиль | Отправить PM | Цитировать

Привет !
Наскока мне известно программа Sun Virtual Boox 3.1.4.57640 поддерживает виртуализацию х64 сам не пробЫвал но привыборе она есть .
В файле ответов можно отключить как ввод ключа так и активацию!
Атак прекрасно надо попробовать!

Да для интеграции языковых пакетов и обновлений есть прекрасная программа называется она W7Mount.
Спасибо за путь в реестре наверняка его можно попробовать использовать в качестве твика приустановке системы.

Отправлено: 18:06, 05-05-2010 | #8


Аватара для alegz81

Старожил


Сообщения: 164
Благодарности: 47

Профиль | Отправить PM | Цитировать

north7, первым вариантом сделал один общий файл ответов для x86 и x64.
Сейчас сделал сборку с использованием этого . Тестирую.

Fraim, VMware Workstation тоже поддерживает x64, но вот только на x86 ты её не запустишь, тоже самое и в Sun Virtual Boox.

-------
Создание сборки Windows 7 SP1
Создание сборки Windows 8.1

Отправлено: 06:40, 07-05-2010 | #9


(*.*)


Сообщения: 36538
Благодарности: 6689

Профиль | Сайт | Отправить PM | Цитировать

alegz81, пожалуйста, исправьте сообщение - используйте тег [code] для обрамления команд и фрагментов файла ответов.

-------
Канал Windows 11, etc | Чат @winsiders

Отправлено: 10:25, 13-06-2010 | #10

1 2 3 11 Следующая > Последняя »


Компьютерный форум OSzone.net » Автоматическая установка Windows » Автоматическая установка Windows 11 / 10 / 8 / 7 / Vista » 7 / 2008 R2 - Созданиие мультиязычного установочного диска Windows 7 SP1 x86 или x64

Участник сейчас на форуме Участник сейчас на форуме Участник вне форума Участник вне форума Автор темы Автор темы Шапка темы Сообщение прикреплено

Похожие темы
Название темы Автор Информация о форуме Ответов Последнее сообщение
Разное - [решено] MS Windows XP: есть наклейка с лиц. ключом, но нет установочного диска... CyraxZ Лицензирование продуктов Microsoft 3 08-02-2010 08:25
Разное - [решено] нужно ли создавать диск восстановления или достаточно установочного диска? forkatt Microsoft Windows 7 1 11-11-2009 10:05
Установка - [решено] x86 или x64? Crush45 Microsoft Windows Vista 3 12-10-2009 16:06
Загрузка - windows не загружается без диска(установочного) Ride Microsoft Windows 2000/XP 6 02-02-2008 16:55
Проблема установки Windows XP с установочного диска paZZZitif Непонятные проблемы с Железом 14 15-01-2008 22:07


« Предыдущая тема | Следующая тема »


 
Переход