[gora]

файл ***.lng »

Приведите полное название этого файла с полным путем к нему на CD (букву CD можете указать любую)

папку этой программы C:\Program Files (x86)\*** »

Приведите полное название папки программы с полным путем к месту расположения в ней вышеупомянутого файла.

[meGangstaWorld]

На CD: G:\SetupRes\lang\russian.lng

На PC: C:\Program Files (x86)\Programma\lang

[gora]

На момент запуска папка C:\Program Files (x86)\Programma\lang должна существовать.
Файл (полный путь к нему) x:\SetupRes\lang\russian.lng не должен иметь дубликатов на других дисках

Код:

@Echo Off
Set xOS=x64
If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86
Set pf=%ProgramFiles%
If %xOS%==x64 Set pf=%ProgramFiles(x86)%
Echo %xOS%	%pf%
For %%z In (c d e f g h i j k l m n o p q r s t u v w x y z) Do If Exist "%%z:\SetupRes\lang\russian.lng" Copy "%%z:\SetupRes\lang\russian.lng" "%pf%\Programma\lang"
Pause

[7ka]

meGangstaWorld

Код:

@Echo off

:: Находим диск
for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist %%d:\SetupRes\lang\russian.lng set DiskDrive=%%d:

:: Определяем разрядность ОС и копируем файл russian.lng в нужную директорию
Set xOS=x64
If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86
If %xOS%==x86 (xcopy "%DiskDrive%\SetupRes\lang\russian.lng" /e "%programfiles(x86)%"\Programma\lang) Else (xcopy "%DiskDrive%\SetupRes\lang\russian.lng" /e "%programFiles%"\Programma\lang)

Exit

gora, упс... забыл страничку обновить)))))

[gora]

If %xOS%==x86 (xcopy "%DiskDrive%\SetupRes\lang\russian.lng" /e "%programfiles(x86)%" »

На x86 ОС такой переменной нет

Else (xcopy "%DiskDrive%\SetupRes\lang\russian.lng" /e "%programFiles%" »

На x64 ОС, но при запуске батника из 64-х разрядного приложения эта переменная развернется в c:\Program Files, а не в c:\Program Files (x86)

[meGangstaWorld]

Какой командой можно приостановить выполнение команды в .cmd файле после его запуска на секунд 30-60, подскажите пожалуйста!?

p.s Где-то видел вариант обходились командой ping на localhost то-ли на 127.0.0.1 точно не помню как правильно писать.

[Iska]

Код:

>nul ping.exe -n 61 127.0.0.1