[Iska]

Код:

WScript.Echo WScript.CreateObject("WScript.Shell").ExpandEnvironmentStrings("%AppData%")
WScript.Echo WScript.CreateObject("Shell.Application").NameSpace("shell:AppData").self.Path

Второй способ предпочтительнее.

[Hancog]

Немножко не понял а во втором варианте вместо NameSpace имя файла сохраняемого писать? Просто попробовал не получается

Полный скрипт
Set oXMLHTTP = CreateObject("MSXML2.XMLHTTP")
'подключение
oXMLHTTP.Open "GET", "http://tau.rghost.ru/57502402/image.png", 0
'получение файла
oXMLHTTP.Send
Set oADOStream = CreateObject("ADODB.Stream")
oADOStream.Mode = 3 'разрешение на чтение и запись
oADOStream.Type = 1 'тип данных - Binary
oADOStream.Open
oADOStream.Write oXMLHTTP.responseBody
'сохранение (с перезаписью файла при необходимости)
WScript.Echo WScript.CreateObject("Shell.Application").NameSpace("shell:AppData").self.Path

может чего не понимаю...

[Iska]

Сохраните с расширением «.wsf»:

читать дальше »

Код:

<?xml version='1.0' encoding='windows-1251' standalone='yes'?>
<job>
	<script language='VBScript'>
		<![CDATA[
			Option Explicit

			Const adTypeBinary = 1
			Const adModeReadWrite = 3
			Const adSaveCreateOverWrite = 2


			Dim strUrl

			Dim objXMLHTTPRequest
			Dim objFSO


			strUrl = "http://tau.rghost.ru/57502402/image.png"

			Set objFSO            = WScript.CreateObject("Scripting.FileSystemObject")
			Set objXMLHTTPRequest = WScript.CreateObject("Msxml2.XMLHTTP")

			objXMLHTTPRequest.Open "GET", strUrl,False
			objXMLHTTPRequest.send

			If objXMLHTTPRequest.status = 200 Then
				With WScript.CreateObject("ADODB.Stream")
					.Mode = adModeReadWrite
					.Type = adTypeBinary
					.Open
					.Write objXMLHTTPRequest.responseBody
					.SaveToFile objFSO.BuildPath(WScript.CreateObject("Shell.Application").NameSpace("shell:AppData").self.Path, objFSO.GetFileName(decodeURI(strUrl))), adSaveCreateOverWrite
				End With
			Else
				WScript.Echo "Status: " & CStr(objXMLHTTPRequest.status)
			End If

			Set objXMLHTTPRequest = Nothing
			Set objFSO            = Nothing

			WScript.Quit 0
		]]>
	</script>

	<script language='JScript'>
		<![CDATA[
			function decodeURI(sUrl) {
				return decodeURI(sUrl);
			}
		]]>
	</script>
</job>

[Hancog]

Спасибо,а как мне добавить деректорию в аппдате? ну к примеру appdata\adobe

[Iska]

добавить »

Добавить — означает «создать»? Или имеется в виду — просто дописать к пути в виде «shell:AppData+adobe+имя файла»?

[Hancog]

Нет не создать ну что бы в подпапку аппдаты можно было сохранить

[Iska]

Например, так:

читать дальше »

Код:

<?xml version='1.0' encoding='windows-1251' standalone='yes'?>
<job>
	<script language='VBScript'>
		<![CDATA[
			Option Explicit
			
			Const adTypeBinary = 1
			Const adModeReadWrite = 3
			Const adSaveCreateOverWrite = 2
			
			
			Dim strUrl
			Dim strDestPath
			
			Dim objFSO
			Dim objXMLHTTPRequest
			
			
			strUrl = "http://tau.rghost.ru/57502402/image.png"
			
			Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
			
			strDestPath = objFSO.BuildPath(WScript.CreateObject("Shell.Application").NameSpace("shell:AppData").self.Path, "adobe")
			
			If objFSO.FolderExists(strDestPath) Then
				Set objXMLHTTPRequest = WScript.CreateObject("Msxml2.XMLHTTP")
				
				objXMLHTTPRequest.Open "GET", strUrl,False
				objXMLHTTPRequest.send
				
				If objXMLHTTPRequest.status = 200 Then
					With WScript.CreateObject("ADODB.Stream")
						.Mode = adModeReadWrite
						.Type = adTypeBinary
						.Open
						.Write objXMLHTTPRequest.responseBody
						.SaveToFile objFSO.BuildPath(strDestPath, objFSO.GetFileName(decodeURI(strUrl))), adSaveCreateOverWrite
					End With
				Else
					WScript.Echo "Status: " & CStr(objXMLHTTPRequest.status)
				End If
				
				Set objXMLHTTPRequest = Nothing
			Else
				WScript.Echo "Destination path [" & strDestPath & "] not found."
				WScript.Quit 1
			End If
			
			Set objFSO = Nothing
			
			WScript.Quit 0
		]]>
	</script>
	
	<script language='JScript'>
		<![CDATA[
			function decodeURI(sUrl) {
				return decodeURI(sUrl);
			}
		]]>
	</script>
</job>

[Hancog]

понял,а можно еще в конце запуск файла добавить?

[Hancog]

ап тему