[Berline]

Очередной вопрос ламера:

Каким образом мы можем сделать следущее - если ставим в 1й раз, и программа определила, что каталога назначения нету - все проходит на ура - а если ставим уже поверх установленной программы - чтоб сперва удалил ярлыки которые были выведены, удалил папку назначения - и уже поставил ка бы с 0(с учетом что настройки программы хранятся в реестре, их удалять нельзя)

[DemonAk]

Можно, только поподробней объясните, что вы хотите сделать и что должно выполниться из секции кода. »

Распаковываются архивы freearc'a с помощью скрипта и dll Bulata Ziganshina. Дело в том что когда сначала копируются файлы и создаются ярлыки они выгледят на раб столе без картинок т.к. файлы содержащие их еще не распаковались а после распаковки приходится нажимать на рабочем столе обновить. А вообще сейчас сказав про это, возможно ли сделать что бы ярлыки создавались последними.

[Serega]

Berline, а не проще поставить поверх программу?
Теоретически, конечно можно определить куда были установлены ярлыки в HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\..._isl, удалить их и удалить всю папку приложения, но как быть с хвостами в реестре? т.е. после удаления второй программы, они так и останутся мусором в системе пользователя...

Дело в том что когда сначала копируются файлы и создаются ярлыки они выгледят на раб столе без картинок т.к. файлы содержащие их еще не распаковались а после распаковки приходится нажимать на рабочем столе обновить. »

Решается очень просто, добавьте в секцию [Setup]:
ChangesEnvironment=yes

Описание

Возможные значения: yes или no Значение по умолчанию: no Описание: При значении yes по завершению установки инсталлятор сообщит другим запущенным приложениям (в том числе Проводнику), чтобы они перезагрузили переменные среды (environment variables) из реестра. На NT-платформах Windows, если инсталлятор создает или изменяет переменную среды (environment variable), а директиве ChangesEnvironment не присвоено значение yes, новая/обновленная переменная среды не будет доступна для приложений, запущенных из Проводника, до тех пор, пока пользователь не завершит сеанс или не перезагрузит компьютер.

[Berline]

Serega, не, вот "мусор" в реестре как раз надо оставить... а ярлыки, и папку с программой снести

[R.i.m.s.k.y.]

Искал, не нашел.

Подскажите пожалуйста, как можно сохранить в Inno изменяемые ветки реестра перед установкой программы (желательно автоматом, уж больно много), и восстановить реестр при деинсталляции программы?

Заранее спасибо.

[Serega]

Подскажите пожалуйста, как можно сохранить в Inno изменяемые ветки реестра перед установкой программы (желательно автоматом, уж больно много), и восстановить реестр при деинсталляции программы? »

Пример

Код:

[Setup]
AppName=RegBackup
AppVerName=Registry Backup
CreateAppDir=false

[Registry]
;если используется функция RegBackup, то желательно удалять ключ или параметр при деинсталляции (флаги deletevalue или uninsdeletekey), чтобы не оставались записи реестра, которых не было до установки.
Root: HKCU; SubKey: Control Panel\Desktop; ValueType: none; ValueName: Wallpaper; Flags: deletevalue uninsdeletevalue; BeforeInstall: RegBackup('HKCU\Control Panel\Desktop')

[Run]
Filename: {uninstallexe}; Flags: nowait postinstall; Description: Восстановить обои Рабочего стола; Parameters: /SILENT
Filename: {cmd}; Parameters: /C del /F /Q /AH IconCache.db; Flags: runhidden nowait; WorkingDir: {code:GetFolderByCSIDL|28}

[code]
function SystemParametersInfo(uAction, uParam: integer; pvParam: longint; fUpdateProfile: integer): boolean; external 'SystemParametersInfoA@user32';

// получить путь к папке. Пример: DestDir: {code:GetFolderByCSIDL|28}
function GetFolderByCSIDL(CSIDL: String): String;
begin
  Result:= GetShellFolderByCSIDL(StrToInt(CSIDL), true);
end;

// Зарезервировать параметры указанного раздела реестра или Восстановить записи реестра из резервной копии
Procedure RegBackup(Path: String);
var
  errCode, n: Integer;
  RegExe, isKey: String;
  Keys: TArrayOfString;
begin
  RegExe:= AddBackslash(GetSystemDir) + 'reg.exe'
  if not FileExists(RegExe) then begin
    MsgBox('Registry backup not created' #13#10 'File reg.exe not found!', mbError, MB_OK);
    Exit;
  end;
	isKey:= 'HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\{#SetupSetting('AppName')}_regBackup'	{! InnoSetup удаляет чужие ключи в AppName_is1}
	if Length(Path) > 0 then
		Exec(RegExe,'copy '+ AddQuotes(Path) +' '+ AddQuotes(AddBackslash(isKey) + Path) +' /s /f','',sw_HIDE, ewWaitUntilTerminated, errCode)
	else begin
		if not RegGetSubkeyNames(HKLM, Copy(isKey, 6,Length(isKey)), Keys) then Exit; { нет резервных записей}
	for n:= 0 to GetArrayLength(Keys) -1 do	{ reg.exe не может сохранять в корень реестра}
		Exec(RegExe, 'copy '+ AddQuotes(AddBackslash(isKey) + Keys[n]) +' '+ Keys[n] +' /s /f','', sw_HIDE, ewWaitUntilTerminated, errCode)
  	RegDeleteKeyIncludingSubkeys(HKLM, Copy(isKey, 6,Length(isKey)))
	end;
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssPostInstall then SystemParametersInfo(20,0,0,2) { update Desktop}
end;

procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
begin
	if CurUninstallStep = usPostUninstall then begin
    RegBackup(''); SystemParametersInfo(20,0,0,2)
  end;
end;

[R.i.m.s.k.y.]

Пример »

эээ, не совсем понятно какой кусок кода какой ключ сохраняет. Ну не силен я в Паскале.
Буду благодарен за простой кусок кода по сути в качестве примера, по аналогии я его размножу.

В принципе можно сделать reg export с параметрами, но выполнить его надо ДО секции [Registry]. Это второй вопрос - в какой последовательности выполняется скрипт Inno и как это сделать.

[Serega]

вот "мусор" в реестре как раз надо оставить... а ярлыки, и папку с программой снести »

как говорят: хозяин - барин...

Пример

Код:

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
AllowNoIcons=yes
OutputDir=.
;отключаем сообщение о существовании папки
DirExistsWarning=no
;не использовать папку, которую выбрал пользователь в прошлый раз
UsePreviousAppDir=no
;не использовать группу меню Пуск, выбранную пользователем при предыдущей установке
UsePreviousGroup=no
;не использовать тип установки, выбранный пользователем в прошлый раз
UsePreviousSetupType=no
;не использовать задания, которые выбрал пользователь при прошлой установке
UsePreviousTasks=no
;имя пользователя, название организации и серийный номер, которые ввел пользователь при предыдущей установке
UsePreviousUserInfo=no
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked
Name: quicklaunchicon; Description: {cm:CreateQuickLaunchIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[InstallDelete]
; делаем пустую команду, чтоб выполнить код перед установкой
Name: ''; Type: files; BeforeInstall: DeleteAppAndLnk

[Files]
Source: compiler:Examples\MyProg.exe; DestDir: {app}; Flags: ignoreversion

[Icons]
Name: {group}\My Program; Filename: {app}\MyProg.exe
Name: {group}\{cm:ProgramOnTheWeb,My Program}; Filename: http://www.example.com/
Name: {group}\{cm:UninstallProgram,My Program}; Filename: {uninstallexe}
Name: {commondesktop}\My Program; Filename: {app}\MyProg.exe; Tasks: desktopicon
Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\My Program; Filename: {app}\MyProg.exe; Tasks: quicklaunchicon

[Run]
Filename: {app}\MyProg.exe; Description: {cm:LaunchProgram,My Program}; Flags: nowait postinstall skipifsilent

[code]
// узнаём путь к папке
function GetGroupPath: string;
var
  i, k: Integer;
  s: string;
begin
  s:= ExpandConstant('{group}');
    repeat
      if s[Length(s)] <> '\' then
      Delete(s, Length(s), 1);
    until s[Length(s)] = '\';
  Result:= s;
end;

procedure DeleteAppAndLnk;
var
  RootKey: Integer;
  SubKeyName, ValueData: string;
begin
  RootKey:= HKEY_LOCAL_MACHINE;
  SubKeyName:= 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\My Program_is1';
  if RegKeyExists(RootKey, SubKeyName) = True then begin
    if RegValueExists(RootKey, SubKeyName, 'InstallLocation') = True then
     // проверяем, куда была установлена программа
      if RegQueryStringValue(RootKey, SubKeyName, 'InstallLocation', ValueData) = True then
      ValueData:= Copy(ValueData, 1, Length(ValueData)-1);
      // проверяем, существует ли папка
      if DirExists(ValueData) = True then
      // удаляем папку
      DelTree(ValueData, True, True, True);
      if RegValueExists(RootKey, SubKeyName, 'Inno Setup: Icon Group') = True then
      // узнаём название группы
      if RegQueryStringValue(RootKey, SubKeyName, 'Inno Setup: Icon Group', ValueData) = True then
       // проверяем, существует ли папка в меню Пуск
       if DirExists(GetGroupPath + ValueData) = True then
       // если да, то удаляем папку
       DelTree(GetGroupPath + ValueData, True, True, True);
       // проверим рабочий стол
       if FileExists(ExpandConstant('{commondesktop}\My Program.lnk')) = True then
      DeleteFile(ExpandConstant('{commondesktop}\My Program.lnk'));
      // проверим панель быстрого запуска
     if FileExists(ExpandConstant('{userappdata}\Microsoft\Internet Explorer\Quick Launch\My Program.lnk')) = True then
    DeleteFile(ExpandConstant('{userappdata}\Microsoft\Internet Explorer\Quick Launch\My Program.lnk'));
  end;
end;

[Serega]

простой кусок кода по сути в качестве примера, по аналогии я его размножу. »

Пример

Код:

[Setup]
AppName=My Program
AppVerName=My Program 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl

[Files]
Source: compiler:Examples\MyProg.exe; DestDir: {app}; AfterInstall: BackupReg; Flags: ignoreversion

[code]
procedure BackupReg;
var
  res: Integer;
  BackupDir, Key, RegEdit: string;
begin
  Key:= 'HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Inno Setup 5_is1';
	BackupDir:= ExpandConstant('{app}');
  RegEdit:= ExpandConstant('{win}\regedit.exe');
	Exec(RegEdit, '-ea backup.reg ' + AddQuotes(Key), BackupDir, SW_HIDE, ewWaitUntilTerminated, Res);
end;

procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
var
  res: Integer;
  reg: string;
begin
  reg:= ExpandConstant('{app}\backup.reg');
  if CurUninstallStep = usUninstall then begin
    // при деинсталляции, заносим ключ в реестр
    if FileExists(reg) = True then
    Exec('regedit.exe',' /s ' + AddQuotes(reg),ExpandConstant('{win}'),SW_HIDE,ewWaitUntilTerminated,res);
  end;
end;

[Krekerpro]

Помогите пожалуйста:раньше использовал скрипт от z10y_ded,всё нормально работало,но после переустановки винды,почему то по не понятным причинам,при начале он мне выдаёт ошибку http://clip2net.com/page/m0/1228857