[Ксеноинженер]

Считает все файлы, кроме скрытых и системных.

Код:

@echo off
set dir1=C:\
set dir2=D:\
CD /d %dir2%
for /f "tokens=*" %%I IN ('dir /b /a-d-h-s "%dir1%"') DO (
IF EXIST "%%I" echo %%I
)
pause

[kelevara]

Нашел схожий скрипт, но не выходит его изменить под свои нужды:

Код:

@echo off
for /f "tokens=*" %%i in ('dir /b /a-d "c:\lab2\1"') do if exist "c:\lab2\2\%%~nxi" echo %%~nxi
pause

1. Необходимо задать каталоги, в которых будет производиться поиск, с помощью параметров. Для этого делаю следующее:

Код:

@echo off
set directum1=c:\lab2\1
set directum2=c:\lab2\2
for /f "tokens=*" %%i in ('dir /b /a-d %directum1%') do if exist %directum2%+%%~nxi echo %%~nxi
pause

Но этот номер не проходит. Как быть?

2. Скрипт выводит только те файлы, у которых совпадает и разрешение и имя, а мне разрешение не важно, главное чтобы имя совпадало. Для этого в %%~nxi убираю х. Но это также не помогает...

Ксеноинженер, мм, а как сделать так, чтобы расширение не учитывалось при поиске?

[Ксеноинженер]

kelevara, дело в скобках после DO.

Код:

@echo off
set dir1=C:\
set dir2=D:\
CD /d "%dir2%"
for /f "tokens=*" %%I IN ('dir /b /a-d-h-s "%dir1%"') DO (
IF EXIST "%%~nI" echo %%~nI
)
pause

Вот так сравнивается только имя файла.

[kelevara]

kelevara, дело в скобках после DO. Код: @echo off set dir1=C:\ set dir2=D:\ CD /d "%dir2%" for /f "tokens=*" %%I IN ('dir /b /a-d-h-s "%dir1%"') DO ( IF EXIST "%%~nI" echo %%~nI ) pause Вот так сравнивается только имя файла. »

Странно, этот вариант у меня вообще ничего не находит. У меня есть две папки 1 и 2. В папке 1 лежат файлы 1.txt, lab2-1.bat, lab2-2.bat, lab2-3.bat, lab2-4.bat, lab2-5.bat.
В папке 2 лежат файлы 1.bat, lab2-1.bat, lab2-3.bat, lab2-5.bat.
Соответственно, в результате работы программы на экран должен выводится следующий список:
1
lab2-1
lab2-3
lab2-5

К слову, предыдущий вариант скрипта, приведенный во втором сообщении, выводит такой список:
lab2-1.bat
lab2-3.bat
lab2-5.bat

[Georgio]

Сообщение удалено автором.

[Ксеноинженер]

Цитата kelevara:
Соответственно, в результате работы программы на экран должен выводится следующий список:
1
lab2-1
lab2-3
lab2-5 »


Так?

Код:

@echo off
set directum1=c:\lab2\1
set directum2=c:\lab2\2
CD /d "%directum2%"
for /f "tokens=*" %%I IN ('dir /b /a-d-h-s "%directum1%"') DO (
IF EXIST %%~nI* echo %%~nI
)
pause

[Georgio]

Ксеноинженер, я так тоже пробовал:

IF EXIST %%~nI* echo %%~nI »

Точнее, так:

Код:

IF EXIST %%~nI.* echo %%~nI

Не подходит. Если, например, в %directum2% находится файл lab-2-1.###.bat вместо файла lab2-1.bat, то также будет выведено имя "lab2-1", а оно не должно выводиться, так как файла с таким именем нет.

[kelevara]

Ксеноинженер, Georgio
Попробую показать вариант, предложенный уважаемым Ксеноинженером. Но проблему, указанную Georgio (тоже кстати не менее уважаемым), также признаю и беру к сведению

[Ксеноинженер]

Не подходит. Если, например, в %directum2% находится файл lab-2-1.###.bat вместо файла lab2-1.bat, то также будет выведено имя "lab2-1", а оно не должно выводиться, так как файла с таким именем нет. »

Georgio, Дисциплина задания kelevara не позволяет второго FOR. Если б позволяла, то было б так:

Код:

@echo off
set directum1=c:\lab2\1
for /f "tokens=*" %%I IN ('dir /b /a-d-h-s "%directum1%"') DO (
echo %%~nI>>"%tmp%\list1.txt"
)
set directum2=c:\lab2\2
for /f "tokens=*" %%I IN ('dir /b /a-d-h-s "%directum2%"') DO (
echo %%~nI>>"%tmp%\list2.txt"
)
findstr /i /x /G:"%tmp%\list1.txt" "%tmp%\list2.txt"
del /q "%tmp%\list1.txt"
del /q "%tmp%\list2.txt"
pause