[Iska]

удалит все столбцы со всех листов во всех книгах. »

«Все столбцы» — подходящие под условие столбцы B? Можно попробовать так:

читать дальше »

Код:

Option Explicit

Const xlWorksheet = &HFFFFEFB9


Dim strFolder

Dim objFSO
Dim objFile

Dim objExcel
Dim objWorksheet


If WScript.Arguments.Count = 1 Then
	strFolder = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FolderExists(strFolder) Then
		Set objExcel = WScript.CreateObject("Excel.Application")
		
		For Each objFile In objFSO.GetFolder(strFolder).Files
			Select Case LCase(objFSO.GetExtensionName(objFile.Name))
				Case "xls", "xlsx"
					With objExcel.Workbooks.Open(objFile.Path)
						For Each objWorksheet In .Sheets
							With objWorksheet
								If .Type = xlWorksheet Then
									With .Cells.Item(1, 2)
										If .Value = "Owner" Then
											.EntireColumn.Delete
										End If
									End With
								End If
							End With
						Next
						
						.Save
						.Close
					End With
				Case Else
					' Nothing to do
			End Select
		Next
		
		objExcel.Quit
		Set objExcel = Nothing
	Else
		WScript.Echo "Folder [" & strFolder & "] not found"
	End If
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Folder>"
End If

WScript.Quit 0

* писалось под 2003-им Microsoft Excel, потому крайне рекомендую сначала опробовать «на свинках»;
* не рекурсивно.

[van1985]

Powershell

написал только что , так что без особого тестирования... Сначала лучше запустить на "кошках"
Excel 2007.

Код:

$xlCellTypeLastCell = 11
$xl = New-Object -com Excel.Application
$xl.Visible = $false
$xl.DisplayAlerts = $False

Get-ChildItem -Path c:\temp\excelRemouveColumn -Recurse -Include *.xlsx | %{
$wb = $xl.Workbooks.Open($_.fullname) 

1..$wb.Worksheets.Count | %{
$ws = $wb.Worksheets.Item($_)
if($ws.cells.item(1,2).value() -eq "Owner"){
[void]$ws.columns.item(2).delete()
}
}
$wb.Save()
$wb.Close()
}
$xl.Quit()
[System.Runtime.Interopservices.Marshal]::ReleaseComObject($xl)
Remove-Variable xl

Upd. Язык Office 2013 должен совпадать с региональными стандартами

[Vadikan]

Iska, спасибо за вариант, я ждал помощи от вас

К сожалению, получил ошибку

Код:

C:\Users\username\Documents\test\remove-column.vbs(31, 11) Microsoft VBScript runtime error: Type mismatch: 'Value'

У меня Office 2010.

van1985, кстати, я очень хотел посмотреть, не предложит ли кто-нибудь вариант с PowerShell. Я по гуглу такое не осилил, к сожалению. Большое спасибо, ненужные мне столбцы удалились везде. Нужные, вроде, не пропали

[Vadikan]

Я временно сниму пометку решено и подниму тему.

Сейчас нужно решение именно на VBS под Office 2013 RT, потому что в Windows RT из пошика это не сделать. Для решения текущей задачи достаточно только поочередно открыть, сохранить и закрыть все книги XLS в заданной папке.

Вот тут есть очень похожее http://stackoverflow.com/questions/1...-automatically , надо на обработку папки переделать, но у меня с VBS совсем никак

Буду признателен любым идеям!

[Iska]

потому что в Windows RT из пошика это не сделать. »

Там нет PowerShell'а?

Для решения текущей задачи достаточно только поочередно открыть, сохранить и закрыть все книги XLS в заданной папке. »

То бишь, со «внутренностями» документа никаких операций делать больше не надо?

Примерно так:

читать дальше »

Код:

Option Explicit

Dim objFSO
Dim objFile

Dim strFolder

Dim objSheet


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If WScript.Arguments.Count = 1 Then ' Если задан аргумент скрипта…
	' …используем его как имя папки для обработки
	strFolder = WScript.Arguments.Item(0)
Else
	' …иначе используем текущий каталог для скрипта
	strFolder = objFSO.GetAbsolutePathName(".")
End If

' В принципе, можно и прямо задать потребную папку для обработки
'strFolder = "c:\temp\excelRemouveColumn"

With WScript.CreateObject("Excel.Application")
	.DisplayAlerts = False
	
	If objFSO.FolderExists(strFolder) Then
		For Each objFile In objFSO.GetFolder(strFolder).Files
			Select Case LCase(objFSO.GetExtensionName(objFile.Name))
				Case "xls", "xlsx"
					With .Workbooks.Open(objFile.Path)
						'WScript.Echo objFile.Path
						
						.Save
						.Close
					End With
				Case Else
					' Nothing to do
			End Select
		Next
	Else
		WScript.Echo "Folder [" & strFolder & "] not found."
	End If
	
	.Quit
End With

Set objFSO = Nothing

WScript.Quit

[Vadikan]

Там нет PowerShell'а? »

Есть, но один специалист по нему сказал, что PS там урезан, поэтому код выше завершается с ошибками.

Примерно так: »

Спасибо, работает, но выводит диалог с именем каждого обработанного файла. Как его убрать?

[Iska]

Есть, но один специалист по нему сказал, что PS там урезан, поэтому код выше завершается с ошибками. »

Спасибо, ясно.

выводит диалог с именем каждого обработанного файла. Как его убрать? »

Вариантов несколько. Проще всего закомментировать строку с «WScript.Echo …». Поправил код выше.

[Vadikan]

Iska, да, так работает, но все равно не сработало в RT.

"Не удается создать объект с именем WScript.Shell".

Видимо, там и VBS какой-то не такой

Спасибо за помощь!

[Iska]

Iska, да, так работает, но все равно не сработало в RT. »

Вот же зараза такая !

"Не удается создать объект с именем WScript.Shell". Видимо, там и VBS какой-то не такой »

Давайте попробуем дедовский способ получения текущего каталога — «objFSO.GetAbsolutePathName(".")» вместо использования объекта «WScript.Shell». Ещё раз поправил код.