[Creat0R]

Нужен скрипт, который постоянно сидел бы в системном трее и через каждые 2 недели запускал программу (или каждый месяц 10 и 20 числа) »

Вот так примерно:

Код:

#RequireAdmin

;Добавляем программу в автозапуск
If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then _
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')

;Указываем программу на запуск
$sApp = "notepad.exe"

While 1
    If @MDAY = 10 Then
        Run($sApp)

        While @MDAY = 10
            Sleep(60000)
        WEnd
    EndIf

    Sleep(1000)
WEnd

[Anarasius]

Все отлично, но он у меня бесконечно запускает программу через каждую сек

[Creat0R]

он у меня бесконечно запускает программу через каждую сек »

Если 10-ое число? В поставленной задачи ничего не сказано по поводу одноразового запуска

Поправил свой пост.

[Anarasius]

Всеравно, я ставлю сегодняшнее число и запускаю скрипт он начинает бесконечно открывать блокнот, попробуйте сами!

Пробовал без добавления в автозапуск

[Creat0R]

А так:

Код:

#RequireAdmin

;Добавляем программу в автозапуск
If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then _
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')

;Указываем программу на запуск
$sApp = "notepad.exe"

;Указываем число запуска
$nDay = 16

While 1
    If @MDAY = $nDay Then
        Run($sApp)

        While @MDAY = $nDay
            Sleep(60000)
        WEnd
    EndIf

    Sleep(1000)
WEnd

?

[Diamond]

Я бы добавил последнюю дату запуска в реестр или в ini-файл:

читать дальше »

Код:

#RequireAdmin

;Добавляем программу в автозапуск
If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then _
    RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')

;Указываем программу на запуск
$sApp = "notepad.exe"

;Определяем последнюю дату запуска
$sLastDay = IniRead(@ScriptDir & "\test.ini","options", "LastDay", -1)

While 1
    If @MDAY = 10 Or @MDAY = 17 Then
        If $sLastDay <> @MDAY & "." & @MON Then
            ;Запоминаем последнюю дату для текущей сессии:
            $sLastDay = @MDAY & "." & @MON
            ;Запоминаем последнюю дату запуска в ini-файл(на случай перезагрузки компьютера):
            IniWrite(@ScriptDir & "\test.ini","options", "LastDay", $sLastDay)
            Run($sApp)
        EndIf
    EndIf
    Sleep(2000)
WEnd

[FlatX007]

И если комп был в это время выключен то программа должна запуститься при его включении. Заранее спасибо! »

Все самое главное забыли

Вот ... извиняйте если что забыл (Оставлю ка я себе програмку пригодится)
Количество "чисел" для запуска вроде как неограничено, можно хоть 20 раз за месяц...

Код:

#NoTrayIcon
#include <File.au3>

If WinExists(@ScriptName) Then _Exit()
AutoItWinSetTitle(@ScriptName)

Opt("TrayMenuMode",1)
TraySetClick(8)
TraySetIcon("Shell32.dll", 25)
TraySetToolTip ("Планировщик запуска")

HotKeySet("!p", "_Exit") ; Alt + P выход

Global $IniFile = @ScriptDir & "/Data_" & @ScriptName & ".ini"
Global $iMDAY
Global $NumberMonth[3]
       $NumberMonth[0] = 10 ; Нужные числа для запуска
       $NumberMonth[1] = 20
       $NumberMonth[2] = 28
Global Const $iNumberNull = $NumberMonth[0]

If Not FileExists($IniFile) Then _FileCreate($IniFile)

If @Compiled = 1 Then
    If RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName) = "" Then
        $iMsgBox = MsgBox(266532,"","Поместить программу в автозагрузку ?")
        If $iMsgBox = 6 Then RegWrite("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", @ScriptName, "REG_SZ", '"' & @ScriptFullPath & '"')
    EndIf
EndIf

$nAbout  = TrayCreateItem("Тут цопирайты (С) :)")
TrayCreateItem("")
$nExit  = TrayCreateItem("Выйти из планировщика задачь")
TraySetState()

$iIniRead = IniRead($IniFile, "Data", "Run", 0)
If $iIniRead = 0 Then IniWrite($IniFile, "Data", "Run", "<" & @MDAY & "> <" & @MON & ">")

$aiArray = StringRegExp($iIniRead, '<(.*?)>', 3)
If Not (@error) Then
    If @MDAY > $aiArray[0] Then $NumberMonth[0] = @MDAY
    If @MON <>  $aiArray[1] Then $NumberMonth[0] = @MDAY
EndIf

While 1
    Switch TrayGetMsg()
        Case $nExit
            _Exit()
        Case $nAbout
            MsgBox(270400,"About", "Цопирайтинг (С) 2009", 5)

        Case Else
            If @MDAY <> $iMDAY Then
                For $iI = 0 To UBound($NumberMonth) - 1
                    If @MDAY = $NumberMonth[$iI] Then
                        TraySetIcon("Shell32.dll", 246)
                        TrayTip("Запускаем ...", "Планироващик задачь", 0, 1)
                        RunWait("notepad") ; Программа для запуска
                        IniWrite($IniFile, "Data", "Run", "<" & @MDAY & "> <" & @MON & ">")
                        $NumberMonth[0] = $iNumberNull
                        TraySetIcon("Shell32.dll", 25)
                        ExitLoop
                    EndIf
                Next
            EndIf
            $iMDAY = @MDAY
    EndSwitch
WEnd

Func _Exit()
    Exit
EndFunc

[Creat0R]

Все самое главное забыли »

И что это? добавление в автозапуск?

[Diamond]

И если комп был в это время выключен то программа должна запуститься при его включении. Заранее спасибо! Все самое главное забыли »

Я так понял... если запуск на запланированное число был пропущен(например если компьютер в этот день ни разу не включали), то нужно запустить программу как только это станет возможным, т.е. уже не зависимо от назначенного числа.

P.S. ИМХО, это уже почти "Планировщик задач" получается.