[amel27]

на базе первого варианта:

Код:

@Echo Off
SetLocal EnableExtensions

Set F=XXX
Set T=%~dpn0.tmp

If Exist "%T%" DEL /F/Q "%T%"
For %%D In (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) Do (
  For /F "Delims=" %%I In ('Dir %%D:\%F%.* /AD/B/S 2^>nul') Do (
    If Exist "%%I" If /I "%%~nxI"=="%F%" (
      Echo %%I
      Echo %%I>>"%T%"
    )
  )
)
If Not Exist "%T%" Echo Каталогов не обнаружено.& Exit
For /F %%i In ('TYPE "%T%"^|Find /C /V ""') Do Set C=%%i
Echo Найдено %C% каталогов...

:D_LOOP
Set /P D=Просмотреть список найденных еще раз? (Y/N)
If /I Not "%D%"=="Y" If /I Not "%D%"=="N" GoTo D_LOOP
If /I "%D%"=="N" GoTo R_LOOP
MORE "%T%"& GoTo D_LOOP

:R_LOOP
Set /P R=Удалить все найденные каталоги? (Y/N)
If /I Not "%R%"=="Y" If /I Not "%R%"=="N" GoTo R_LOOP
If /I "%R%"=="N" Exit

For /F "UseBackQ Delims=" %%i In ("%T%") Do RD /S/Q "%%i"

[volk1234]

Код:

If Not Exist "%T%" Echo Каталогов не обнаружено.& Exit

Вот здесь не очень удачно реализовано,
надпись не успеваешь увидеть. Может пинг какой всобачить?

[gora]

Может пинг какой всобачить? »

Возможные варианты:

Код:

rem остановка скрипта
If Not Exist "%T%" Echo Каталогов не обнаружено.& Pause>Nul& Exit

rem пауза на 5 с
If Not Exist "%T%" Echo Каталогов не обнаружено.& ping -n 6 localhost>Nul& Exit

rem подача звукового сигнала + задержка (каждый BEEP ~ 0.5 с) Код BEEP = 07H
If Not Exist "%T%" Echo Каталогов не обнаружено.& Exit

[PFMAX]

Как удалить папку со всеми вложенными файлами (без подтверждения на удаление) ? XPSP-3
пример бы

[amel27]

PFMAX,

Код:

RD /S /Q "C:\TEST"

[Ctrec]

PFMAX,

Код:

set dir=C:\test
pushd %dir%
if not errorlevel 1 rd /s /q . >nul 2>nul
popd
rd %dir% :: Если надо удалить папку...

Как то так...