[решено] Как сделать,чтобы скрипт после запука,продолжил своё выполн в ЗАДАННОЕ мной время?

Creat0R · Конфигурация компьютера

Цитата sashadeg:

для этого есть специальня команда? »

_NowTime()?

Код:

#include <Date.au3>

_ScheduleStart_Proc("21:05:00")

Func _ScheduleStart_Proc($sStartTime)
    While 1
        If _NowTime() = $sStartTime Then Return 1
        Sleep(100)
    WEnd
EndFunc

sashadeg · Отправлено: **11:53, 23-02-2009** | #3

Цитата Creat0R:

#include <Date.au3> »

Что делает эта команда???

Creat0R · Конфигурация компьютера

Цитата sashadeg:

Что делает эта команда? »

Подключает библиотеку для работы с датой и временем.

sashadeg · Отправлено: **12:12, 23-02-2009** | #5

Мда, капец, я скачал с инета русский справочник команд, ВЕСЬ выучил, НО стока нового от вас узнаю.... СПАСИБО ОГРОМНОЕ,,,,

leprecon · Отправлено: **23:55, 21-03-2009** | #6

А как сделать так, если компьютер был выключен в заданое время, то нужно чтобы скрипт продолжил работу при запуске компьютера.

Creat0R · Конфигурация компьютера

Цитата leprecon:

нужно чтобы скрипт продолжил работу при запуске компьютера »

Записать его в автозапуск?

Код:

RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce", @ScriptName, "REG_SZ", @ScriptFullPath)

leprecon · Отправлено: **00:51, 22-03-2009** | #8

нет, а если например ждал скрипт 21:05 но не дождался

, а комп включили на следующее утро в 9 утра, и что ему опять 21:05 ждать?

Creat0R · Конфигурация компьютера

Цитата leprecon:

а если например ждал скрипт 21:05 но не дождался »

Ну тогда можно в начале скрипта (при его запуске) записать в автозапуск, и если скрипт выполнил что нужно в указанное время, то просто удалить запись из реестра.

amel27 · Отправлено: **06:23, 22-03-2009** | #10

Цитата Creat0R:

RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce", @ScriptName, "REG_SZ", @ScriptFullPath) »

а почему "RunOnce"?.. он же одноразовый - его придется создавать при каждом запуске
думаю скрипт будет проще, если использовать ключ "Run"

Цитата Creat0R:

If _NowTime() = $sStartTime Then Return 1 »

Windows не является ОСью реального времени, поэтому логичней ставить ">=" вместо равенства... Тем более, если речь о возможной перезагрузке... Хотя на самом деле все сложней чем кажется. Предпложим, что комп выключили в "21:00:00" и включили на следующий день в 8:00 - время просрочено, а скрипт этого не сможет определить, выходов два: 1) задавать всегда точную дату/время; 2) сохранять где-нибудь время последнего запуска скрипта. Последний вариант уже напоминает полноценный шедулер с периодическим запуском (раз в год, раз в месяц, etc) и логикой анализа просроченных заданий. Первый вариант "одноразовый" и поэтому проще:

Код:

#include <Date.au3>

$sRegKey = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"
$sRegVal = RegRead($sRegKey, @ScriptName)
If Not($sRegVal = @ScriptFullPath) Then RegWrite($sRegKey, @ScriptName, "REG_SZ", '"'& @ScriptFullPath &'"')

_ScheduleStart_Proc("2009","03","22","21","05","00")
RegDelete($sRegKey, @ScriptName)

Func _ScheduleStart_Proc($iYear, $iMonth, $iDay, $iHour, $iMinute, $iSecond)
    Local $tFileNow, $tFile=_Date_Time_EncodeFileTime($iMonth, $iDay, $iYear, $iHour, $iMinute, $iSecond)
    Local $pFileNow, $pFile=DllStructGetPtr($tFile)
    Do
        Sleep(100)
        $tFileNow = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
        $pFileNow = DllStructGetPtr($tFileNow)
    Until _Date_Time_CompareFileTime($pFileNow, $pFile)>=0
EndFunc