[Creat0R]

Drsmog,

Этот скрипт проверяет всю страницу в блокноте на наличии знаков

Задача была поставлена значит неясно...

Надо чтоб возле каждого символа писал слово

А это уже совсем другая задача

Что то вроде этого:

Код:

$NotepadTitle = "[CLASS:Notepad]"

Run(@WindowsDir & "\Notepad.exe")
WinWait($NotepadTitle)

ControlSetText($NotepadTitle, "", "Edit1", "+" & @CRLF & "-" & @CRLF & "?")

$EditText = ControlGetText($NotepadTitle, "", "Edit1")

;Разделим весь текст из блокнота по строчкам, и заменим в каждой строчке по надобности
$SplitText = StringSplit($EditText, @CRLF)
$NewText = ""
For $i = 1 To UBound($SplitText)-1
    If StringInStr($SplitText[$i], "+") Then
        $SplitText[$i] = StringReplace($SplitText[$i], "+", "+ это плюс")
    ElseIf StringInStr($SplitText[$i], "-") Then
        $SplitText[$i] = StringReplace($SplitText[$i], "-", "- это минус")
    ElseIf StringInStr($SplitText[$i], "?") Then
        $SplitText[$i] = StringReplace($SplitText[$i], "?", "? это вопрос")
    EndIf
    $NewText &= $SplitText[$i] & @CRLF
Next

ControlSetText($NotepadTitle, "", "Edit1", $NewText)

MsgBox(0, "", "Сделано!")

;Просто закроем то что открыли
WinClose($NotepadTitle)
WinWaitClose($NotepadTitle, "", 1)
If WinActive("[CLASS:#32770]", "&") Then ControlClick("[CLASS:#32770]", "&", "Button2")

fak1r,
Увы, мне тоже никогда не приходилось производить авторизацию на сайте/форуме, я поищю на оф. форуме, возможно там кто-то уже делал подобное...

[Drsmog]

Спасибо !!! Ну вроде то что надо

[Creat0R]

Два вопроса на повестке дня:

1) Возможно ли отключить (временно) устройство ввода (клавиатуру)? позже нужно будет его включить, без “побочных эффектов”

2) Как определить, установлен ли Flash Player для Internet Explorer?
Обсуждение на оф. форуме зашло в тупик, функция чуть ниже возвращает True, однако при открытии странички с роликом на YouTube к примеру, получаю предупреждение о том что нужно установить Flash Player...

Код:

Func ShockWavePlayer_Installed()
    Local $sObjRead = RegRead("HKCR\CLSID\{D27CDB6E-AE6D-11cf-96B8-444553540000}\ProgID", "")
    Local $sFlashObj = ObjCreate($sObjRead)
    If Not IsObj($sFlashObj) Then Return False
    Return True
EndFunc

[Creat0R]

AutoIt v3.2.10.0 Release!!!

25 ноября, 2007 - v3.2.10.0

• ВНИМАНИЕ: Следующий выпуск AutoIt будет иметь следующие изменения, которые нарушат обратную совместимость:
• FileInstall() будет переписана с нуля. FileInstall() функция останется, но не будет действовать таким же образом как ранее. Новые реализации появятся в будущих бета версиях.
• Библиотека GUIConstants.au3 стала излишней, она будет идентична GUIConstantsEx.au3. Самый простой способ преодалеть это изменение, заключается в замене всех GUIConstants.au3 на GUIConstantsEx.au3, затем запустите Au3Check, и включите все недостающие библиотеки и константы пока все ошибки не будут исчерпаны.
  Это изменение желательно сделать сейчас, оно не требует ожидания будущей бета-версии. В какой-то момент в ходе следующей бета-версии, GUIConstants.au3 станет идентичной GUIConstantsEx.au3, и тогда скрипты использующие GUIConstants.au3 могут работать некорректно (в зависимости от констант, которые используются в скриптах).

• Изменено: DllCall() Новый метод передачи типов ByRef используя *.
• Изменено: DllCall(): short_ptr, long_ptr, и int_ptr типы запрещены. Используйте short*, long* и int* соответственно.
• Изменено: Сняты ограничения на Execute().
• Изменено: PCRE движок регулярных выражений обновлен до 7,4.

• Добавлено: 64-битные (x64) версии AutoIt, Aut2Exe, Au3Info и AutoItX (см. здесь).
• Добавлено: DllCallbackRegister(), DllCallbackGetPtr() и DllCallbackFree() [Ураааа!].
• Добавлено: DllCall() теперь принимает двойные типы, int64, uint64, wparam и lparam.
• Добавлено: SendKeepActive().
• Добавлено: ControlTreeView() [Ураааа!].
• Добавлено: ProcessGetStats().
• Добавлено: VarGetType() [Ураааа!].
• Добавлено: макрос @AutoItX64.
• Добавлено: Au3Info: Информация идентификатора для окон и контролей (элементов GUI).
• Добавлено: DllStructCreate() добавлен ключ "align" для установки согласования структуры.

• Исправлено: Control...() функции при использовании CLASS и TEXT вместе иногда приводит к неправильному результату.
• Исправлено: Control ...() функции при использовании CLASSNN иногда приводит к неправильному результату.
• Исправлено: Предпросмотр панели задач в Windows Vista вызывает проблемы с соответствием (поиском) окон.
• Исправлено: $var = $var не выводило ошибку если переменная $var не обьявлена.
  Исправлено: GUICtrlSetImage() регрессии с изменением размера в 3.2.4.9.
• Исправлено: GUICtrlCreateListView() без колонок (Columns).
• Исправлено: Экстра уведомление при использовании цветной кнопки.
• Исправлено: IniReadSectionNames() для секции без имени ( [] ).
• Исправлено: Opt( "WinTitleMatchMode", Default) фатальная ошибка.
• Исправлено: GUICtrlSetStyle() с $ES_READONLY плохой $WS_TABSTOP.
• Исправлено: AutoIt вылетает при выходе, если в функциях Win...() COM-объект используется как заголовок.
• Исправлено: ProcessExists() с сервисным процессом под Win2K.
• Исправлено: DefPushButton поведение [Ураааа!].
• Исправлено: ControlCommand(SelectString) порядок отбора.
• Исправлено: Массив не может иметь 2 ^ 24 записей (элементов).
• Исправлено: GuiCreateMenu() на окна без заголовка и без области клиентской части.
• Исправлено: WinWaitActive() иногда не срабатывает после WinActivate().
• Исправлено: При использовании GUIRegisterMsg() в цикле, не срабатывает отмена ригестрации.
• Исправлено: Фокус на ES_READONLY Edit контроля.
• Исправлено: Многочисленные исправления в UDF'ах.

Перевод by CreatoR (мой), мод на перевод от Google

---

P.S

Скажу от себя, что в этой версии, как я и писал ранее, разработчики сделали поворот в 360 градусов, изменили многие функции, добавили новые. Да, теперь чтобы перейти на новую версию, нужно будет поменять многие (если не все) наши скрипты, я если честно не спешу этого делать, т.к у меня их слишком много - разработчики знают о том, что подобные перемены проблематичны скриптерам, но понаблюдав за их действиями (на оф. форуме), можно понять, что такие перемены оправданы, тем более что это принесёт пользу в будущем, ведь рано или поздно нужно что-то менять, улучшать, и лучше поменять всё(?) одним махом, чем каждый раз по чуть чуть, мучаясь переписывая скрипты.

Happy Scripting!!!

[amel27]

Creat0R

при открытии странички с роликом на YouTube к примеру, получаю предупреждение о том что нужно установить Flash Player »

не знаю как надо, но по тому линку который ты указал проверка производится по алгоритму (вытащил из HTML):

Код:

MsgBox(0, "", ShockwaveDetectAxVer(0))

; $iVerReq=0 - возврат текущей версии
; $iVerReq>0 - соответствие минимальным требованиям к версии
Func ShockwaveDetectAxVer($iVerReq)
    Local $i, $iVer, $sVer
    For $i=8 To 1 Step -1
        $sVer = GetShockwaveVer($i)
        If $sVer <> '0.0' Then
            $iVer = Number($sVer)
            If $sVer='1.0' Then $iVer = 6
            If $iVerReq Then Return $iVer>=$iVerReq
            Return $iVer
        EndIf
        If $iVerReq Then Return False
        Return 0
    Next
EndFunc

Func GetShockwaveVer($iVer)
    Local $swControl=ObjCreate("SWCtl.SWCtl." & $iVer), $sVer = '0.0'
    If IsObj($swControl) Then
        $sVer = $iVer + '.0'
        $sVer = $swControl.ShockwaveVersion("")
        Return $sVer
    EndIf
EndFunc

[amel27]

Creat0R

Возможно ли отключить (временно) устройство ввода (клавиатуру)? »

на базе скрипта-кейлоггера получилось вот что:

Код:

; Скрипт для версии v3.2.10.0

Global Const $WH_KEYBOARD_LL = 13

Global $hKeyProc = DllCallbackRegister ("_KeyProc", "int", "int;ptr;ptr")
Global $hmod = DllCall("kernel32.dll","hwnd","GetModuleHandle","ptr",0)
Global $hHook = DllCall("user32.dll","hwnd","SetWindowsHookEx","int", $WH_KEYBOARD_LL, _
    "ptr", DllCallbackGetPtr($hKeyProc), "hwnd", $hmod[0], "dword", 0)

MsgBox(4096, "", 'После нажатия "Ok" клавиатура будет заблокирована на 10 сек.')
Sleep(10000)
MsgBox(4096, "", 'Клавиатура разблокирована!')

OnAutoItExit()
Exit

Func _KeyProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then
         $ret = DllCall("user32.dll","long","CallNextHookEx","hwnd", $hHook[0], _
            "int",$nCode, "ptr", $wParam, "ptr", $lParam)
        Return $ret[0]
    EndIf
    Return 1
EndFunc

Func OnAutoItExit()
    DllCall("user32.dll","int","UnhookWindowsHookEx","hwnd",$hHook[0])
    DllCallbackFree($hKeyProc)
EndFunc

[Creat0R]

amel27,
Спасибо, но функция всегда возвращает 0 , у меня на компе установлен Flash Player.
Объекта SWCtl.SWCtl у меня нет, возможно это не стандартный объект...

Но вот piccaso вроде нашёл решение, у меня, где есть флэш (для IExplorer), возвращает 9, на компе без флэша пока нет возможности проверить:

Код:

Global $oErr = ObjEvent("AutoIt.Error","_ComError")
ConsoleWrite(_FlashMajorVersion()  & @CRLF)

Func _FlashMajorVersion()
    Local $oSwf,$sVersion
    $oSwf = ObjCreate("ShockwaveFlash.ShockwaveFlash")
    if @error Then Return 0 ; No flash at all
    $oSwf.AllowScriptAccess = "always"
    $sVersion = $oSwf.GetVariable("$version")
    if @error Then
       $oSwf = ObjCreate("ShockwaveFlash.ShockwaveFlash.3")
       if @error Then
         $oSwf = ObjCreate("ShockwaveFlash.ShockwaveFlash.2")
         if @error then return 0
         Return 2
       EndIf
       Return 3
    EndIf
    $sVersion = StringTrimLeft($sVersion,3)
    $sVersion = StringLeft($sVersion,StringInStr($sVersion,",")-1)
    Return Number($sVersion)
EndFunc

Func _ComError()
   ; Just set @error, the script will handle it...
   Local $iErr = $oErr.number
   if $iErr = 0 Then $iErr = -1
   SetError($iErr)
EndFunc

на базе скрипта-кейлоггера получилось вот что

Получилось то что надо!!! я правда поменял концепцию примера, во-первых потому то ещё не ставил последнюю версию, а во-вторых потому что мне нужно иметь возможность включать/выключать клавиатуру по запросу (не при выходе из скрипта)...

Код:

#include <DllCallBack.au3>
Global $hWinHook

$CallBackProc = TogglePlugKeyBoard()
MsgBox(4096, "", "Клавиатура заблокирована, нажмите OK для разблокирования.")

TogglePlugKeyBoard($CallBackProc)
MsgBox(4096, "", "Клавиатура разблокирована!")

Exit

Func TogglePlugKeyBoard($hCallProc=0)
    If IsArray($hWinHook) Then
        DllCall("user32.dll", "int", "UnhookWindowsHookEx", "hwnd", $hWinHook[0])
        _DllCallBack_Free($hCallProc)
        Return 0
    EndIf

    Local Const $WH_KEYBOARD_LL = 13
    Local $hKeyProc = _DllCallBack("_KeyProc", "int;ptr;ptr")
    Local $hMod = DllCall("kernel32.dll", "hwnd", "GetModuleHandle", "ptr", 0)
    $hWinHook = DllCall("user32.dll", "hwnd", "SetWindowsHookEx", _
        "int", $WH_KEYBOARD_LL, _
        "ptr", $hKeyProc, _
        "hwnd", $hMod[0], _
        "dword", 0)
    Return $hKeyProc
EndFunc

Func _KeyProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then
        Local $iRet = DllCall("user32.dll", "long", "CallNextHookEx", "hwnd", $hWinHook[0], _
            "int", $nCode, _
            "ptr", $wParam, _
            "ptr", $lParam)
        Return $iRet[0]
    EndIf
    Return 1
EndFunc

Но это мелочи, главное что оно блокирует все(?) клавишы, на любой клавиатуре

P.S
Кстати, функция OnAutoItExit вызывается по умолчанию, её не обязательно вызывать ( OnAutoItExit() ).

[amel27]

Creat0R

функция всегда возвращает 0 »

была ошибка - исправил... чес говоря не проверял - просто тупо сконвертировал

Объекта SWCtl.SWCtl у меня нет, возможно это не стандартный объект »

не знаю, у меня после установки плеера объект появился... просто интересно - разные сайты используют разный код для обнаружения... попадался еще один вариант, который был приведен piccaso и использует свойство ShockwaveVersion объекта SWCtl.SWCtl

функция OnAutoItExit вызывается по умолчанию, её не обязательно вызывать ( OnAutoItExit() )

спасибо, буду знать

[Creat0R]

amel27,

у меня после установки плеера объект появился

И ещё у многих... видимо это что-то специфичное/системно-зависимое/условное

Я на днях (максимум в субботу) проверю скрипт от piccaso, мне кажется что он сработает (вернёт 0 или ошибку).

По поводу примера для клавы... есть подозрение что это тот же BlockInput, только для клавиатуры, т.к Ctrl Alt Del всё же работает (клаву не включает, но вызывает Диспетчер задач)... нет, я конечно не хочу блокировать и эти клавиши, но просто интересно, действительно ли блокируются все клавиши кроме этих, как бы это проверить точно?

[amel27]

Creat0R

Ctrl Alt Del всё же работает »

гы, а эта комбинация неотключаемая aka "in design" - требование безопасности

В том скрипте что я прикрепил, замени создание строки состояния (Label) на настоящий StatusBar, и полученное имя видео отобрази в этом статус баре »

подправил штатную _GUICtrlStatusBar_SetText() для случая юникода...
если на вход подать результат _Utf8ToUnicode() ту что приводил выше, то текст отобразится корректно... там номер сообщения отличается на 10

Код:

; Вариант установки текста статус-бара для юникода
; $binUTF16 - текст, тип Binary

Func _GUICtrlStatusBar_SetUTF16($hWnd, $binUTF16, $iPart = 0, $iUFlag = 0)
    If $Debug_SB Then _GUICtrlStatusBar_ValidateClassName($hWnd)
    Local $ret, $struct_String, $sBuffer_pointer, $struct_MemMap, $Memory_pointer
    $struct_String = DllStructCreate("byte[" & BinaryLen($binUTF16) & "];byte[2]")
    $sBuffer_pointer = DllStructGetPtr($struct_String)
    DllStructSetData($struct_String, 1, $binUTF16)
    If _GUICtrlStatusBar_IsSimple($hWnd) Then $iPart = $SB_SIMPLEID
    If _WinAPI_InProcess($hWnd, $__ghSBLastWnd) Then
        $ret = _SendMessage($hWnd, $SB_SETTEXT+10, BitOR($iPart, $iUFlag), $sBuffer_pointer, 0, "wparam", "ptr")
    Else
        $Memory_pointer = _MemInit($hWnd, StringLen($sText) + 1, $struct_MemMap)
        _MemWrite($struct_MemMap, $sBuffer_pointer)
        $ret = _SendMessage($hWnd, $SB_SETTEXT+10, BitOR($iPart, $iUFlag), $Memory_pointer, 0, "wparam", "ptr")
        _MemFree($struct_MemMap)
    EndIf
    Return $ret <> 0
EndFunc