CMD/BAT - [решено] Удаление файлов в папке и подпапках, содержащих определенную строку

Iska · Отправлено: **11:40, 04-12-2013** | #2

Цитата hron66:

необходимо в конкретной папке и всех подпапках найти и удалить:
…
2) Файлы, в которых первый символ - .(точка). »

Код:

del /q /s ".*"

Не?!

hron66 · Отправлено: **11:43, 04-12-2013** | #3

Я может как то неправильно объяснил. Имелось в ввиду, первый символ точка не в имени файла, а внутри файла. Если мы открываем файл блокнотом например, то внутри первый символ первой строчки - точка.

Iska · Отправлено: **15:41, 04-12-2013** | #4

hron66, ясно. Файлы текстовые? Кодировка их какая?

hron66 · Отправлено: **15:55, 04-12-2013** | #5

Файлы обычные текстовые. Кодировка тоже стандартная - cp1251.

sov44 · Конфигурация компьютера

hron66, так?

Код:

@ECHO OFF
SETLOCAL EnableDelayedExpansion

for /f "delims=" %%a in ('dir /b /s /a-d "c:\1\new\*" ^|find "\."') do echo rd /q "%%~dpa" 2>nul

pause

hron66 · Отправлено: **17:12, 04-12-2013** | #7

sov44, у меня ваш вариант не работает.. И насколько я понял по коду он расчитан на одну папку (без подпапок). И find ищет все точки в файле, а нужно, чтобы искал только первый символ в файле.

sov44 · Конфигурация компьютера

hron66, не увидел уточнение ТЗ

Цитата hron66:

Имелось в ввиду, первый символ точка не в имени файла, а внутри файла. »

попробуйте

Код:

@echo off
setlocal EnableDelayedExpansion

set filename=c:\1\new\dfg.txt
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ^<"%filename%"') do (
set line=%%a_%%b
if "!line:~0,3!"=="1_." echo %%b
)
pause>nul
exit

Iska · Отправлено: **18:24, 04-12-2013** | #9

Цитата hron66:

Файлы обычные текстовые. Кодировка тоже стандартная - cp1251. »

Ясно. Пробуйте:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=" %%i in (
	`dir /b /s /a:-d "E:\Песочница\0334\*.*"`
) do (
	<"%%~i" set /p sValue=
	if defined sValue if "!sValue:~0,1!" equ "." echo del /f /q "%%~i"
)

endlocal
exit /b 0

Для реального удаления уберите echo.

P.S. А что это за файлы?

hron66 · Отправлено: **09:26, 05-12-2013** | #10

Iska, спасибо огромное !!! Ваше решение работает идеально и именно так, как нужно!
P.S. Это файлы по работе, которые приходят с АРМ и загружаются в БД. При этом, непонятно почему, бывают пустые файлы и файлы, содержащие много точек. Они обрабатываются с ошибками, поэтому хотелось сделать батник для удаления таких файлов. Можно бы было решить это все на Дельфи, но не хотелось еще больше грузить сервер задачами. А батник не ест память и работает очень быстро и незаметно.
P.P.S. Решение уже запущено в работу.
P.P.P.S. Еще раз спасибо всем за помощь!