[Creat0R]

См. функций _IE*.

[boxer18181818]

Хотелось бы это организовать через Mozilla Firefox, но о этом браузере ничего не нашёл. Помогите начинающему!!!

[madmasles]

Хотелось бы это организовать через Mozilla Firefox »

Здесь посмотрите:Библиотека для работы с FireFox.
Но если Вам надо на каждой странице производить различные действия, то, имхо, для работы в IE у AutoIt больше возможностей.

[madmasles]

boxer18181818,
Вы , на будущее, вопросы лучше в форуме задавайте, а не в ПМ.

Не могли бы Вы привести небольшой пример такого скрипта

Примерно так:

Код:

#include <IE.au3>

Dim $sUrl[5] = ['http://www.google.ru/', _
        'http://autoit-script.ru/index.php?action=forum', _
        'http://autoit-script.ru/index.php', _
        'http://forum.oszone.net/', _
        'http://forum.oszone.net/forum-103.html']
;задаем массив ссылок, по которым будем переходить
$oIE = _IECreate($sUrl[0])
;открываем IE на адресе с индексом 0 (http://www.google.ru/)
For $i = 1 To UBound($sUrl) - 1
    _IENavigate($oIE, $sUrl[$i])
    ;в цикле переходим по ссылкам из массива
    $sText = _IEBodyReadText($oIE)
    ;читаем текст страницы
    If $sText Then
        ;если прочитали.
        $hFile = FileOpen(@ScriptDir & '\' & $i & '_Test.txt', 2)
        ;открываем файл
        FileWrite($hFile, $sUrl[$i] & @CRLF & @CRLF & $sText)
        ;записывем в него ссылку страницы и ее текст
        FileClose($hFile)
        ;закрываем файл
    EndIf
Next
;переходим обратно на адрес с индексом 0 (http://www.google.ru/)
_IENavigate($oIE, $sUrl[0])

[boxer18181818]

А как потом это всё зациклить на безконечное количество переходов???

[madmasles]

boxer18181818,
Вот так будет работать до тех пор, пока не нажмете Esc:

Код:

#include <IE.au3>

HotKeySet("{ESC}", "_MyExit") ;Esc - выход
$j = 0
Dim $sUrl[5] = ['http://www.google.ru/', _
        'http://autoit-script.ru/index.php?action=forum', _
        'http://autoit-script.ru/index.php', _
        'http://forum.oszone.net/', _
        'http://forum.oszone.net/forum-103.html']

$oIE = _IECreate()
While 1
    For $i = 0 To UBound($sUrl) - 1
        _IENavigate($oIE, $sUrl[$i])
        $sText = _IEBodyReadText($oIE)
        If $sText Then
            $j += 1
            $hFile = FileOpen(@ScriptDir & '\' & $j & '_Test.txt', 2)
            FileWrite($hFile, $sUrl[$i] & @CRLF & @CRLF & $sText)
            FileClose($hFile)
        EndIf
    Next
    Sleep(1000)
WEnd

Func _MyExit()
    If ProcessExists('IEXPLORE.EXE') Then ProcessClose('IEXPLORE.EXE')
    Exit
EndFunc   ;==>_MyExit