[Iska]

Имеется файл list.txt, »

Упакуйте файл в архив. Выложите сюда или на RGhost.

[ultrarare]

Сделано, спасибо за внимание к теме

[Iska]

ultrarare, на WSH:

читать дальше »

Код:

Option Explicit

Const ForReading   = 1
Const ForWriting   = 2


Dim strFile
Dim strPattern

Dim objFSO

Dim strProxyS
Dim strContent


strFile = "E:\Песочница\0288\list.txt"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strFile) Then
	With objFSO.OpenTextFile(strFile, ForReading)
		strContent = .ReadAll()
		.Close
	End With
	
	With WScript.CreateObject("VBScript.RegExp")
		.Pattern = "^(ProxyS=)(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})$"
		.IgnoreCase = True
		.MultiLine  = True
		
		If .Test(strContent) Then
			strProxyS = Trim(InputBox("Change ProxyS value:", "ProxyS", .Execute(strContent).Item(0).Submatches(1)))
			
			If Len(strProxyS) > 0 Then
				strContent = .Replace(strContent, "$1" & strProxyS)
				
				With objFSO.OpenTextFile(strFile, ForWriting)
					.Write strContent
					.Close
				End With
			End If
		Else
			WScript.Echo "Can't find any line in file [" & strFile & "] for pattern [" & .Pattern & "]."
		End If
	End With
Else
	WScript.Echo "Can't find file [" & strFile & "]."
End If

WScript.Quit 0

Проверка — является ли введённое значение IP-адресом — не производится.

[ultrarare]

Простите, каюсь, забыл упомянуть, вместо ip ещё можно и нужно вводить домены типа myproxy.freeproxy.net или р72345.myproxy.freeproxy.net - сейчас не получается.
И не могли бы вы добавить в конце запуск файла при нажатии кнопки ok и просто завершение скрипта по нажатию кнопки отмена, без запуска .exe, если конечно возможно.

PS уточню, в форме ввода InputBox'a можно написать myproxy.freeproxy.net и он изменится в файле, но при следующем запуске скрипт не находит строку по указанному шаблону.
PSPS можно ещё каким то образом управлять кодировкой файла list.txt? наверное ANSI, совсем забыл про кириллические домены

[Iska]

забыл упомянуть, вместо ip ещё можно и нужно вводить домены типа myproxy.freeproxy.net или р72345.myproxy.freeproxy.net »

Ясно.

И не могли бы вы добавить в конце запуск файла при нажатии кнопки ok »

Какого файла?

Пусть будет «Блокнот»:

читать дальше »

Код:

Option Explicit

Const ForReading   = 1
Const ForWriting   = 2


Dim strFile
Dim strFile4Execute
Dim strPattern

Dim objFSO

Dim strProxyS
Dim strContent


strFile         = "E:\Песочница\0288\list.txt"
strFile4Execute = "c:\Windows\notepad.exe"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strFile) Then
	With objFSO.OpenTextFile(strFile, ForReading)
		strContent = .ReadAll()
		.Close
	End With
	
	With WScript.CreateObject("VBScript.RegExp")
		.Pattern = "^(ProxyS=)(.*)$"
		.IgnoreCase = True
		.MultiLine  = True
		
		If .Test(strContent) Then
			strProxyS = Trim(InputBox("Change ProxyS value:", "ProxyS", .Execute(strContent).Item(0).Submatches(1)))
			
			If Len(strProxyS) > 0 Then
				strContent = .Replace(strContent, "$1" & strProxyS)
				
				With objFSO.OpenTextFile(strFile, ForWriting)
					.Write strContent
					.Close
				End With
				
				If objFSO.FileExists(strFile4Execute) Then
					WScript.CreateObject("WScript.Shell").Run """" & strFile4Execute & """", 1, False
				End If
			End If
		Else
			WScript.Echo "Can't find any line in file [" & strFile & "] for pattern [" & .Pattern & "]."
		End If
	End With
Else
	WScript.Echo "Can't find file [" & strFile & "]."
End If

WScript.Quit 0

можно ещё каким то образом управлять кодировкой файла list.txt? наверное ANSI, совсем забыл про кириллические домены »

Так и есть.

[ultrarare]

Премного благодарен, всё работает

[ultrarare]

Iska, не тут то было, в попыхах проверил, всё работает, сейчас пристальнее присмотрелся, выявил несколько проблем, не могли бы вы мне ещё немного помочь?
Можно ли явно указать кодировку ANSI выходному файлу list.txt? Даже не могу понять в какой кодировке он сохраняется.
Когда я первый раз запускал, так и оставил расширение .vbs, сейчас изменил на .whs (полагаю, что так нужно) при запуске отображается ошибка с сообщением "Сценарий не указан" я, что то не так делаю?

[Iska]

Можно ли явно указать кодировку ANSI выходному файлу list.txt? Даже не могу понять в какой кодировке он сохраняется. »

Можно. Но не нужно:

читать дальше »

Она и так будет ANSI по умолчанию — OpenTextFile Method:

… format Optional. One of three Tristate values used to indicate the format of the opened file (TristateTrue = -1 to open the file as Unicode, TristateFalse = 0 to open the file as ASCII, TristateUseDefault = -2 to open the file as the system default). If omitted, the file is opened as ASCII. …

Когда я первый раз запускал, так и оставил расширение .vbs »

Верно.

сейчас изменил на .whs (полагаю, что так нужно) »

Не нужно. «*.wsh» — достаточно бесполезный файл описания сценария.

[ultrarare]

Большое спасибо за объяснения