VBS/WSH/JS

Iska · Отправлено: **21:12, 26-10-2012** | #21

ul9, я никак не пойму, почему Вы так упорно хотите получить три действия (запуск + выбор + ввод) вместо двух (выбор + запуск)? Зачем?

ul9 · Отправлено: **21:17, 26-10-2012** | #22

Потому что я свожу всё в один батник. Запустила ярлык и пошёл процесс. Только попутно выбираешь нужные действия. Делать 15 ярлыков совсем не вариант...

Iska · Отправлено: **21:20, 26-10-2012** | #23

Ну, тогда, раз Вам знаком JScript, напишите себе форму на HTA, в которой уже и будете выбирать, с какими параметрами запускать скрипт.

ul9 · Отправлено: **21:38, 26-10-2012** | #24

Нашла вот таких два батника. Теперь осталось определиться.

Код:

@Echo Off

set /p variable=[Viberite tip 1- red 2- green 3- blue 4- black]
if /I %variable%==1 goto red
if /I %variable%==2 goto green
if /I %variable%==3 goto blue
if /I %variable%==4 goto black
goto error

:red
echo ****************************************************
echo red
echo ****************************************************
pause
:green
echo ****************************************************
echo green
echo ****************************************************
pause
:blue
echo ****************************************************
echo blue
echo ****************************************************
pause
:black
echo ****************************************************
echo black
echo ****************************************************
pause

:error
echo error - try again
pause
goto :start

Код:

@Echo off
 
:m1
Echo Выберите программу:
Echo.
Echo 1 - Программа 1
Echo 2 - Программа 2
Echo 3 - Программа 3
 
echo.
Set /p choice="Ваш выбор: "
if not defined choice goto m1
if "%choice%"=="1" (start 1.exe)
if "%choice%"=="2" (start 2.exe)
if "%choice%"=="3" (start 3.exe)
Echo.
Echo Не правильно сделан выбор задания
Echo.
Echo.
goto m1
pause >nul

Iska · Отправлено: **22:50, 26-10-2012** | #25

Цитата ul9:

Теперь осталось определиться. »

Примерный вид исполнителя с кнопками на .hta:

Код:

<html id="appSampleScriptRunner">
	<head>
		<meta charset="windows-1251">
		<meta http-equiv="Content-Type" content="text/html; charset=windows-1251">
		<meta http-equiv="Content-Language" content="ru">
		<title>Sample Script Runner</title>
		<hta:Application
			Id              = "appSampleScriptRunner"
			Icon            = "%SystemRoot%\System32\wscript.exe"
			ApplicationName = "Sample Script Runner"
			Border          = "normal"
			BorderStyle     = "normal"
			Caption         = "yes"
			ContextMenu     = "no"
			InnerBorder     = "yes"
			MaximizeButton  = "yes"
			MinimizeButton  = "yes"
			Navigable       = "no"
			Scroll          = "auto"
			ScrollFlat      = "no"
			Selection       = "no"
			ShowInTaskbar   = "yes"
			SingleInstance  = "yes"
			SysMenu         = "yes"
			Version         = "1.0"
			WindowState     = "normal"
		/>
		
		<style type="text/css">
			body {
				font: x-small Verdana, Arial, sans-serif;
				color: WindowText;
				background-color: ButtonFace;
			}
		</style>
		
		<script language="VBScript">
			Option Explicit
			
			Sub Window_OnLoad
				Dim arrValues
				Dim elem
				
				Dim objHTMLElement
				
				arrValues = Array( _
					"/FolderForScan:""E:\Песочница\0001"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\01\Найти это.txt"" /FileReplaceBy:""E:\Песочница\01\заменить этим.txt""", _
					"/FolderForScan:""E:\Песочница\0002"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\02\Найти это.txt"" /FileReplaceBy:""E:\Песочница\02\заменить этим.txt""", _
					"/FolderForScan:""E:\Песочница\0003"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\03\Найти это.txt"" /FileReplaceBy:""E:\Песочница\03\заменить этим.txt""" _
				)
				
				For Each elem In arrValues
					Set objHTMLElement = document.createElement("input")
					
					With objHTMLElement
						.type            = "button"
						.style.textAlign = "left"
						.value           = "cscript.exe //nologo ""c:\My Scripts\Script.vbs""" & Replace(" " & elem, " /", vbCrLf & vbTab & " /")
						
						.onclick         = GetRef("OnClickButtonRunScript")
					End With
					
					document.body.appendChild objHTMLElement
					
					Set objHTMLElement = document.createElement("br")
					document.body.appendChild objHTMLElement
				Next
				
				With window
					.resizeTo tagBody.scrollWidth + 25, tagBody.scrollHeight + 32
					.moveTo (.screen.availWidth - tagBody.offsetWidth) \ 2, (.screen.availHeight - tagBody.offsetHeight) \ 2
				End With
			End Sub
			
			Sub OnClickButtonRunScript()
				With CreateObject("WScript.Shell")
					MsgBox Replace(window.event.srcElement.value, vbCrLf & vbTab & " /", " /")
					'.Run Replace(window.event.srcElement.value, vbCrLf & vbTab & " /", " /")
				End With
			End Sub
		</script>
	</head>
	
	<body id="tagBody" scroll="auto">
	</body>
	
	<script language="VBScript">
		Option Explicit
		
	</script>
</html>

ul9 · Отправлено: **23:09, 26-10-2012** | #26

Цитата Iska:

Примерный вид исполнителя с кнопками на .hta: »

Ого, а как это использовать? Первый раз такое вижу

Iska · Отправлено: **23:22, 26-10-2012** | #27

Откройте Блокнот. Скопируйте код и вставьте его в Блокнот. Сохраните в файл с расширением «.hta». Сделайте двойной щелчок в Проводнике по созданному файлу.

ul9 · Отправлено: **23:30, 26-10-2012** | #28

Получилось.
Редактировать только тут?

Код:

Dim objHTMLElement	
arrValues = Array( _
	"/FolderForScan:""E:\Песочница\0001"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\01\Найти это.txt"" /FileReplaceBy:""E:\Песочница\01\заменить этим.txt""", _
	"/FolderForScan:""E:\Песочница\0002"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\02\Найти это.txt"" /FileReplaceBy:""E:\Песочница\02\заменить этим.txt""", _
	"/FolderForScan:""E:\Песочница\0003"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\03\Найти это.txt"" /FileReplaceBy:""E:\Песочница\03\заменить этим.txt""" _
)

А можно выводить не пути, а названия в кнопках(Красный, Зелёный и т.д.)?

А ещё лучше не названия, а просто пустые цветные кнопки (#00FF00, #FFFFFF...)

Iska · Отправлено: **01:22, 27-10-2012** | #29

Цитата ul9:

Редактировать только тут… »

Да.

Цитата ul9:

А можно выводить не пути, а названия в кнопках(Красный, Зелёный и т.д.)? »

Для данного алгоритма — нет. Тут название фактически является командной строкой для исполнения. Но можно сменить алгоритм.

Цитата ul9:

А ещё лучше не названия, а просто пустые цветные кнопки (#00FF00, #FFFFFF...) »

Пробуйте другой алгоритм:

Код:

<html id="appSampleScriptRunner">
	<head>
		<meta charset="windows-1251">
		<meta http-equiv="Content-Type" content="text/html; charset=windows-1251">
		<meta http-equiv="Content-Language" content="ru">
		<title>Sample Script Runner</title>
		<hta:Application
			Id              = "appSampleScriptRunner"
			Icon            = "%SystemRoot%\System32\wscript.exe"
			ApplicationName = "Sample Script Runner"
			Border          = "normal"
			BorderStyle     = "normal"
			Caption         = "yes"
			ContextMenu     = "no"
			InnerBorder     = "yes"
			MaximizeButton  = "yes"
			MinimizeButton  = "yes"
			Navigable       = "no"
			Scroll          = "auto"
			ScrollFlat      = "no"
			Selection       = "no"
			ShowInTaskbar   = "yes"
			SingleInstance  = "yes"
			SysMenu         = "yes"
			Version         = "1.1"
			WindowState     = "normal"
		/>
		
		<style type="text/css">
			body {
				font: x-small Verdana, Arial, sans-serif;
				color: WindowText;
				background-color: ButtonFace;
			}
		</style>
		
		<script language="VBScript">
			Option Explicit
			
			Dim objDictionary
			
			'==========================================================================
			Sub Window_OnLoad
				Dim strKey
				Dim objHTMLElement
				
				For Each strKey In objDictionary.Keys
					Set objHTMLElement = document.createElement("div")
					
					With objHTMLElement
						.id    = strKey
						.title = Replace(objDictionary.Item(strKey), " /", vbCrLf & "   /")
						
						With .style
							.textAlign       = "left"
							
							.borderWidth     = "thick"
							.borderStyle     = "outset"
							
							.margin          = "0.5em"
							.padding         = "0.5em"
							
							.backgroundColor = strKey
						End With
						
						.onclick     = GetRef("OnClickButtonRunScript")
						
						.onMouseOut  = GetRef("OnMouseOut")
						.onMouseOver = GetRef("OnMouseOver")
					End With
					
					document.body.appendChild objHTMLElement
					
					objHTMLElement.appendChild document.createTextNode(objDictionary.Item(strKey))
				Next
				
				With window
					.resizeTo tagBody.scrollWidth + 25, tagBody.scrollHeight + 32
					.moveTo (.screen.availWidth - tagBody.offsetWidth) \ 2, (.screen.availHeight - tagBody.offsetHeight) \ 2
				End With
			End Sub
			'==========================================================================
			
			'==========================================================================
			Sub OnClickButtonRunScript()
				With CreateObject("WScript.Shell")
					MsgBox objDictionary.Item(window.event.srcElement.id)
					'.Run objDictionary.Item(window.event.srcElement.id)
				End With
			End Sub
			'==========================================================================
			
			'==========================================================================
			Sub OnMouseOut()
				With window.event.srcElement
					.style.color  = "WindowText"
				End With
			End Sub
			'==========================================================================
			
			'==========================================================================
			Sub OnMouseOver()
				With window.event.srcElement
					.style.color  = "Yellow"
				End With
			End Sub
			'==========================================================================
			
			Set objDictionary = CreateObject("Scripting.Dictionary")
			
			With objDictionary
				.Add "Red",           "cscript.exe //nologo ""c:\My Scripts\Script.vbs"" /FolderForScan:""E:\Песочница\0001"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\01\Найти это.txt"" /FileReplaceBy:""E:\Песочница\01\заменить этим.txt"""
				.Add "Green",         "cscript.exe //nologo ""c:\My Scripts\Script.vbs"" /FolderForScan:""E:\Песочница\0002"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\02\Найти это.txt"" /FileReplaceBy:""E:\Песочница\02\заменить этим.txt"""
				.Add "Blue",          "cscript.exe //nologo ""c:\My Scripts\Script.vbs"" /FolderForScan:""E:\Песочница\0003"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\03\Найти это.txt"" /FileReplaceBy:""E:\Песочница\03\заменить этим.txt"""
				.Add "SpringGreen",   "cscript.exe //nologo ""c:\My Scripts\Script.vbs"" /FolderForScan:""E:\Песочница\0003"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\03\Найти это.txt"" /FileReplaceBy:""E:\Песочница\03\заменить этим.txt"""
				.Add "DarkSlateBlue", "cscript.exe //nologo ""c:\My Scripts\Script.vbs"" /FolderForScan:""E:\Песочница\0003"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\03\Найти это.txt"" /FileReplaceBy:""E:\Песочница\03\заменить этим.txt"""
				.Add "#CFCFF0",       "cscript.exe //nologo ""c:\My Scripts\Script.vbs"" /FolderForScan:""E:\Песочница\0003"" /FileExtension:""htm"" /FileWhatFind:""E:\Песочница\03\Найти это.txt"" /FileReplaceBy:""E:\Песочница\03\заменить этим.txt"""
			End With
		</script>
	</head>
	
	<body id="tagBody" scroll="auto">
	</body>
</html>

Как и в предыдущем, для исполнения — закомментировать «MsgBox»:

Код:

					MsgBox objDictionary.Item(window.event.srcElement.id)

и раскомментировать «.Run»:

Код:

					'.Run objDictionary.Item(window.event.srcElement.id)

ul9 · Отправлено: **01:43, 27-10-2012** | #30

Ага, спасибо. Мы уже почти приблизились к моей затее

Вот так бы было просто замечательно