[NoName01.cpp]

K.A.V., спасибо за 3 деинсталлятора! Но еще одна проблемка нарисовалась: не могу удалить папку в которую установлена программа. (Ярлыки удаляются, из реестра тоже)

Код:

читать дальше »

Section $(Name_Seс1) Sec1
...
Strcpy $R9 $INSTDIR
strcpy $INSTDIR "$INSTDIR\Sec2"
WriteUninstaller "$INSTDIR\uninstall.exe"
strcpy $INSTDIR "$R9"
SectionEnd

Section $(Name_Sec2) Sec2
...
Strcpy $R9 $INSTDIR
strcpy $INSTDIR "$INSTDIR\Sec2"
WriteUninstaller "$INSTDIR\uninstall.exe"
strcpy $INSTDIR "$R9"
SectionEnd

Section $(Name_Sec3) Sec3
...
Strcpy $R9 $INSTDIR
strcpy $INSTDIR "$INSTDIR\Sec3"
WriteUninstaller "$INSTDIR\uninstall.exe"
strcpy $INSTDIR "$R9"
SectionEnd

Function un.UnInstall_Sec1
RMDir /r "$INSTDIR\Sec1" ;вот это не работает
...
FunctionEnd

Function un.UnInstall_Sec2
RMDir /r "$INSTDIR\Sec2" ;вот это не работает
...
FunctionEnd

Function un.UnInstall_Sec3
RMDir /r "$INSTDIR\Sec1" ;вот это не работает
...
FunctionEnd

Может папка не удаляется, потому-что в ней деинсталлятор, или потому-что в ней еще есть папки?
Хотя в примерах скриптов вроде все точное так же.

[K.A.V.]

Может папка не удаляется, потому-что в ней деинсталлятор »

При запуске деинсталлятор копирует сам себя во временную папку со случайным именем, чтобы возможно было удалить деинсталлятор в каталоге $INSTDIR
Скорее всего, в данной папке есть файлы, которые используются системой/программами

К тому же, у вас ошибка в скрипте
Должно быть так:

Код:

RMDir /r "$INSTDIR"

или

Код:

RMDir /r "$R0\Sec1"

Т.к. переменная $INSTDIR уже содержит в своём пути "Sec1", мы же изменяли значение переменной в момент создания деинсталлятора, помните?

[dracosha]

K.A.V., Спасибо Вам большое.

StrCmp $Language "1049" 0 +2 »

Я так понял "1049" - это код русского языка.
А какой код у английского?

[K.A.V.]

K.A.V., Спасибо Вам большое. »

Лучше помогите материально
Шучу конечно, да пожалуйста!

А какой код у английского? »

1033

[NoName01.cpp]

Т.к. переменная $INSTDIR уже содержит в своём пути "Sec1", мы же изменяли значение переменной в момент создания деинсталлятора, помните? »

Спасибо большое! Теперь работает!

[dracosha]

Вам нужно поместить данную команду в секцию, а не в функцию, которая выполняется при запуске инсталлятора, пример кода: Код: Section -post StrCmp $Language "1049" 0 +2 CopyFiles "files\russian.lng" "$INSTDIR\" SectionEnd »

не работает! K.A.V., помоги разобраться плиз. Может я что-то не так делаю.
Но из функций я этот код убрал... Дабавил секцию полностью скопировав твой пример... А оно работать не хочет
Неработает - всмысле не копируется файл russian.lng.

[K.A.V.]

dracosha, ну ей богу...
Команда "CopyFiles" копирует файл, который есть на жестком диске, а у нас файл упакованный в инсталлятор, значит прописывать надо так:

Код:

SetOutpath $INSTDIR
File "files\russian.lng"

---
Добавил позже

а. Как сделать что-бы обойти размер в 2 Gb. если нельзя, то как реализовать по другому »

У меня тут мысль в голову пришла
Использовать несколько инсталляторов NSIS, главный файл будет инсталлятором (маленький размер, чисто для запуска других), остальные будут как архивы (можно изменить на любое расширение отличное от EXE), каждый из инсталлеров будет принимать от главного инсталлера путь, куда следует распаковать файлы и будет их распаковывать

[dracosha]

K.A.V., я думал если Вы мне поможете с копированием файла russian.lng при выборе русского языка, то я смогу догадаться как мне остальные файлы распределить по языкам...
Но к сожалению я разобраться не смог. Извините что сразу не ввел Вас вкурс того что мне еще надо.

Вобщем при выборе русского языка мне нужно что бы копировался russian.lng в корневую папку (с этим Вы мне уже помогли т.е. вопрос закрыт) и set.dll в папку $INSTDIR\settings

а при выборе английского языка что бы копировался тоже set.dll в папку $INSTDIR\settings
но это уже другой файл т.е. внутренности етого файла для русской версии проги отличаются хотя названия файлов одинаковые...
Файлы эти при компиляции естественно лежат в разных местах...
И вот собственно то что я сделал:

читать дальше »

Код:

SetCompressor /SOLID lzma
RequestExecutionLevel admin
SetOverwrite on

!define PRODUCT_NAME "Super Proga"
InstallDir "$PROGRAMFILES\Super Proga"
OutFile "SuperProga.exe"

!include "MUI2.nsh"

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "LicenseRU.rtf"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES

!insertmacro MUI_LANGUAGE "English"
!insertmacro MUI_LANGUAGE "Russian"
!insertmacro MUI_RESERVEFILE_LANGDLL

Section "Group 1 - Option 1" g1o1
SectionEnd

Section "Group 2 - Option 2" g2o2
SectionEnd

Section "Group 2 - Option 3" g2o3
SectionEnd

Section -post
StrCmp $Language "1049" 0 +2
SetOutPath "$INSTDIR\"
File "files\russian.lng"
SectionEnd

Section -setru
StrCmp $Language "1049" 0 +2
SetOutPath "$INSTDIR\settings"
File "settings\set.dll"
SectionEnd

Section -seten
StrCmp $Language "1033" 0 +2
SetOutPath "$INSTDIR\settings"
File "files\set.dll"
SectionEnd

Section Uninstall
RMDir /r "$INSTDIR\"
SectionEnd

Function .onInit
!insertmacro MUI_LANGDLL_DISPLAY
SetOutPath $TEMP
File /oname=spl.bmp "splash.bmp"
advsplash::show 1500 2500 250 0 $TEMP\spl
Pop $0
Delete $TEMP\spl.bmp
FunctionEnd

Но в итоге при выборе русского языка файл для английского все равно копируется
а при выборе английского файл russian.lng копируется в папку $INSTDIR\settings
что за глюки такие... понятия не имею.
Помогите плиз

[K.A.V.]

В выделенном тексте, везде где написано 0 +2 замените на 0 +3

Кстати не обязательно для каждого файла создавать новую секцию, всё можно прописать в одну

читать дальше »

Код:

Section -post
StrCmp $Language "1049" 0 +3
SetOutPath "$INSTDIR\"
File "files\russian.lng"

StrCmp $Language "1049" 0 +3
SetOutPath "$INSTDIR\settings"
File "settings\set.dll"

StrCmp $Language "1033" 0 +3
SetOutPath "$INSTDIR\settings"
File "files\set.dll"
SectionEnd

[dracosha]

!insertmacro MUI_PAGE_WELCOME Page license !insertmacro MUI_PAGE_DIRECTORY !insertmacro MUI_PAGE_INSTFILES !insertmacro MUI_PAGE_FINISH !insertmacro MUI_LANGUAGE "Russian" !insertmacro MUI_LANGUAGE "English" LicenseLangString myLicenseData ${LANG_ENGLISH} "English_license_file.txt" LicenseLangString myLicenseData ${LANG_RUSSIAN} "Russian_license_file.txt" LicenseData $(myLicenseData) »

Очень хотелось использовать именно MUI
Когда разбирался с языками для названия секций я просек тему что в nsis можно присваивать переменные а потом объявлять для них перевод...
После чего решил попробовать на MUI_PAGE_LICENSE
И к моему большому удивлению у меня все получилось...

читать дальше »

Код:

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "$(myLicenseData)"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES

!insertmacro MUI_LANGUAGE "English"
!insertmacro MUI_LANGUAGE "Russian"
!insertmacro MUI_RESERVEFILE_LANGDLL

LicenseLangString myLicenseData ${LANG_ENGLISH} "files\Licenseen.rtf"
LicenseLangString myLicenseData ${LANG_RUSSIAN} "files\Licenseru.rtf"

может кому пригодится