VBS/WSH/JS - [решено] Экспорт данных из одного txt файла в другой

Iska · Отправлено: **17:33, 21-08-2012** | #2

Например, так:

Исполнять под «cscript.exe», указывая исходный файл аргументом скрипта, а результирующий — перенаправлением вывода, наподобие:

Код:

cscript.exe //nologo "C:\Песочница\0018\MyScript.vbs" "C:\Temp\Kl_to_1c.txt" 1>Out.txt 2>Errors.txt

TRaMeLL · Отправлено: **19:58, 21-08-2012** | #3

Великолепно! Почти. Только нужно еще сделать так чтобы после:
%Дата=% - %Номер=% - %Сумма=% - %Плательщик1=%
Начиналась новая строка, сейчас идет сразу: %Дата=% - %Номер=% - %Сумма=% - %Плательщик1=% - %Дата=% - %Номер=% - %Сумма=% - %Плательщик1=% и т. д.
А надо:
%Дата=% - %Номер=% - %Сумма=% - %Плательщик1=%
%Дата=% - %Номер=% - %Сумма=% - %Плательщик1=%
%Дата=% - %Номер=% - %Сумма=% - %Плательщик1=%
%Дата=% - %Номер=% - %Сумма=% - %Плательщик1=%
....
и т. д. до конца

Iska · Отправлено: **03:30, 22-08-2012** | #4

В реальном файле «Kl_to_1c.txt» несколько квитанций о платежах? В Вашем примере только одна квитанция, а я просто не успел взять реальный файл у себя, а так бы проверил на реальных данных.

Попробуйте тогда так:

TRaMeLL · Отправлено: **05:00, 22-08-2012** | #5

Да, в реальном файле могут быть несколько квитанций. Теперь всё OK. Спасибо огромное!

TRaMeLL · Отправлено: **05:58, 22-08-2012** | #6

В принципе и так нормально, но кое-что еще можно поправить:
Сейчас, если %Номер% одинаковое количество символов, то всё нормально, но если число разное, т. е. в одной строке, например 5 символов, а во второй - 3, то файл получается немного кривым. Можно как-то облагородить форматирование? Чтобы получались ровные колонки? Вот тогда счастью моему не было бы предела.

Iska · Отправлено: **06:53, 22-08-2012** | #7

TRaMeLL, Вам нужен табличный, выровненный вид? Зачем тогда нужны разделители « - » в результирующем файле?

TRaMeLL · Отправлено: **07:20, 22-08-2012** | #8

Да, нужен табличный вид. " - " это просто для примера, я вместо него vbTab поставил.

Iska · Отправлено: **08:39, 22-08-2012** | #9

TRaMeLL, ясно. Попробуйте так:

Код:

Option Explicit

Const adInteger  =   3
Const adCurrency =   6
Const adDate     =   7
Const adVarChar  = 200



Dim lngErrCode

Dim strSourceFile
Dim strLine

Dim objTS
Dim objRecordSet

Dim intNumberMaxLength
Dim intSummMaxLength
Dim intPlatMaxLength


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FileExists(strSourceFile) Then
			Set objTS = .OpenTextFile(strSourceFile)
			
			With WScript.CreateObject("ADOR.Recordset")
				With .Fields
					.Append "Дата",                   adDate
					.Append "Номер",                  adInteger
					.Append "Сумма",                  adCurrency
					.Append "Плательщик1",            adVarChar, 2^15 - 1
					.Append "ДлинаСтрокиПлательщик1", adInteger
				End With
				
				.Open
				
				Do Until objTS.AtEndOfStream
					strLine = objTS.ReadLine()
					
					Select Case Split(strLine, "=")(0)
						Case "Дата"
							.AddNew
							.Fields.Item("Дата").Value = CDate(Split(strLine, "=")(1))
						Case "Номер"
							.Fields.Item("Номер").Value = CLng(Split(strLine, "=")(1))
						Case "Сумма"
							.Fields.Item("Сумма").Value = CCur(Split(strLine, "=")(1))
						Case "Плательщик1"
							.Fields.Item("Плательщик1").Value = CStr(Split(strLine, "=")(1))
							.Fields.Item("ДлинаСтрокиПлательщик1").Value = Len(CStr(Split(strLine, "=")(1)))
					End Select
				Loop
				
				objTS.Close
				
				.Sort = "Номер DESC" : .MoveFirst
				intNumberMaxLength = Len(CStr(.Fields.Item("Номер").Value))
				
				.Sort = "Сумма DESC" : .MoveFirst
				intSummMaxLength   = Len(CStr(.Fields.Item("Сумма").Value))
				
				.Sort = "ДлинаСтрокиПлательщик1 DESC" : .MoveFirst
				intPlatMaxLength   = .Fields.Item("ДлинаСтрокиПлательщик1").Value
				
				.Sort = "" : .MoveFirst
				
				Do Until .EOF
					With .Fields
						WScript.StdOut.Write FormatString(.Item("Дата").Value, 10) & vbTab
						WScript.StdOut.Write FormatString(.Item("Номер").Value, intNumberMaxLength) & vbTab
						WScript.StdOut.Write FormatString(.Item("Сумма").Value, intSummMaxLength) & vbTab
						WScript.StdOut.Write FormatString(.Item("Плательщик1").Value, intPlatMaxLength)
						WScript.StdOut.WriteLine
					End With
					
					.MoveNext
				Loop
				
				.Close
			End With
			
			Set objTS = Nothing
			
			lngErrCode = 0
		Else
			WScript.StdErr.WriteLine "File [" & strSourceFile & "] not found"
			lngErrCode = 2
		End If
	End With
Else
	WScript.StdErr.WriteLine "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ ""<Source file>"""
	lngErrCode = 1
End If

WScript.Quit lngErrCode
'=============================================================================

'=============================================================================
Function FormatString(anyValue, intLength)
	Select Case TypeName(anyValue)
		Case "Date"
			FormatString = Left(CStr(anyValue) & Space(intLength), intLength)
		Case "String"
			FormatString = Left(CStr(anyValue) & Space(intLength), intLength)
		Case "Integer", "Long", "Currency"
			FormatString = Right(Space(intLength) & CStr(anyValue), intLength)
		Case Else
			FormatString = "<unsupported type " & TypeName(anyValue) & ">"
	End Select
End Function
'=============================================================================

На копейки не рассчитано. Если могут присутствовать — надо будет править код.

TRaMeLL · Отправлено: **08:51, 22-08-2012** | #10

Этот что-то не запустился, в логе ссылается на 51-ю строку. И там копейки присутствуют еще.