[amel27]

Код:

$sKey = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx"
$aDrives = DriveGetDrive("CDROM")

For $i=1 To $aDrives[0]
    If FileExists($aDrives[$i] &"\WIN51") Then $sDVD = $aDrives[$i]
Next

RegWrite($sKey &"\910", "1", "REG_SZ","REGEDIT /S "& $sDVD &"\$OEM$\HKLM.reg")
RegWrite($sKey &"\920", "1", "REG_SZ", "hidcon.exe Shutdown -r -f -t 0")
RegWrite($sKey &"\999", "1", "REG_SZ", $sDVD &"\WPI\WPI.hta")

[Pozia]

amel27, вы как всегда маг и волшебник. Щелкаете проблемы мои как орешки. С кардрийдером проблема ушла, молчит. Появилась теперь другая проблема. Если в DVD приводе диска нет или находится другой без путей которые хочет добавить скрипт (%DVD%\$OEM$\HKLM.reg и %DVD%\WPI\WPI.hta) то выскакивает ошибка с надписью:

Line 8 (File путь к скрипту... )

RegWrite($sKey &"\910", "1", "REG_SZ","REGEDIT /S "& $sDVD &"\$OEM$\HKLM.reg")
RegWrite($sKey &"\999", "1", "REG_SZ", $sDVD &"\WPI\WPI.hta")

Error: Variabl used without being declared.

И кнопка OK.

И в реестр ничего вообще не добовляется. Можно ли как нибудь сделать чтобы производилась проверка наличия нужного диска с правильными путями к файлам и при его отсутствии выскакивало сообщение о необходимости вставить диск и кнопка OK для подтверждения???

[Pozia]

amel27, а как правильно записать в скрипт вот это:

REG ADD %KEY%\920 /VE /D "Перезагрузка..." /f

?

[amel27]

Можно ли как нибудь сделать чтобы производилась проверка наличия нужного диска с правильными путями к файлам и при его отсутствии выскакивало сообщение о необходимости вставить диск и кнопка OK для подтверждения??? »

Код:

$sKey = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnceEx"
$sTag = "WIN51"
$sDVD = ""

$aDrives = DriveGetDrive("CDROM")

While 1
    For $i=1 To $aDrives[0]
        If FileExists($aDrives[$i] &"\"& $sTag) Then $sDVD = $aDrives[$i]
    Next
    If StringLen($sDVD)>0 Then ExitLoop
    MsgBox(48, "Прерывание", 'Вставьте диск с дистрибутивом и нажмите "OK" для продолжения установки.')
WEnd

RegWrite($sKey &"\910", "1", "REG_SZ","REGEDIT /S "& $sDVD &"\$OEM$\HKLM.reg")
RegWrite($sKey &"\920", "1", "REG_SZ", "hidcon.exe Shutdown -r -f -t 0")
RegWrite($sKey &"\999", "1", "REG_SZ", $sDVD &"\WPI\WPI.hta")

RegWrite($sKey &"\920", "" , "REG_SZ", "Перезагрузка...")

как правильно записать в скрипт вот это »

последняя строчка примера

[Pozia]

amel27, спасибо огромное!!! Я уже подумывал кардрийдер выбрасывать и покувать внешний съемный. Спасли!!!

[R.M.L]

спасибо ребята,сегодня мой день,прям в точки попадаю )) думал создать такую тему но оказывается я не один.Незнаю,но я полюбил этот сайт

[FreshMen85]

добрые люди, подправте скриптик так чтобы можно было запускать файл из текущей сессии, а не после перезагрузки. Мне надо запустить файл после полной загрузки OS, ну вот такой вот я превереда, уж извените, если что.

[Pozia]

FreshMen85,

Код:

#NOtrayIcon
#include <GuiConstantsEx.au3>
#include <ComboConstants.au3>
;
$sBSPI_Drives = ""
$sSel_Drive = ""
$sFirst_Drive = ""
$aDrives = DriveGetDrive("All")

;=============================================================================
For $i = 1 To $aDrives[0]
    If DriveStatus($aDrives[$i]) <> "READY" Then ContinueLoop

    If FileExists($aDrives[$i] & "\BSPI\Presetup.exe") Then
        If $sBSPI_Drives = "" Then $sFirst_Drive = $aDrives[$i]
        $sBSPI_Drives &= StringUpper($aDrives[$i]) & "|"
    EndIf
Next

$sBSPI_Drives = StringRegExpReplace($sBSPI_Drives, "\|+$", "")

If StringInStr($sBSPI_Drives, "|") Then
    $hGUI = GUICreate("Выберите диск запуска BSPI", 240, 50)
	
    $Drives_Combo = GUICtrlCreateCombo("", 20, 20, 40, 20, $CBS_DROPDOWNLIST)
    GUICtrlSetData(-1, $sBSPI_Drives, $sFirst_Drive)

    $OK_Button = GUICtrlCreateButton("OK", 80, 19, 60, 25)
    $Cancel_Button = GUICtrlCreateButton("Cancel", 160, 19, 60, 25)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $Cancel_Button
                Exit
            Case $OK_Button
                $sSel_Drive = GUICtrlRead($Drives_Combo)

                ExitLoop
        EndSwitch
    WEnd
ElseIf $sBSPI_Drives <> "" Then
    $sSel_Drive = $sBSPI_Drives
EndIf

If $sSel_Drive <> "" Then RunWait($sSel_Drive & "\BSPI\Presetup.exe")
;=============================================================================

[FreshMen85]

Pozia, спасибо конечно, но мне немного труднова-то разобратся в твоём скрипте. Он сильно большой и я не могу проследить что за что отвечает. Может если тебе это не сильно трудно, сделаеш скрипт на такой вот путь: %CDROM%\AutoInstall\Install_Soft.bat

P.S. Вчера запускал скрипт от amel27, всё было нормально, сегодня востановил старую винду акронисом, скрипт не работаеат, пишет про ошибку в первой строчке. Вобщем мозги скоро начнут плавится, а загадок меньше не становится. Да кстати ещё на одной востановленной версии винды команда:
for %%i in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist %%i:\WIN51 set CDROM=%%i:
, отработала нормально, вот так вот...