[Creat0R]

_GUICtrlRichEdit_StreamToVar, _GUICtrlRichEdit_StreamFromVar »

Это не отвечает на вопрос как менять Stream, т.е как обращаться к его содержимому?
Немного ошибся с описанием функции.

Но всё равно работать с файлом легче, не добавляются лишние теги.

[Creat0R]

Вот так получилось:

Код:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIRichEdit.au3>

Global $sStream_File = @TempDir & '\au3_rtf.tmp'

$hGUI = GUICreate('_GUICtrlRichEdit_SetFormat Demo', 300, 200)

$hRichEdit = _GUICtrlRichEdit_Create($hGUI, 'Some data with [img]image[/img] tags, [b]bold[/b], and [color]color[/color].', 20, 20, 260, 160, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
_GUICtrlRichEdit_StreamToFile($hRichEdit, $sStream_File)

GUISetState(@SW_SHOW, $hGUI)

While 1
	_GUICtrlRichEdit_SetFormat()
	
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			_GUICtrlRichEdit_Destroy($hRichEdit)
			FileDelete($sStream_File)
			Exit
	EndSwitch
WEnd

Func _GUICtrlRichEdit_SetFormat()
	If Not _GUICtrlRichEdit_IsModified($hRichEdit) Then
		Return
	EndIf
	
	Local $aPos, $sRead, $sColorTbl
	
	_GUICtrlRichEdit_StreamToFile($hRichEdit, $sStream_File)
	$aPos = _GUICtrlRichEdit_GetSel($hRichEdit)
	$sRead = FileRead($sStream_File)
	
	$sColorTbl = '\red255\green0\blue0;\red0\green150\blue0;\red0\green0\blue255' ;red(cf1;green(cf2);blue(cf3)
	Dim $aTags[3][3] = [['b', '\b', '\cf0'], ['img', '', '\cf2'], ['color', '', '\cf1']]
	
	For $i = 0 To UBound($aTags) - 1
		$sRead = StringRegExpReplace($sRead, '(\[' & $aTags[$i][0] & '\].*?\[/' & $aTags[$i][0] & '\])', '{\' & $aTags[$i][1] & '\' & $aTags[$i][2] & ' \1}')
	Next
	
	$sRead = '{\rtf1 {\colortbl ;' & $sColorTbl & ';}' & StringReplace(StringStripCR($sRead), @LF, @LF & '\par ') & '}'
	
	$hFile = FileOpen($sStream_File, 2)
	FileWrite($hFile, $sRead)
	FileClose($hFile)
	
	_GUICtrlRichEdit_StreamFromFile($hRichEdit, $sStream_File)
	_GUICtrlRichEdit_SetSel($hRichEdit, $aPos[0], $aPos[1])
	_GUICtrlRichEdit_SetModified($hRichEdit, False)
EndFunc

[Pavluha]

ещё вопросик: а как изменить фон определённых слов?

[Creat0R]

как изменить фон определённых слов? »

По идее нужно использовать \cbN как параметр рядом с cfN, но оно почему то не работает...

[Pavluha]

Creat0R, вот-вот. я сделал документ в ворде с фоном, сохранил в формате ртф, работает, даже в вордпэде правильно показывает. открываю я исходный код, а там....... короче я не разобрался. но фон ооочень нужен. без него нормальную подсветку не сделаешь.

[Pavluha]

Ура!!! Нашёл!!!

Код:

{\rtf1
{\colortbl ;\red255\green255\blue0;}
some 
{\highlight1 yellow }
text
}

[Pavluha]

Ещё вопрос (не обязательно, но всё же): нужно сделать так, чтобы подсвечивались url и при нажатии на них (например, ctrl + нажатие или, например, двойной клик по ссылке) открывалась страница с этим url. _GUICtrlRichEdit_AutoDetectURL ($hRichEdit, True) только подсвечивает.

[Creat0R]

_GUICtrlRichEdit_AutoDetectURL ($hRichEdit, True) только подсвечивает. »

Нужно ещё отлавливать событие:

Код:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIRichEdit.au3>

Global $sStream_File = @TempDir & '\au3_rtf.tmp'

$hGUI = GUICreate('_GUICtrlRichEdit_SetFormat Demo', 300, 200)

$hRichEdit = _GUICtrlRichEdit_Create($hGUI, 'Some data with [img]image[/img] tags, [b]bold[/b], and [color]color[/color].' & @LF & @LF & 'http://autoitscript.com', _
	20, 20, 260, 160, BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
	
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

_GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
_GUICtrlRichEdit_SetEventMask($hRichEdit, $ENM_LINK)
_GUICtrlRichEdit_StreamToFile($hRichEdit, $sStream_File)

GUISetState(@SW_SHOW, $hGUI)

While 1
	_GUICtrlRichEdit_SetFormat()
	
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			_GUICtrlRichEdit_Destroy($hRichEdit)
			FileDelete($sStream_File)
			Exit
	EndSwitch
WEnd

Func _GUICtrlRichEdit_SetFormat()
	If Not _GUICtrlRichEdit_IsModified($hRichEdit) Then
		Return
	EndIf
	
	Local $aPos, $sRead, $sColorTbl
	
	_GUICtrlRichEdit_StreamToFile($hRichEdit, $sStream_File)
	$aPos = _GUICtrlRichEdit_GetSel($hRichEdit)
	$sRead = FileRead($sStream_File)
	
	$sColorTbl = '\red255\green0\blue0;\red0\green150\blue0;\red0\green0\blue255;\red255\green255\blue0' ;red(cf1;green(cf2);blue(cf3);yellow(cf4)
	Dim $aTags[3][3] = [['b', '\b', '\cf0'], ['img', '', '\cf2 \highlight4'], ['color', '', '\cf1']]
	
	For $i = 0 To UBound($aTags) - 1
		$sRead = StringRegExpReplace($sRead, '(\[' & $aTags[$i][0] & '\].*?\[/' & $aTags[$i][0] & '\])', '{' & StringReplace($aTags[$i][1] & $aTags[$i][2], '\', '\\') & ' \1}')
		;$sRead = StringRegExpReplace($sRead, '\[url=(.*?)\](.*?)\[/url\]', '{\\field{\\*\\fldinst{HYPERLINK "\1"}}{\\fldrslt{\\cf3 \\ul \2}}}')
	Next
	
	$sRead = '{\rtf1 {\colortbl ;' & $sColorTbl & ';}' & StringReplace(StringStripCR($sRead), @LF, @LF & '\par ') & '}'
	
	$hFile = FileOpen($sStream_File, 2)
	FileWrite($hFile, $sRead)
	FileClose($hFile)
	
	_GUICtrlRichEdit_StreamFromFile($hRichEdit, $sStream_File)
	_GUICtrlRichEdit_SetSel($hRichEdit, $aPos[0], $aPos[1])
	_GUICtrlRichEdit_SetModified($hRichEdit, False)
EndFunc

Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
	#forceref $hWnd, $iMsg, $iWparam
	
	Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $cpMin, $cpMax, $tMsgFilter
	
	$tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	$iCode = DllStructGetData($tNMHDR, "Code")
	
	Switch $hWndFrom
		Case $hRichEdit
			Select
				Case $iCode = $EN_LINK
					$tMsgFilter = DllStructCreate($tagMSGFILTER, $iLparam)
					
					If DllStructGetData($tMsgFilter, "msg") = $WM_LBUTTONUP Then
						$tEnLink = DllStructCreate($tagENLINK, $iLparam)
						$cpMin = DllStructGetData($tEnLink, "cpMin")
						$cpMax = DllStructGetData($tEnLink, "cpMax")
						
						ShellExecute(_GUICtrlRichEdit_GetTextInRange($hRichEdit, $cpMin, $cpMax))
					EndIf
			EndSelect
	EndSwitch
	
	Return $GUI_RUNDEFMSG
EndFunc

[Pavluha]

Creat0R, если ссылка находится в каком-либо теге, то она не подсвечивается, а ведь должна.

[Creat0R]

если ссылка находится в каком-либо теге, то она не подсвечивается »

Пример текста можно?