2010 - как пакетно назначить имена для клеток excel?

okshef · Конфигурация компьютера

Поясните:

Цитата Pozia:

определенному диапазону »

единственное число

Цитата Pozia:

произвольные имена »

множественное....
Идею (цель) - подробнее

Pozia · Отправлено: **01:17, 21-01-2012** | #3

Если из эксель скопировать клетку и вставить ее через специальную вставку в ворд - получится связь. Изменив значение клетки в эксель - меняется значение в ворд. Так вот если клетку в эксель куда то перенести - связь теряется. Если клетке эксель предварительно дать имя, и затем сделать связь, то так связь ворд эксель не потеряется, так как ворд будет ссылаться не на координату а на имя клетки, которое является уникальным для листа.
Далее. У меня есть файл эксель с большими расчетами, состоящий примерно из 2000 строк и 50 столбцов. Вот для этого диапазона клеток мне нужно задать каждой клетке произвольное имя - допустим в формате "_******", где * - цифра произвольная. Вот это мне и нужно сделать.

В нете нашел вот такой скрипт:

HTML код:

Sub CopyFromExcel() 
 'Связывание таблиц Word и Excel по ячейкам. Необходимо выделить ячейки в Excel и
 ' соответствующиие им ячейки в Word
 Dim objExcel, c, i
 'Если ошибка - В пункте меню Tools -> References отметить 
 ' Microsoft Excel Object Library
 Set objExcel = GetObject(, "Excel.Application.11") 
 For Each c In Selection.Cells
 i = i + 1
 objExcel.Selection.Cells(i).Copy
 c.Select
 Selection.PasteExcelTable True, True, True
 Next c
 End Sub

который позволяет быстро скопировать клетку эксель в ворд создав связь. Работает так - выделяем клетку в ворд, выделяем в эксель, запускаем скрипт - ссылка готова. Но он почему то не работает. Выскакивает ошибка - Run-time error '429': ActiveX component can't create object. Вот если бы его починить, и дописать возможность автоматического присваивания произвольного имени клетке эксель при создании связи ворд эксель - это было бы самым шикарным вариантом... Такое можно осуществить?

Iska · Отправлено: **07:58, 21-01-2012** | #4

Попробуйте убрать привязку к конкретной версии и обращаться по VersionIndependentProgID:

Код:

Set objExcel = GetObject(, "Excel.Application")

либо указать ProgID, соответствующий Вашей версии Microsoft Office.

P.S. У меня не получилось вставить связь, когда ячейке Excel присвоено имя (Microsoft Office 2003).

Pozia · Отправлено: **11:51, 21-01-2012** | #5

Цитата Iska:

Попробуйте убрать привязку к конкретной версии и обращаться по VersionIndependentProgID:
Код:
Set objExcel = GetObject(, "Excel.Application") »

после этого у меня появилась другая ошибка:

Код:

Run-time error '438': Object doesn't support this property or method

Iska · Отправлено: **21:08, 21-01-2012** | #6

Pozia, как я уже писал:

Цитата Iska:

P.S. У меня не получилось вставить связь, когда ячейке Excel присвоено имя (Microsoft Office 2003). »

У Вас, насколько я понимаю, Microsoft Office 2010. Посему: опишите подробно, как Вы назначаете имя отдельной ячейке в Excel, как вставляете связь на эту ячейку в Microsoft Word. Если у меня сие получится воспроизвести — двинемся дальше, если нет — я отойду в сторону.

Pozia · Отправлено: **00:27, 22-01-2012** | #7

Цитата Iska:

У Вас, насколько я понимаю, Microsoft Office 2010 »

да. но и в 2003 все работает практически также. Описываю как сделать именно в 2003. Ставим курсор на любую клетку в эксель, в поле где показывается координата выбранной клетки (левы верхний угол) просто вписываем нужное имя и нажимаем ввод. Так назначается имя клетки. Далее вписываем что либо в выбранную клетку и копируем содержимое в буфер обмена. В ворд выбираем Правка -> Специальная вставка. В окошке ставим птичку связать. Выбираем Неформатированный текст, жмем Ок. Все. Теперь если мы изменим что то в клетке эксель, в ворде тоже произойдет изменение. И если клетку в эксель мы перенесем в другое место, ворд все равно ее найдет. Вот примерно это и нужно реализовать макросом. И желательно имя клетки давать случайное как я писал ранее в формате "_******", где * - цифра произвольная. Спасибо за помощь.

Iska · Отправлено: **00:58, 23-01-2012** | #8

Цитата Pozia:

Выбираем Неформатированный текст, жмем Ок. Все. »

У меня как раз с этим проблема:

Цитата:

Не удается получить данные для связи Excel.Sheet.8

про которую я и писал выше.

Pozia, попробуйте так:

Код:

Option Explicit

Sub CopyFromExcel()
    Dim objExcel As Excel.Application
    Dim strAddress As String
    Dim strNewName As String
    
    Dim i As Long
    
    Set objExcel = GetObject(, "Excel.Application")
    
    With objExcel.Selection
        If .Worksheet.Type = xlWorksheet Then
            i = .Worksheet.Names.Count + 1
            
            Do
                strNewName = "_" & CStr(i)
                
                If Not NameExists(.Worksheet, strNewName) Then
                    Exit Do
                Else
                    i = i + 1
                End If
            Loop
            
            .Worksheet.Names.Add strNewName, "=" & .Address(, , xlR1C1, True)
            .Copy
            
            Selection.PasteSpecial , True, , , wdPasteText
            
            .Application.CutCopyMode = False
        End If
    End With
    
    Set objExcel = Nothing
End Sub

Function NameExists(objWorksheet As Excel.Worksheet, strName As String) As Boolean
   On Error Resume Next
   
   NameExists = Len(objWorksheet.Names(strName).Name) <> 0
End Function

Основной макрос — «CopyFromExcel()». Также потребуется задать ссылку на «Microsoft Excel Object Library».

Pozia · Отправлено: **07:52, 23-01-2012** | #9

Iska, Спасибо. Буду пробовать днем. А что значит

Цитата Iska:

потребуется задать ссылку на «Microsoft Excel Object Library». »

?

Iska · Отправлено: **11:12, 23-01-2012** | #10

Цитата Pozia:

А что значит… »

См. выше:

Цитата Pozia:

В нете нашел вот такой скрипт:

Код:

…
В пункте меню Tools -> References отметить Microsoft Excel Object Library
…

»