[andr_mozg]

программу нашол, (hwmonitor ) но как ее заставить делать лог в скрытом режими?? что бы она не отображалась не в трее не открывала окно.

[andr_mozg]

температупа с HDD http://www.autoitscript.com/forum/in...mperature&st=0
температура GPU nVidia http://www.autoitscript.com/forum/in...1&#entry587389

CPU - ????

[timsky]

http://www.cpuid.com/pcwizard.php - есть дамп в текст.

еще есть everest http://www.lavalys.com/index.php?lang=en , он тоже должен уметь это делать

[andr_mozg]

про эти пронраммы я прекрасно знаю, и про многии другие, но они не подходят.

[Belfigor]

Поройся в CompInfo.au3, про температуру не помню но помню но в целом, инфу о процессоре, видяхе там можно посмотреть.

[andr_mozg]

я всю ее перерыл, много хорошего пользую, про температуро там нет нечего..

[timsky]

Есть потребность в скрипте , который ковсему прочему, мог бы в лог писать еще и температуру устройств, не вреальном времени а хотябы в тот момент когда скрипт отрабатывает. Главное условие что бы это было тихо и без запуска приложений с GUI, если это будит сторонняя программа но работающая через командную строку .. то подайдет... »

про эти пронраммы я прекрасно знаю, и про многии другие, но они не подходят »

Ты сам себе противоречишь. Почему не подходят? Есть ком. строка, есть дамп...

[amel27]

andr_mozg, штатной поддержки в Windows нет (пока?), Intel никаких (бесплатных) API/SDK не предоставляет, многие графические тулзы лишь реклама своих SDK, которые продаются уже за приличные деньги... Для надоверчивых - официальный ответ на оффсайте Intel... отсюда вывод: единственный выход писать AutoIT-врапперы для доступных графических утилит... Благо, AutoIT под такие цели и "заточен"...

Мне приглянулась прога RightMark CPU Clock Utility – простой дизайн, много настроек, поддержка лога... Жаль, давно не обновлялась, но вроде пока справляется. Проверил прогу в двух режимах: режиме вывода данных в лог-файл (есть возможность просмотреть все предыдущие значения) и режиме оперативного чтения данных - оба режима легко автоматизируются. Каждый режим соответствует определенной настройке программы, поэтому перед запуском EXE нужно восстановить их в ветку HKCU\Software\RightMark (например, из REG-файла). Общий алгоритм скрипта:

0. Настаиваем RMClock в нужный режим (в скрипте опущено)
1. Запускаем RMClock.EXE
2. Ожидаем и удаляем иконку из трея
3. Входим в цикл чтения данных (из файла или окна программы)

В скрипте использована библиотека SysTray_UDF с форума оффсайта

Режим LOG-файла >>

Код:

#include <SysTray_UDF.au3>

; Расположение RMClock
$RMClockDir = @ProgramFilesDir &"\RMClock"
$RMClockExe = $RMClockDir &"\RMClock.Exe"
$RMClockLog = $RMClockDir &"\RMClock.Log"
; Запуск RMClock
$PID = Run($RMClockExe, $RMClockDir)
ProcessWait("RMClock.exe")
Sleep(1000) ; минимальный период обновления лога

Global $hLog = FileOpen($RMClockLog, 0)
Global $aCPU, $iCPU=0, $iTmp=0

While 1
    ; Читаем строку из лог-файла
    $sLine = FileReadLine($hLog)
    If @error = -1 Then
        If ProcessWaitClose("RMClock.exe", 1) Then ExitLoop
        ContinueLoop
    EndIf
    ; Разбор строки
    $aCPU = StringRegExp($sLine, "(?:CPU: |CoreTemp: )([\d.]+)", 3)
    If @error Then ContinueLoop
    ; Подсчет средней температуры по всем ядрам
    If $iTmp>0 And $aCPU[0]=0 Then
        ; Вывод данных/сброс счетчиков
        ConsoleWrite("Avarage CPU Temperature: "& $iTmp/($iCPU+1) &@CRLF)
        $iTmp=0
    EndIf
    $iCPU = $aCPU[0]
    $iTmp+= $aCPU[1]
Wend

REG-файл настроек >>

Код:

REGEDIT4

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowPerfLevel"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowFreqInTray"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowLoadInTray"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowCriticalBalloons"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"TaskbarButton"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"RunMinimized"=dword:00000001

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"EnableLogging"=dword:00000001

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"LoggingFlags"=dword:000000bf

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ActivePage"=dword:00000001

Оперативный режим >>

Код:

#include <SysTray_UDF.au3>
AutoItSetOption("WinDetectHiddenText",1)

; Расположение RMClock
$RMClockDir = @ProgramFilesDir &"\RMClock"
$RMClockExe = $RMClockDir &"\RMClock.Exe"
; Запуск RMClock
$PID = Run($RMClockExe, $RMClockDir)
; Ожидаем и удаляем иконку из трея
Do
    Sleep(100)
    $iTrayIcon = _SysTrayIconIndex("RMClock.exe")
Until $iTrayIcon >=0
_SysTrayIconRemove($iTrayIcon)

; Цикл чтения/разбора текста окна
While ProcessExists($PID)
    $iTmp = 0
    $sTxt = WinGetText("RightMark")
    $aTmp = StringRegExp($sTxt, "Core temp\.[\n\r]+([\d.]+)", 3)
    ; Суммируем по всем ядрам
    For $i=0 To UBound($aTmp)-1
        $iTmp += $aTmp[$i]
    Next
    $iTmp = $iTmp/UBound($aTmp) ; Среднее значение

        ConsoleWrite("Avarage CPU Temperature: "& $iTmp &@CRLF)
    Sleep(1000)
WEnd

REG-файл настроек >>

Код:

REGEDIT4

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowPerfLevel"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowFreqInTray"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowLoadInTray"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ShowCriticalBalloons"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"TaskbarButton"=dword:00000000

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"RunMinimized"=dword:00000001

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"ActivePage"=dword:00000001

[HKEY_CURRENT_USER\Software\RightMark\RMClock]
"EnableLogging"=dword:00000000

ВАЖНО! Не стоит жать все подряд и менять настройки CPU/MB! RMClock работает на низком уровне и результат непредсказуем!

[andr_mozg]

andr_mozg, штатной поддержки в Windows нет (пока?), Intel никаких (бесплатных) API/SDK не предоставляет, многие графические тулзы лишь реклама своих SDK, которые продаются уже за приличные деньги... Для надоверчивых - официальный ответ на оффсайте Intel... отсюда вывод: единственный выход писать AutoIT-врапперы для доступных графических утилит... Благо, AutoIT под такие цели и "заточен"... »

спасибо... все стало понятно.... программа не плохая, поковыряю ее...