[Iska]

И что? Для класса WshURLShortcut свойство IconLocation не поддерживается.

Вы можете создать url-ярлык, затем открыть его как обычный текстовый файл и тупо дописать две строки, например:

Скрытый текст

Код:

Option Explicit

Const ForAppending = 8

Dim strPath2UrlFile


strPath2UrlFile = "C:\Мои проекты\0074\My.url"

With WScript.CreateObject("WScript.Shell").CreateShortcut(strPath2UrlFile)
	.TargetPath = "http://forum.oszone.net/thread-327113.html"
	.Save
	WScript.Echo .FullName
End With

With WScript.CreateObject("Scripting.FileSystemObject").OpenTextFile(strPath2UrlFile, ForAppending)
	.WriteLine "IconFile=C:\Windows\system32\SHELL32.dll"
	.WriteLine "IconIndex=27"
End With

WScript.Quit 0

[Zerstoren]

strPath2UrlFile = "C:\Мои проекты\0074\My.url" »

а как сюда засунуть

PHP код:

strDesktop = WshShell.SpecialFolders("Desktop") 

 Set oUrlLink = WshShell.CreateShortcut(strDesktop & "\ссылка.url") 

[Zerstoren]

Вы можете создать url-ярлык, затем открыть его как обычный текстовый файл и тупо дописать две строки, например: »

почему-то иконку через тотал видно, а через проводник белый листок (я свои поставил значения, но разницы нет)

код

PHP код:

Option Explicit

Const ForAppending = 8

Dim strPath2UrlFile

strPath2UrlFile = "C:\Users\Admin\Desktop\ярлык.url"

With WScript.CreateObject("WScript.Shell").CreateShortcut(strPath2UrlFile)
    .TargetPath = "http://yandex.ru"
    .Save
    WScript.Echo .FullName
End With

With WScript.CreateObject("Scripting.FileSystemObject").OpenTextFile(strPath2UrlFile, ForAppending)
    .WriteLine "IconFile=C:\Windows\system32\SHELL32.dll"
    .WriteLine "IconIndex=27"
    .WriteLine "HotKey=0"
End With

WScript.Quit 0 

содержание url через блокнот

[{000214A0-0000-0000-C000-000000000046}]
Prop3=19,2
[InternetShortcut]
URL=http://yandex.ru
IDList=
IconFile=C:\Windows\system32\SHELL32.dll
IconIndex=27
HotKey=0

[Iska]

а через проводник белый листок »

содержание url через блокнот »

У меня — нормально:

Скрытый текст

«WScript.Echo .FullName» можно убрать — это по недосмотру оставил.

а как сюда засунуть… »

Например. так:

Скрытый текст

Код:

Option Explicit

Const ForAppending = 8

Dim strUrlFileName

Dim objFSO
Dim strPath2UrlFile


strUrlFileName = "ссылка.url"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

With WScript.CreateObject("WScript.Shell")
	strPath2UrlFile = objFSO.BuildPath(.SpecialFolders("Desktop"), strUrlFileName)
	
	With .CreateShortcut(strPath2UrlFile)
		.TargetPath = "http://yandex.ru"
		.Save
	End With
End With
	
With objFSO.OpenTextFile(strPath2UrlFile, ForAppending)
	.WriteLine "IconFile=C:\Windows\system32\SHELL32.dll"
	.WriteLine "IconIndex=27"
End With

Set objFSO = Nothing

WScript.Quit 0

Кстати: использование раскрытие пути к специальной папке Рабочий стол вместо прямого задания пути — правильный подход, Вы совершенно правы.

[Zerstoren]

У меня — нормально: »

А у меня нет, даже на нулевой виртуалке


Изменяет иконку после второго запуска скрипта
Странно, почему

[Iska]

Изменяет иконку после второго запуска скрипта »

А если после первого (и единственного) запуска выделить что-нибудь на Рабочем столе и нажать F5?

[Zerstoren]

нажать F5? »

да хоть занажимайся

[Iska]

да хоть занажимайся »

Давайте ещё одно посмотрим, если Вы не против. Вам оно, конечно, ни к чему, а мне интересно. Если, опять же, с нуля создать ярлык скриптом, а затем завершить сеанс пользователя и заново войти в систему — ярлык отобразится со значком?

[Zerstoren]

Iska, все сработало!!
тема закрыта