[скуби_ДУ]

все файлы естественно с разными именами.
только одинаковое расширение...

[Iska]

скуби_ДУ, Вам это действительно надо будет делать на регулярной основе и программно? Или это однократное действие?

[Busla]

скуби_ДУ, указанные строки должны идти строго подряд или просто содержаться в файле?

[скуби_ДУ]

сейчас это однократное действие которое возможно и будет регулярным раз в месяц при естественно уже меньшем кол-ве файлов. строки должны идти именно в такой последовательности - собственно во всех файлах значение этой суммы либо 0 - и их отобрать надо - в других файлах оно отлично от нуля и эти файлы не нужны

[Busla]

На jscript или powershell реализуется довольно просто. А вот в bat выискивать многострочный блок текста - нетривиальная задача.

[amel27]

как минимум, для CMD нужна кодировка исходных файлов

читать дальше »

Код:

@echo off
SetLocal EnableDelayedExpansion

set "D1=C:\Upload"
set "D2=C:\Upload\Выборка"
set "$1=<КодСтроки>10</КодСтроки>"
set "$2=<Сумма>0.00</Сумма>"

if not exist "%D2%" MD "%D2%"
pushd "%D1%" && (
for /f "tokens=1,2* delims=:" %%a in ('findstr/xnc:"!$1!" /c:"!$2!" *.xml') do (
if "!$c!"=="!$1!" if "%%c"=="!$2!" if "!$a!"=="%%a" set/a "$=%%b-!$b!"& if !$! equ 1 move/-y "%%a" "%D2%"
set "$a=%%a"& set "$b=%%b"& set "$c=%%c"))

[Anonymоus]

Мой вариант:

Код:

@Echo Off
SetLocal EnableDelayedExpansion
Set TargetDir=D:\TEMP\Testing\Upload

Set i=0
If Not Exist "%TargetDir%\Выборка" Md "%TargetDir%\Выборка"
For /F "tokens=*" %%F In ('Dir "%TargetDir%\*.xml" /A-D /B') Do (
Grep -o "<КодСтроки>10</КодСтроки>" "%TargetDir%\%%F">nul&&^
Grep -o "<Сумма>0.00</Сумма>" "%TargetDir%\%%F">nul&&^
Move /Y "%TargetDir%\%%F" "%TargetDir%\Выборка\%%F"&&Set /A i+=1
Title Файлов перемещено !i!
)
Echo Работа завершена
Pause>nul

Заменяете значение TargetDir на свой путь, если не нужна индикация количества обработанных файлов - убираете SetLocal EnableDelayedExpansion и всё, относящееся к счётчику. По идее, должно работать с любой поддерживаемой grep кодировкой, я проверял на 1251. Сам скрипт сохранить в 866 для работы с кириллическими путями.
Для работы скрипта нужен grep, входящий в пакет утилит GnuWin32 core utils. Скачать его можно здесь (сам grep и нужные dll) или здесь (официальная страница на sourceforge)

[amel27]

Для работы скрипта нужен grep, входящий в пакет утилит GnuWin32 core utils.»

тогда уж сразу вариант на AWK:

Код:

@for /f "delims=" %%a in (
'gawk "/<КодСтроки>10<\/КодСтроки>/ {getline;if ($0~/<Сумма>0.00<\/Сумма>/){print FILENAME;nextfile}}" *.xml'
) do move/-y "%%a" ".\Upload"

[скуби_ДУ]

спасибо анонимоусу - все отлично сработало...