[Busla]

Как это реализовать? »

так а с чем у вас затруднения?
FOR /? напомнит, как разбить вывод DIR на части

или воспользуйтесь FORFILES

[username-qq]

Я не умею писать скрипты такой сложности

[megaloman]

Код:

@Echo Off                                                                                                  
	Call :@Files "Z:\Test\До" "Z:\Test\После"  "jpeg" "_201"
GoTo :Eof

:@Files
	FOR /F "usebackq delims=" %%f IN (`2^>nul Dir /B /A:-D /S "%~1\*%~4*.%~3"`) DO (
		If Exist "%%f" Call :@Moveing "%%f" %2 %3 %4  
	)
GoTo :Eof

:@Moveing
	Set "Fold=%~n1"
	Call Set "Fold=%%Fold:%~4=:%%"
	FOR /F "delims=:" %%n IN ("%Fold%") DO Set "Fold=%%n"
	If Not Exist "%~2\%Fold%" Md "%~2\%Fold%"
	>nul Move /Y "%~dp1%Fold%%~4*.%~3" "%~2\%Fold%\" 
GoTo :Eof

[username-qq]

@Echo Off Call :@Files "Z:\Test\До" "Z:\Test\После" "jpeg" "_201" GoTo :Eof :@Files FOR /F "usebackq delims=" %%f IN (`2^>nul Dir /B /A:-D /S "%~1\*%~4*.%~3"`) DO ( If Exist "%%f" Call :@Moveing "%%f" %2 %3 %4 ) GoTo :Eof :@Moveing Set "Fold=%~n1" Call Set "Fold=%%Fold:%~4=:%%" FOR /F "delims=:" %%n IN ("%Fold%") DO Set "Fold=%%n" If Not Exist "%~2\%Fold%" Md "%~2\%Fold%" >nul Move /Y "%~dp1%Fold%%~4*.%~3" "%~2\%Fold%\" GoTo :Eof »

Спасибо за помощь, но у меня почему-то не сработало.

Дополню: Файлы создаются по шаблону "ИМЯ_ГОД-МЕСЯЦ-ДЕНЬ-ЧАСЫ-МИНУТЫ-СЕКУНДЫ-ДОЛИСИКУНД_САЙТ_ПРЯМАЯССЫЛКА.jpeg"

Тоесть ИМЯ может меняться как угодно, не только File№... (добавлю в шапку)

[megaloman]

username-qq, Вы свои пути к файлам прописали? В этих путях есть русские символы? Если есть - сохраните батник в 866 кодировке. Не сработало - это как? Сообщения об ошибках? Переименуйте Ваш батник, который не сработал, в txt-файл и приложите к сообщению.
Скрипту фиолетово, какое имя стоИт перед заданной подстрокой (здесь, по Вашему пожеланию, _201)
В принципе, при вызове функции :@Files можно прописать иную подстроку для опознавания имени, расширение, пути к папкам.

[username-qq]

сохраните батник в 866 кодировке »

Помогло сохранение в 866 кодировке.


ОГРОМНОЕ СПАСИБО!