.: NSIS

kotkovets · Конфигурация компьютера

Цитата:

Возможно ли использовать одну и
ту же функцию для install и
deinstall секции

да, пробуйте, а потом пишите о результатах..

dix75 · Отправлено: **18:01, 02-09-2013** | #**512**

В том то и дело, что нельзя

K.A.V. · Конфигурация компьютера

Цитата tony1990:

Возвращаясь к вопросу о выводе строки Space available: на стандартной странице компонентов. Всё работает на ура до тех пор пока не начинаешь выбирать эти самые компоненты. Тут видать страница обновляется и созданная нами надпись про доступный размер на диске исчезает. Похоже, это нельзя обойти . Ежели только в исходниках нсиса не копаться. Да и то не поможет наверно. »

Со стандартной оболочкой? Что-то я не замечал таких проблем никогда, может, у вас в скрипте прописаны какие-то уникальные функции??

Цитата dix75:

Добрый день!
Возможно ли использовать одну и ту же функцию для install и deinstall секции
Есть функции BASE64 Encoding/Decoding Functions здесь
Но как их заставить работать для деинсталл секции »

Цитата dix75:

В том то и дело, что нельзя »

С чего вы взяли, что нельзя то? Вы пробовали?

Цитата K.A.V.:

Плохо пробовали, раз не работает

»

У вас же прописаны уже подобные функции в скрипте, если у вас прописаны команды деинсталлятора, вот возьмите, изучите скрипт, и всё поймёте...

Подсказка: ищите в скрипте слова, которые появляются в сообщениях при запуске программы удаления

MKN · Отправлено: **09:26, 03-09-2013** | #**514**

Вызов стандартного диалога выбора каталога/файла (принтера/компьютера) c помощью функции SHBrowseForFolder

Полезно при работе со стандартными страницами для обзора до или после установки и при помещении кнопки обзора на любой странице.
(Есть конечно Dialogs plug-in, но в нём нет некоторых моментов, доступных при оперирировании флагами функции )

Код:

OutFile "SHBrowseForFolder_test.exe"

Section
StrCpy $9 "Folder Dialog Title"
System::Store "s r9"
; создаём структуру обозревателя 
System::Call '*(i $HWNDPARENT, i 0, t "", t r9, i 0x40|0x4000, i 0, i, i) i.r1'
System::Call 'shell32::SHBrowseForFolderA(i r1) i.r2'
System::Free $1

;получаем путь для выбранной папки/файла
System::Call 'shell32::SHGetPathFromIDListA(i $2, t "" r3)'
MessageBox MB_OK "Selected :  $3"
        
;Функция  SHGetMalloc  извлекает указатель на интерфейс IMalloc оболочки. 
;Расширение оболочки должно использовать этот интерфейс для выделения памяти, 
;позднее освобождаемой оболочкой.
System::Call 'shell32::SHGetMalloc(*i . r4)'  
; IMalloc->Free call
System::Call '$4->5(i r2)'
; IMalloc->Release
System::Call '$4->2()'
System::Store "p3 l"
SectionEnd

Код этот обычно находится в функции, здесь в секции, лишь как пример.

Флаги BROWSEINFO structure ( BIF_BROWSEINCLUDEFILES )
http://msdn.microsoft.com/en-us/libr...(v=vs.85).aspx
Флагов много, вот некоторые :
; 0x0000040 - с кнопкой "Создать папку"
; 0x00000200 - без кнопки "Создать папку"
; 0x00004000 - обзор, включая файлы
; 0x00000010 - с EditBox_ом над деревом папок
флаг можно записывать короче : 0x40 и т.д. , а также назначать через !define BIF_BROWSEINCLUDEFILES

ps если кто владеет программированием - может доработать диалог, как здесь :
http://www.manhunter.ru/assembler/23...forfolder.html
Хорошо было бы приспособить этот тюнинг для NSIS, в виде плагина...

tony1990 · Отправлено: **13:51, 03-09-2013** | #**515**

Цитата:

K.A.V. : Со стандартной оболочкой? Что-то я не замечал таких проблем никогда, может, у вас в скрипте прописаны какие-то уникальные функции??

Ну вот простенький пример кода. Когда мы снимаем/ставим галочку у компонента, надпись Space available: исчезает.

Код:

!include "MUI2.nsh"

Name "Components Example"
OutFile Components.exe
InstallDir $TEMP

RequestExecutionLevel user

!define MUI_PAGE_CUSTOMFUNCTION_SHOW "CompShowProc"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "English"

Section "Component1"
SectionEnd

Section "Component2"
SectionEnd

Section "Component3"
SectionEnd


Function CompShowProc

    System::Call 'kernel32::GetDiskFreeSpaceEx(t"$instdir",*l.r1,*l,*l)'
    System::Int64Op $1 / 1024 
    Pop $1
        
    StrCpy $4 'Space available: $1 KB'
    FindWindow $0 "#32770" "" $HWNDPARENT
    System::Call 'USER32::CreateWindowEx(i0,t "STATIC",t "$4",i ${WS_CHILD}|${WS_VISIBLE},i0,i203,i150,i20,i $0,i222,i0,i0) $R2'

    GetDlgItem $1 $0 1006
    GetDlgItem $2 $0 222
    SendMessage $1 ${WM_GETFONT} 0 0 $3
    SendMessage $2 ${WM_SETFONT} $3 1

FunctionEnd

MKN · Отправлено: **15:22, 03-09-2013** | #**516**

Цитата tony1990:

надпись Space available: исчезает. »

Потому, что ты не удачно переместил её в область контрола окна 1023, которое эту надпись и закрывает при обновлении инфы Space required e, когда отмечается компонент ...
В приведённом примере ведь всё на месте и никуда не исчезает.
Либо измени размер 1023, либо смести своё окно-надпись в свободное место. Те же грабли , что и с кнопкой...

MKN · Отправлено: **17:55, 05-09-2013** | #**517**

Эффект "кругов на воде" на BMP рисунке.

Получается с помощью инносетаповской waterctrl.dll и следующего кода :

Код:

!AddPluginDir ".\"
!include MUI2.nsh

OutFile "WaterCtrl_test.exe"

ReserveFile waterctrl.dll
!define MUI_WELCOMEFINISHPAGE_BITMAP WizModernImage-Is.bmp
!define MUI_PAGE_CUSTOMFUNCTION_PRE pre
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE leave
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!define MUI_PAGE_CUSTOMFUNCTION_Pre pre
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE leave
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE "English"

Function .onGUIEnd
SetPluginUnload manual
waterctrl::disablewater
System::Free
FunctionEnd

Function .onInit
InitPluginsDir
SetOutPath $PLUGINSDIR
File waterctrl.dll
;SetOutPath $TEMP
FunctionEnd

Function Pre
; Load Image (LR_CREATEDIBSECTION|LR_LOADFROMFILE = 0x2010)
System::Call 'user32::LoadImage(i,t,i,i,i,i,) i (0,"$PLUGINSDIR\modern-wizard.bmp",0,0,0,0x2010) .s'
Pop $R0
System::Call '$PLUGINSDIR\waterctrl::enablewater(i,i,i,i,i,i) i ($HWNDPARENT,0,0,$R0,3,50)'
System::Call '$PLUGINSDIR\waterctrl::setwaterparent(i $HWNDPARENT)'
System::Call '$PLUGINSDIR\waterctrl::flattenwater()'
System::Call '$PLUGINSDIR\waterctrl::waterblob(i,i,i,i) i (70,198,10,1000)'
FunctionEnd

Function leave
System::Call '$PLUGINSDIR\waterctrl::disablewater()'
FunctionEnd

Section
Sleep 300
SectionEnd

Недостаток - ощутимая задержка после запуска перед появлением страницы.

MKN · Отправлено: **10:49, 06-09-2013** | #**518**

Эффект пламени на BMP изображении

Для эффекта используется инносетаповская firectrl.dll. Т.к. пламя какое то бледненькое, лучше использовать WizModernImage-Is.bmp светлого цвета.

Код:

!AddPluginDir ".\"

!include MUI.nsh
OutFile "Flame_Effects_test.exe"

ReserveFile firectrl.dll
!define MUI_WELCOMEFINISHPAGE_BITMAP WizModernImage-Is.bmp
!define MUI_PAGE_CUSTOMFUNCTION_PRE pre
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE leave
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!define MUI_PAGE_CUSTOMFUNCTION_Pre pre
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE leave
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE "English"

Function .onGUIEnd
SetPluginUnload manual
firectrl::disablefire
System::Free
FunctionEnd

Function .onInit
InitPluginsDir
SetOutPath $PLUGINSDIR
File firectrl.dll
SetOutPath $TEMP
FunctionEnd

Function Pre
System::Call 'user32::LoadImage(i,t,i,i,i,i,) i (0,"$PLUGINSDIR\modern-wizard.bmp",0,0,0,0x2010) .s'
Pop $R0
System::Call '$PLUGINSDIR\firectrl::enablefire(i,i,i,i,i) i ($HWNDPARENT,0,0,$R0,50)'
FunctionEnd

Function leave
System::Call '$PLUGINSDIR\firectrl::disablefire()'
FunctionEnd

 Section
 Sleep 300
 SectionEnd

Недостаток тот же - тормоз перед открытием страницы.

tony1990 · Отправлено: **16:16, 08-09-2013** | #**519**

Положение окна 1023 получается регулировать, но вот его размеры нет. Меняю параметры, идущие за положением - на размеры окна они не влияют. Хотелось бы поместить всё-таки строчку о доступном размере на стандартное место, дабы не контрастировать с предыдущей страницей директории

Код:

 

!include "MUI2.nsh"
Name "Components Example"
OutFile Components.exe
InstallDir $TEMP
RequestExecutionLevel user
 
!insertmacro MUI_PAGE_DIRECTORY
!define MUI_PAGE_CUSTOMFUNCTION_SHOW "CompShowProc"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
 
!insertmacro MUI_LANGUAGE "English"
 
Section "Component1"
SectionEnd
Section "Component2"
SectionEnd
Section "Component3"
SectionEnd

Function CompShowProc
    System::Call 'kernel32::GetDiskFreeSpaceEx(t"$instdir",*l.r1,*l,*l)'
    System::Int64Op $1 / 1024 
    Pop $1
        
    StrCpy $4 'Space available: $1 KB'
    FindWindow $0 "#32770" "" $HWNDPARENT
    GetDlgItem $R5 $0 1023
    System::Call "User32::SetWindowPos(i, i, i, i, i, i, i) b ($R5, 0, 0, 180, 75, 10, 0x201)"
    System::Call 'USER32::CreateWindowEx(i0,t "STATIC",t "$4",i ${WS_CHILD}|${WS_VISIBLE},i0,i203,i150,i20,i $0,i222,i0,i0) $R2'
    GetDlgItem $1 $0 1006
    GetDlgItem $2 $0 222
    SendMessage $1 ${WM_GETFONT} 0 0 $3
    SendMessage $2 ${WM_SETFONT} $3 1
FunctionEnd

MKN · Отправлено: **10:38, 09-09-2013** | #**520**

Цитата tony1990:

Положение окна 1023 получается регулировать, но вот его размеры нет. »

Не правильный синтаксис вызова функции. Надо так :

Код:

System::Call "User32::SetWindowPos(i$R5, i0, i0, i180, i150, i15, 0x0004)"
; Флаги устанавливают - исходя из задачи  : http://msdn.microsoft.com/en-us/library/windows/desktop/ms633545(v=vs.85).aspx
; по русски :  http://www.firststeps.ru/mfc/winapi/win/r.php?96

Только и так не очень правильно... Сначала создают Rect структуру, потом получают координаты окна, позицию которого надо изменить, задают новые координаты и потом уже применяют функцию SetWindowPos.
Также по хорошему, надо , сделать привязку к базовым единицам, чтобы при ином разрешении экрана, выбранные координаты не уехали... (А может и не обязательно... ) Гемор одним словом. Не проще ли подправить размер окна в ресурсах ?