[Creat0R]

Предупреждение за нарушение правил форума, пункт 2.7:

В заголовке темы обязательно обозначайте название предмета, которого касается вопрос, а в теле сообщения максимально подробно опишите проблему (приведите аппаратную/программную конфигурацию, а также изложите ситуацию, в которой возникает проблема). Темы с несодержательными или слишком общими заголовками будут закрываться или переноситься в раздел "Зона тестирования" в зависимости от политики конкретного форума. Подробнее о принципах создания тем читайте в этом документе и Правилах форумов.

Переименуйте пожалуйста тему.

---

И ещё, код нужно заключать в теги code, а раскрашивать можно утилитой Au3ToPost.

[pekich]

Исправлю

[Creat0R]

Задача »

Примерно так:

Код:

$sCompare_File = "Compare.ini"
$sSample_File = "Sample.ini"

$aCompare_Sect = IniReadSection($sCompare_File, "HG")
$aSample_Sect = IniReadSection($sSample_File, "HG")

$iComp_Ubound =  UBound($aCompare_Sect) - 1
$iSamp_Ubound =  UBound($aSample_Sect) - 1

If $iComp_Ubound <> $iSamp_Ubound Or $iComp_Ubound <= 0 Then
    MsgBox(48, $sCompare_File, "Данные файла [" & $sSample_File & "] не совпадают", 2); несовпадение массива
    Exit
EndIf

For $i = 1 To $iComp_Ubound
    If $aCompare_Sect[$i][0] & $aCompare_Sect[$i][1] = $aSample_Sect[$i][0] & $aSample_Sect[$i][1] Then
        MsgBox(64, $sCompare_File & " строка " & $i+1, "Данные файла [" & $sSample_File & "] в строке №" & $i+1 & " совпадают", 2)
    Else
        MsgBox(48, $sCompare_File & " строка " & $i+1, "Данные файла [" & $sSample_File & "] в строке №" & $i+1 & " не совпадают", 2)
        Exit
    EndIf
Next

[gregaz]

Вот вариант без построчной обработки массива :

Код:

$sCompare_File = "Compare.ini"
$sSample_File = "Sample.ini"

$sSectNameSample_File="JK"
$sSectNameCompare_File="HG"

$sSample_FileText=FileRead($sSample_File)
$sCompare_FileText=FileRead($sCompare_File)

$aSample_SectText= StringRegExp($sSample_FileText,"(?s).*\[" & $sSectNameSample_File & "\]\r\n(.+?)\[.*",1)
$aCompare_SectText= StringRegExp($sCompare_FileText,"(?s).*\[" & $sSectNameCompare_File & "\]\r\n(.+?)\[.*",1)

If $aSample_SectText[0] = $aCompare_SectText[0] Then
    $sInfoText="Все три строки совпали"
Else
    $sInfoText="Данные секций  НЕ совпадают"
EndIf

MsgBox(64, "Info" ,$sInfoText)

[gregaz]

Возможен вариант с использованием ф-ии : _ArrayEx.au3 см. Multidimensional array to string and back

Код:

#include "_ArrayEx.au3"
$sCompare_File = "Compare.ini"
$sSample_File = "Sample.ini"

$aCompare_Sect = IniReadSection($sCompare_File, "HG")
$aSample_Sect = IniReadSection($sSample_File, "JK")
$sSample_SectText=_ArrayToStringEx($aSample_Sect, "|")
$sCompare_SectText=_ArrayToStringEx($aCompare_Sect, "|")
If $sSample_SectText = $sCompare_SectText Then
    $sInfoText="Данные секций  совпадают"
Else
    $sInfoText="Данные секций  НЕ совпадают"
EndIf

MsgBox(64, "Info" ,$sInfoText)

но он работает на порядок медленнее

[pekich]

Спасибо за оперативность, мне тоже интересен вариант сравнения из двух файлов *.ini .
Видимо несовсем понятно объяснил ,что мне нужно,уточню.

Мой код и Ваш работает так ,при успехе:
1. Сравнивается первая строка обоих *.ini >вывод сообщения о совпадении ;
2. Сравнивается вторая строка обоих *.ini >вывод сообщения о совпадении ;
3. Сравнивается третья строка обоих *.ini >вывод сообщения о совпадении ;
4. Сравнивается четвертая строка обоих *.ini>вывод сообщения о совпадении ;
5. Завершение работы скрипта.

Мне нужно так ,при успехе:
1. Сравнивается первая строка обоих *.ini ;
2. Сравнивается вторая строка обоих *.ini ;
3. Сравнивается третья строка обоих *.ini ;
4. Сравнивается четвертая строка обоих *.ini ;
5. Вывод сообщения,что все четыре строки в *.ini файлах совпали ;
6. Завершение работы скрипта.

[gregaz]

Видимо несовсем понятно объяснил ,что мне нужно,уточню. »

Ничего-себе уточнил :

Как тема называется ? разве не так : "Как сравнить два массива не построчно,а целиком?"

И зачем тогда сравнивать построчно

Если тексты всей секции равны , то наверное и каждая строка равна , или я что-то не понимаю

[Creat0R]

Ошибаешься мой код выдает только 1 сообщение при полном успехе »

Он говорил про мой код, ибо когда он написал своё сообщение, твои два сообщения были пустые

Мне нужно так ,при успехе »

Код:

$sCompare_File = "Compare.ini"
$sSample_File = "Sample.ini"

$aCompare_Sect = IniReadSection($sCompare_File, "HG")
$aSample_Sect = IniReadSection($sSample_File, "HG")

$iComp_Ubound = UBound($aCompare_Sect) - 1
$iSamp_Ubound = UBound($aSample_Sect) - 1

$iUbound = $iComp_Ubound
If $iSamp_Ubound > $iComp_Ubound Then $iUbound = $iSamp_Ubound

If $iComp_Ubound <> $iSamp_Ubound Or $iComp_Ubound <= 0 Then
    MsgBox(48, $sCompare_File, "Данные файла [" & $sSample_File & "] не совпадают", 2); несовпадение массива
    Exit
EndIf

$sCompare = "совпадают"

For $i = 1 To $iUbound
    If $aCompare_Sect[$i][0] & $aCompare_Sect[$i][1] <> $aSample_Sect[$i][0] & $aSample_Sect[$i][1] Then
        $sCompare = "НЕ " & $sCompare
        ExitLoop
    EndIf
Next

MsgBox(64, $sCompare_File, "Данные файла [" & $sSample_File & "] " & $sCompare, 2)
Exit

[pekich]

Сижу, пробую, разбираюсь. Завтра к вечеру отпишусь.