[diagnoz_]

делал так - msinfo32 /computer имя_ПК /report D:\имя_ПК.txt получаю имя_пк.txt, но файл со всем цифровым мусором внутри, все что только можно. пробовал получить справку с параметром msinfo32 /showcategories, /categories, /category , но мне средство msinfo32 просто собирает инфу о моем, локальном компьютере. получается, что msinfo32 игнорирует те компоненты которые я ей указываю для сбора.

[Iska]

diagnoz_, смотрите в сторону Wbem. Это wmic.exe для командной строки, и ровно те же классы для использования посредством Automation в WSH/PoSH: Win32_ComputerSystem, Win32_Baseboard и т.д.

[alpap]

Код:

@echo off
for /f "delims=" %%a in ('"wmic path Win32_OperatingSystem get Caption,CSDVersion,Version,BuildNumber,BuildType,OSArchitecture,RegisteredUser,SerialNumber,WindowsDirectory /value|find "^=""') do set "%%a"
for /f "delims=" %%a in ('"wmic path Win32_ComputerSystem get Manufacturer,Model,SystemType,TotalPhysicalMemory,UserName,Workgroup /value|find "^=""') do set "%%a"
for /f "delims=" %%a in ('"wmic path Win32_VideoController get VideoProcessor,CurrentHorizontalResolution,CurrentVerticalResolution,AdapterDACType,AdapterRAM /value|find "^=""') do set "%%a"
for /f "delims=" %%a in ('"wmic path Win32_SoundDevice get ProductName /value|find "^=""') do set "%%a"
for /f "delims=" %%a in ('"wmic path Win32_Processor get Name,NumberOfCores /value|find "^=""') do set "%%a"
for /f "delims=" %%a in ('"wmic path Win32_NetworkAdapter where NetConnectionStatus=2 get Description,NetConnectionID,Speed,MACAddress /value|find "^=""') do set "%%a"
>>"info.txt" (
 echo Система
 echo Название ОС:                   %Caption:~,-2%
 echo Версия ОС:                     %Version% %CSDVersion% сборка %BuildNumber%
 echo Тип ОС:                        %BuildType% ^(%OSArchitecture%^)
 echo Код продукта:                  %SerialNumber%
 echo Папка Windows:                 %WindowsDirectory%
 echo Зарегистрированный владелец:   %RegisteredUser% 
 echo Изготовитель системы:          %Manufacturer%
 echo Модель системы:                %Model%
 echo Тип системы:                   %SystemType%
 echo Системная память:              %TotalPhysicalMemory% МБ
 echo Тип ЦП:                        "%Name%"
 echo Число ядер:                    %NumberOfCores%
 echo Имя пользователя:              %UserName%
 echo Рабочая группа:                %Workgroup%
 echo.
 echo Видео
 echo Тип видеопроцессора:           "%VideoProcessor%"
 echo Разрешение монитора:           %CurrentHorizontalResolution%x%CurrentVerticalResolution%
 echo Тип DAC:                       %AdapterDACType%
 echo Объем видео ОЗУ:               %AdapterRAM%
 echo.
 echo Аудио
 echo Имя адаптера:                  %ProductName%
 echo.
 echo Сеть
 echo Сетевой адаптер:               %Description%
 echo Имя подключения:               %NetConnectionID%
 echo Скорость:                      %Speed%
 echo MAC адрес:                     %MACAddress%
)
exit

[diagnoz_]

Спасибо. запустил Ваш файл, показал инфу моего ПК, но без HDD. а вот на некоторых системах где стоит ХР, создает файл, а там пусто напротив всех категорий "железа".

[Kazun]

Есть бесплатная замечательная утилита WinAudit с поддержкой командной строки.

[Iska]

diagnoz_, Wbem — платформа. Если тот или иной производитель «забил» на поддержку оной целиком или частично — естественно, могут быть и пустые классы без экземпляров объектов, и отсутствующие свойства, и не реализованные методы.

P.S. Насчёт «всех категорий» — это перебор.