CMD/BAT

Georgio · Отправлено: **11:44, 14-09-2014** | #2

Как-то так:

Код:

@echo off

>"example.log" (
echo =======
set /p="%date%  "<nul& @for /f %%i in ('time /t') do @echo %%i Началось обновление комплекта №1
start "" /wait "example.exe"
set /p="%date%  "<nul& @for /f %%i in ('time /t') do @echo %%i Завершилось обновление комплекта №1
echo =======
)

exit /b

.

i-Lex · Конфигурация компьютера

Georgio, а можешь приписать, чтобы в папку нужную писал?

Georgio · Отправлено: **12:21, 14-09-2014** | #4

Код:

@echo off

:: Полный путь к LOG-файлу:
>"C:\Soft\Other\Scripts\Logs\example.log" (
echo =======
set /p="%date%  "<nul& @for /f %%i in ('time /t') do @echo %%i Началось обновление комплекта №1

:: Пример запуска программы:
start "" /wait "D:\Test\example.exe"

set /p="%date%  "<nul& @for /f %%i in ('time /t') do @echo %%i Завершилось обновление комплекта №1
echo =======
)

exit /b

Iska · Отправлено: **14:25, 14-09-2014** | #5

Georgio, почему не просто:

Код:

echo %date% %time:~0,5% Мама мыла раму

?

Georgio · Отправлено: **15:53, 14-09-2014** | #6

Iska, смотрите:

Код:

@echo off

>"example.log" (
set /p="%date%  "<nul& for /f %%i in ('time /t') do echo %%i  Мама мыла раму.
timeout /t 60 /nobreak>nul
set /p="%date%  "<nul& for /f %%i in ('time /t') do echo %%i  Мама мыла раму.
)

exit /b

.

Результат:

Код:

14.09.2014  15:07  Мама мыла раму.
14.09.2014  15:08  Мама мыла раму.

.

И теперь смотрите:

Код:

@echo off

>"example.log" (
echo %date%  %time:~0,5%  Мама мыла раму.
timeout /t 60 /nobreak>nul
echo %date%  %time:~0,5%  Мама мыла раму.
)

exit /b

.

Результат:

Код:

14.09.2014  15:10  Мама мыла раму.
14.09.2014  15:10  Мама мыла раму.

.

То есть по-хорошему надо было использовать и "date /t".

Также могу предложить такие варианты:

Код:

@echo off

>"example.log" (
cmd /v:on /c echo !date!  !time:~0,5!  Мама мыла раму.
timeout /t 60 /nobreak>nul
cmd /v:on /c echo !date!  !time:~0,5!  Мама мыла раму.
)

exit /b

и

Код:

@echo off

>"example.log" (
call echo %%date%%  %%time:~0,5%%  Мама мыла раму.
timeout /t 60 /nobreak>nul
call echo %%date%%  %%time:~0,5%%  Мама мыла раму.
)

exit /b

.

i-Lex · Конфигурация компьютера

Georgio, я как-то не вижу разницы...

Georgio · Отправлено: **16:13, 14-09-2014** | #8

i-Lex, просто в одном случае везде будет фигурировать только одно и то же время -- время запуска программы, а в других случаях время будет меняться, как это и положено.

Iska · Отправлено: **17:32, 14-09-2014** | #9

Georgio, так это тот же самый типичный случай — надо пользовать либо отложенное раскрытие переменных окружения и «!» вместо «%», либо двойной раскрытие переменных окружения через «call echo %%date%% %%time%% …». Второй вариант Вы озвучили.

Другой Ваш вариант выглядит чересчур надуманным. Отчего Вы так не любите простое «setlocal enableextensions enabledelayedexpansion»?

Georgio · Отправлено: **18:11, 14-09-2014** | #10

Цитата Iska:

Другой Ваш вариант выглядит чересчур надуманным. Отчего Вы так не любите простое «setlocal enableextensions enabledelayedexpansion»? »

Iska, просто сравните:

Код:

:: !!!Мама мыла раму!!!

@echo off
chcp 1251>nul

setlocal enabledelayedexpansion

for /f "usebackq delims=" %%i in ("%~f0") do chcp 866>nul& echo %%i& endlocal& pause>nul& exit /b

и

Код:

:: !!!Мама мыла раму!!!

@echo off
chcp 1251>nul

:setlocal enabledelayedexpansion

for /f "usebackq delims=" %%i in ("%~f0") do chcp 866>nul& cmd /v:on /c echo %%i& pause>nul& exit /b

.