[IntuitOS]

Почему-то не получается. Где должна создаться эта нуль-папка?

мой скрипт с изменнёным путём к папке

PHP код:

@Echo Off

ChCp 1251>Nul

If "%~1"=="" (

    Echo The correct syntax:

    Echo %~nx0 "e:\Проекты\Сжатие\DV"

    Pause>Nul

    Exit

)

For /F "Tokens=1 Delims=." %%i In ('WMIC OS Get LocalDateTime^|Find "."') Do Set t=%%i

Set zDT=_Zero_%t:~2,2%%t:~4,2%%t:~6,2%_%t:~8,2%-%t:~10,2%

Set f=%~1& Set cnt=2& Set c=0& Set cf=0

:_loop

    If "%f:~0,1%"=="\" Set /A cnt+=1

    Set f=%f:~1%

If Defined f GoTo _loop

Set /A cntI=cnt-1



If "%~2"=="" (

    If Exist "%~1*" Call :_makeDir "%~1%zDT%"

    Call :_item "%~1" "%~1%zDT%" "%~1" "%cnt%" "%~1%zDT%" "%~dpn1%zDT%%~x1"

    If Exist "%~1*" For /R "%~1%zDT%" %%f In (.) Do Set /A cf+=1

) Else (

    Call :_makeDir "%~dp1%zDT%"

    For %%i In (%*) Do Call :_item "%%~i" "%~dp1%zDT%%%~nxi" "%~dp1%%~nxi" "%cntI%" "%~dp1%zDT%" "%~dp1%zDT%%%~nxi"

    For /R "%~dp1%zDT%" %%f In (.) Do Set /A cf+=1

)

Echo Complete!

Echo Folders=%cf%    Files=%c%

Echo.

Pause

Exit



:_item

If Exist "%~1*" (

    xCopy /T /E /H /K "%~1" "%~2"|| GoTo :_err

    PushD "%~3"

    For /F "tokens=%~4* delims=" %%a In ('Dir /S /B /A:-D') Do (

        If "%%~b"=="" (CD.>"%~5%%~a") Else CD.>"%~5%%~a%%~b"

        Set /A c+=1

    )

    PopD

) Else (

    CD.>"%~6"

    Set /A c+=1

)

GoTo :EOF



:_err

For /R "%~2" %%f In (.) Do Set erf=%%f

Set erf=%erf:~0,-2%

Call Set erf=%%erf:%~2=%~1%%

RD /S /Q "%~5"

Echo Error xCopy on file:

Echo %erf%

Pause>Nul

Exit



:_makeDir

If Exist "%~1" RD /S /Q "%~1"

MD "%~1"

GoTo :EOF 

[gora]

Где должна создаться эта нуль-папка? мой скрипт с изменнёным путём к папке »

Нуль-копия папки создается рядом с исходной с добавление к имени суффикса _Zero_yyMMdd_HH-mm
Править скрипт не надо. Нужно его запустить с параметром в качестве которого нужно указать полный путь к папке, которую нужно обработать, заключенного в кавычки.
Пример:

Код:

ZeroCopy.bat "E:\Temp\путь к Вашей папке"

[Vadikan]

gora, надо, чтобы люди клали скрипт в папку - это избавит от вопросов^^

[gora]

клали скрипт в папку »

Скрипт может делать нуль-копию не одной папки, а сразу нескольких расположенных по разным путям. Кроме папок ему можно передать пути к файлам или комбинации путей папок\файлов.

А для совсем простого использования этого функционала у меня есть такая же опция в SetTools. Там просто выделяются нужные объекты и нажимается пункт в контекстном меню.

[Vadikan]

gora, ок, тогда в шапке понятно объясните это тем, кто будет послан сюда

[40rus]

А если имена файлов в обрабатываемой папке на китайском языке, как тогда быть?