[Vadikan]

Как изменить библиотеки в Windows7? »

Написано много кода, но не очень понятно, чего вы пытаетесь добиться. Опишите словами свою цель.

Библиотеки - это обычные XML файлы. Читайте материалы сайта Подробное руководство по использованию библиотек Windows 7

P.S. Вы не первый день на форуме, так что, пожалуйста, используйте тег code для оформления кода (см. в конце шапки темы http://forum.oszone.net/thread-140910.html)

[SvoiLudi]

читал эту статью. поэтому скопировал xml-файл с библиотеками - нифига не работает. значит, что-то не так делаю. что?

[SvoiLudi]

задача - переместить папку МОИ ДОКУМЕНТЫ - с диска C: на диск V:

цель - сохранить эту папку при восстановлении образа диска C:

[Vadikan]

задача - переместить папку МОИ ДОКУМЕНТЫ - с диска C: на диск V: »

А, так вы уже десяток тем по этому вопросу создали...

Вам просто при установке нужно другой раздел для профилей указать с помощью файла ответов, и можно будет обойтись без кучи тем и скриптов.

[видео] Как быстро и грамотно переместить профили пользователей на другой раздел

P.S. Код оформите по правилам, больше просить не буду.

[SvoiLudi]

а если уже стоит винда и нужно такое проделать?

Вам просто при установке нужно другой раздел для профилей указать с помощью файла ответов, и можно будет обойтись без кучи тем и скриптов. Microsoft-Windows-Shell-Setup | FolderLocations | ProfilesDirectory См. также http://support.microsoft.com/kb/929831 »

ВРОДЕ И ПОЛУЧАЮТСЯ ЗАТЕМ ПРОБЛЕМЫ, ЦИТИРУЮ:

Эти автоматической настройки имеют следующие известные проблемы: При использовании автоматической настройки FolderLocations для перемещения пользовательских данных или данных программы в другом месте, кроме папки% SystemDrive%, можно блокировать обновления для других версий Windows Vista или более поздних версий в Microsoft Windows. Если вы используете System Preparation Tool (Sysprep), чтобы применить FolderLocations автоматической настройки, некоторые переходы системной директории не указывают на новое местоположение цели. Следующие переходы каталог системы по-прежнему указывают на старых местах: C: \ Documents и Настройка продолжает указывать на C: \ Users. C: \ ProgramData \ Desktop продолжает указывать на C: \ Users \ Public \ Desktop. C: \ ProgramData \ Documents продолжает указывать на C: \ Users \ Public \ Documents. C: \ ProgramData \ Favorites продолжает указывать на C: \ Users \ Public \ Favorites. Если вы используете Windows Vista программа установки применяются FolderLocations автоматической настройки, переходов системной директории не указывают на новое местоположение цели. Следующие переходы каталог системы по-прежнему указывают на старых местах: C: \ Documents и Настройка продолжает указывать на C: \ Users. C: \ Users \ Default User продолжает указывать на C: \ Users \ Default. C: \ Users \ All Users продолжает указывать на C: \ ProgramData.

C: \ Users \ Имя_Пользователя\ Documents

и выдаётся в библиотеке ДОКУМЕНТЫ, хотя

C: \ Users \ Public \ Documents - не выдаётся (заменяется на v:\Общие\Общие Документы)

[amel27]

задача - переместить папку МОИ ДОКУМЕНТЫ - с диска C: на диск V: »

разве только как пример управления библиотеками из CMD через ShLib и SLUtil
копирование/редирект "Документов" и "Избранного" текущего пользователя:

Код:

@Echo Off

Call :REDIR Personal "V:\Users\Admin\Documents" "C:\Users\Admin\AppData\Roaming\Microsoft\Windows\Libraries\Documents.library-ms"
Call :REDIR Favorites "V:\Users\Admin\Favorites"
Exit

:REDIR
::----------------------------------------
::%1- ID пользовательского каталога
::%2- новый путь к каталогу
::%3- путь к файлу библиотеки (опция)
::----------------------------------------
SetLocal
::--- пути ключей реестра ----------------
Set KEY_SHF=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders
Set KEY_USF=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders
Set KEY_SIW=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Search\CrawlScopeManager\Windows\SystemIndex\WorkingSetRules
Set KEY_SIP=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Search\Gather\Windows\SystemIndex\Sites\LocalHost\Paths
Set KEY_SIS=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Search\Gather\Windows\SystemIndex\StartPages
::--- читаем текущий путь ----------------
For /F "Tokens=2* Delims=	 " %%i In ('REG Query "%KEY_SHF%" /v %~1^|Find "REG_SZ"') Do Set $OLD=%%j
::--- создание/настройка целевой папки ---
If Not Exist "%~2" MD "%~2"
ATTRIB +R -H "%~2"& ATTRIB +H -R "%$OLD%"
ATTRIB -R -H -S "%$OLD%\desktop.ini"
COPY "%$OLD%\desktop.ini" "%~2" /Y
If Exist "%~2\desktop.ini" DEL /F/Q "%$OLD%\desktop.ini"
ATTRIB +R +H +S "%~2\desktop.ini"
::--- копирование содержимого ------------
XCOPY /S/K "%$OLD%\*" "%~2\"
::--- поиск параметров Windows Search ----
For /F "Delims=" %%i In ('REG Query "%KEY_SIW%" /s /f "file:///%$OLD%\\" /d /e^|Find /I "%KEY_SIW%"') Do Set SUB_SIW=%%i
For /F "Delims=" %%i In ('REG Query "%KEY_SIP%" /s /f "file:///%$OLD%\\" /d /e^|Find /I "%KEY_SIP%"') Do Set SUB_SIP=%%i
For /F "Delims=" %%i In ('REG Query "%KEY_SIS%" /s /f "%$OLD%\\" /d /e^|Find /I "%KEY_SIS%"') Do Set SUB_SIS=%%i
::--- замена параметров WindowsSearch ----
If Defined SUB_SIW REG ADD "%SUB_SIW%" /v URL /t REG_SZ /d "file:///%~2\\" /f
If Defined SUB_SIP REG ADD "%SUB_SIP%" /v URL /t REG_SZ /d "file:///%~2\\" /f
If Defined SUB_SIS REG ADD "%SUB_SIS%" /v URL /t REG_SZ /d "%~2\\" /f
::--- правим библиотеку ------------------
If Not "%~3"=="" ShLib Remove "%~3" "%$OLD%"
If Not "%~3"=="" ShLib Add "%~3" "%~2"
If Not "%~3"=="" ShLib SetSaveLoc "%~3" "%~2"
::--- вбиваем новый путь -----------------
REG ADD "%KEY_SHF%" /v "%~1" /t REG_SZ /d "%~2" /f
REG ADD "%KEY_USF%" /v "%~1" /t REG_EXPAND_SZ /d "%~2" /f
::----------------------------------------
EndLocal& GoTo :EOF

P.S. иногда могут возникать конфликты доступа при удалении пути из файла библиотеки

[SvoiLudi]

я правильно понял?

либо использовать предложенный Вами скрипт, либо одну из двух утилит?

Ваш код сработал!!!

[amel27]

либо использовать предложенный Вами скрипт, либо одну из двух утилит »

скрипт - пример использования одной из утилит (ShLib)

[SvoiLudi]

хочу заменить путь

"C:\Users\Admin\AppData\Roaming\Microsoft\Windows\Libraries\Documents.library-ms"

на

v:\Библиотеки с Windows 7 и новее

как это сделать?

скрипт - пример использования одной из утилит (ShLib) »

т.е. эта утилита выдала такой скрипт?

не скачал ещё ни одной утилиты, а скрипт работает