[amel27]

Код:

Set Shell = WScript.CreateObject("WScript.Shell")

Do
  Drive = GetDriveByFyle("WIN51IP")
  If Len(Drive)>0 Then Exit Do
  MsgBox "Вставьте диск 1",vbOKOnly+vbExclamation+vbApplicationModal,"Пауза"
Loop

MsgRet = MsgBox("Вы хотите установить обновление?",vbOKCancel+vbQuestion+vbApplicationModal,"Пауза")
If MsgRet=2 Then WScript.Quit 2

Shell.Run "CMD /C "& Drive &":\I386\UPDATE\RUNONCE.bat", 0, vbTrue
MsgBox "Сейчас будет произведена перезагрузка компьютера!",vbOKOnly+vbExclamation+vbApplicationModal,"Пауза"

For Each OS In GetObject ("winmgmts:{(Shutdown)}//./root/cimv2").InstancesOf("Win32_OperatingSystem")
  Set Security = OS.Security_
  Set PrivObj = Security.Privileges
  PrivObj.Add(18)
  OS.Win32ShutDown 6
Next

Function GetDriveByFyle(file)
  Dim fso, d, dc
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set dc = fso.Drives
  For Each d in dc
    If d.DriveType = 4 Then
      If fso.FileExists(d.DriveLetter &":\"& file) Then
        GetDriveByFyle = d.DriveLetter
        Exit Function
      End If
    End If
  Next
  GetDriveByFyle = ""
End Function

[deepred]

vosya,

Код:

Set objFSO    = CreateObject("Scripting.FileSystemObject")
Set WSHShell  = WScript.CreateObject("WScript.Shell")
Set colDrives = objFSO.Drives: InStat    = False
    DO: For Each objDrive in colDrives
        IF objDrive.DriveType = 4 And objDrive.IsReady Then
           Install(objDrive.DriveLetter): InStat = True
        End IF
    Next

    IF Not InStat Then Wscript.Echo "Вставьте Диск"
    Loop

Function Install(Strmarker)
strSourceFile = Strmarker & ":\WIN51IP"
Set objFile = objFSO.GetFile(strSourceFile)
    If objFSO.FileExists(objFile) Then 
       MsgRetval = MsgBox("Установить обновление?", _
       vbOKCancel+vbQuestion+vbApplicationModal, _
       "Установка...")
       If MsgRetval=2 Then WScript.Quit (2)
    WSHShellShell.Run "cmd /c "& Strmarker &":\i386\update\runonce.bat", 0, True
    WSHShellShell.Run "cmd /c shutdown /r /t 10", 0, False
    FSO.DeleteFile WScript.ScriptFullName, 0
    Wscript.Quit (0)
    Else
    InStat = False
End if
End Function

PS : я вижу, Amel27, Вы меня уже опередили, не обновил страничку вовремя..., ну ладно, наши способы несколько отличны...
PPS : уточняю по поводу второго сообщения, предшествующего перезагрузке - команда "shutdown" выдаст это предупреждение самостоятельно!

[vosya]

amel27,
deepred,

ребята! большое человеческое спасибо за помощь!