CMD/BAT - Добавления значения к уже существующей системной переменной

Foreigner · Отправлено: **15:00, 14-01-2015** | #21

Цитата termitt:

hklm\environment »

Вообще-то если hklm, то hklm\SYSTEM\CurrentControlSet\Control\Session Manager\Environment
Сами же говорили чуть ранее

Цитата termitt:

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment вот сюда должна записать то есть hklm »

Проверить можно в regedit или в свойствах системы: Панель Управления > Система > Дополн. параметры системы > Переменные среды > Системные переменные > PATH

Либо перезагрузить компьютер

Код:

@echo off
setlocal

set "key=hklm\System\CurrentControlSet\Control\Session Manager\Environment"
set "parameter=path"
set "value=%ProgramFiles%\Autodesk\AutoCAD 2014"

1>nul 2>&1 reg query "%key%" /v "%parameter%" || (

    reg add "%key%" /v "%parameter%" /t reg_sz /d "%value%"
    goto:eof

)

for /f "tokens=3*" %%i in ('reg query "%key%" /v "%parameter%"') do call:add %%i %%j
goto:eof

:add
reg add "%key%" /v "%parameter%" /d "%*;%value%" /f

Батник должен быть запущен с повышенными привилегиями (от Администратора)

termitt · Отправлено: **17:40, 14-01-2015** | #22

Foreigner, хмм... дома сработала. сделал запуск от имени администратора. спасибо!!! завтра попробую на работе)

termitt · Отправлено: **09:01, 15-01-2015** | #23

Foreigner, да да все работает спасибо. а можно же сделать что смотрел на эту переменную проверил чтобы не было дублирования?

gora · Конфигурация компьютера

Цитата termitt:

проверил чтобы не было дублирования? »

Код:

Set InstPath=%SystemDrive%\Program Files\7-Zip
Set sw="HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"
For /F "tokens=2*" %%j In ('Reg Query %sw% /v Path ^| Find /I "Path"') Do Set type=%%j& Set curpath=%%k
Echo "%curpath%" | Find /I "%InstPath%" >Nul && Exit
Reg Add %sw% /v Path /t %type% /d "%curpath%;%InstPath%" /f