[deepred]

Pyrocar,

Cтарайтесь сначала пользоваться поиском по форуму - подобные задачи уже решались.
Дополнительных условий к выбору копируемых файлов нет?
В качестве решения предлагаю скрипт на Vbs (*.vbs):

Код:

Option Explicit 
Dim objFSO, objFile
Dim strSRCFolder, strDSTFolder
Dim Name, Extn, strNewname, strTime

strSRCFolder   = "G:\" ' папка источник
strDSTFolder   = "G:\1"  ' папка приемник

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
if objFSO.FolderExists(strSRCFolder) Then
   if objFSO.FolderExists(strDSTFolder) Then

      For Each objFile In objFSO.GetFolder(strSRCFolder).Files
          Name = objFSO.GetBaseName(objFile)
          Extn = objFSO.GetExtensionName(objFile)
          strTime=Left(Replace(Time,":","-"),5)
          strNewname = "["& Date & ", "& strTime & "]_" & Name &"."& Extn
         'Wscript.Echo  strNewname ' закомментированная строка для отладки и проверки
          objFile.Move strDSTFolder & "\" & strNewname
      Next
    Else
        Wscript.Echo "strDSTFolder: " & strDSTFolder & " не существует!"
        Wscript.Quit 1
    End If
Else
    Wscript.Echo "strSRCFolder: " & strSRCFolder & " не существует!"
    Wscript.Quit 1
End If
Wscript.Quit 0

[Pyrocar]

Спасибо! проблема решена