[Iska]

Из командной строки это выглядит примерно так: edit_xls.vbs Excel.xlsx 1 2 3 "X date" … 3 - номер листа ( вот на номере листа он у меня и ошибку кидает) »

Какую именно ошибку? Где приложенный образец файла «Excel.xlsx»?

Если именно номер листа, а не имя — тогда никак не:

Код:

set s = b.sheets ("" & xlssheets & "")

а:

Код:

set s = b.sheets(xlssheets)

можете даже уточнить как:

Код:

set s = b.sheets(CLng(xlssheets))

[DEDI]

Iska, Спасибо!!!

Вот скрипт: (Рабочий )

читать дальше »

Код:

Dim xlsFileName
Dim xlsx
Dim xlsy
Dim xlssheets
Dim xlsvalue

xlsFileName = WScript.Arguments.Item(0)
xlsx = WScript.Arguments.Item(1)
xlsy = WScript.Arguments.Item(2)
xlssheets = WScript.Arguments.Item(3)
xlsvalue = WScript.Arguments.Item(4)
set fso = createobject("Scripting.FileSystemObject")
set co = createobject("excel.application")
set b = co.workbooks.open(xlsFileName)
set s = b.sheets(CLng(xlssheets))
s.Cells(CLng(xlsx),CLng(xlsy)).Value = xlsvalue
b.save
b.close true
co.quit

Но может будут еще варианты интересные?)

[Iska]

Но может будут еще варианты интересные?) »

Держите «интересный вариант» — то же самое, но с проверками:

читать дальше »

Код:

Option Explicit

Dim objFSO

Dim strSourceFile
Dim intWorksheetNumber
Dim intRowNumber
Dim intColumnNumber
Dim strNewValue


If WScript.Arguments.Count = 5 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FileExists(strSourceFile) Then
		Select Case LCase(objFSO.GetExtensionName(strSourceFile))
			Case "xls", "xlsx"
				If IsNumeric(WScript.Arguments.Item(1)) Then
					intWorksheetNumber = CInt(WScript.Arguments.Item(1))
					
					If IsNumeric(WScript.Arguments.Item(2)) Then
						intRowNumber = CInt(WScript.Arguments.Item(2))
						
						If IsNumeric(WScript.Arguments.Item(3)) Then
							intColumnNumber = CInt(WScript.Arguments.Item(3))
							
							strNewValue = WScript.Arguments.Item(4)
							
							With WScript.CreateObject("Excel.Application")
								With .Workbooks.Open(strSourceFile)
									If .Worksheets.Count >= intWorksheetNumber Then
										.Worksheets.Item(intWorksheetNumber).Cells.Item(intRowNumber, intColumnNumber).Value = strNewValue
									Else
										WScript.Echo "Worksheet number [" & WScript.Arguments.Item(1) & "] greater then worksheets count in workbook."
										.Close
										.Application.Quit
										WScript.Quit 7
									End If
									
									.Save
									.Close
								End With
								
								.Quit
							End With
						Else
							WScript.Echo "Column number [" & WScript.Arguments.Item(3) & "] is not a numeric value."
							WScript.Quit 6
						End If
					Else
						WScript.Echo "Row number [" & WScript.Arguments.Item(2) & "] is not a numeric value."
						WScript.Quit 5
					End If
				Else
					WScript.Echo "Worksheet number [" & WScript.Arguments.Item(1) & "] is not a numeric value."
					WScript.Quit 4
				End If
			Case Else
				WScript.Echo "Source file [" & strSourceFile & "] probably is not an Excel document."
				WScript.Quit 3
		End Select
	Else
		WScript.Echo "Source file [" & strSourceFile & "] not found."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Source file> <Worksheet number> <Row number> <Column number> <New cell's value>"
	WScript.Quit 1
End If

WScript.Quit 0