[Maza Faka]

Creat0R
Помоги пожалуйста:

Код:

$string = "Location: http://game.chirkom.uz/download/game/warcraft3/i_hate_this_key.zip [following]" & @CRLF & _
          "Checking..."

$result = StringRegExp($string, "http.*/(.*)\s", 1)

MsgBox(0, "", $result[0])

Пытаюсь получить подстроку i_hate_this_key.zip, но безуспешно.

[NikLok]

Помогите разобраться с ListView. Хочу поймать выбор пункта в нем (желат по двойному клику) и не поумй как. Постоянно генерируется сообщение не давая даже сделать выбор.
Я так понимаю неправильна строка - Case $msg = $treeNets

Вот код.

Код:

#include <GuiConstants.au3>
#include <GuiListView.au3>

$hGUI = GuiCreate("Nets", 1020, 620)
$AcceptButton = GUICtrlCreateButton("Ok",   880, 5, 60, 25)

$a = _NetAdapterGetProp()
        $treeNets = GUICtrlCreateListView("IP Adress        |Name nets",590,120,400,400,$LVS_SINGLESEL)
        _GUICtrlListViewSetColumnWidth ($treeNets, 0, 130)
        _GUICtrlListViewSetColumnWidth ($treeNets, 1, 470)
        Dim $hTreeNets[30]
        $n = UBound($a,2)
        For $i=0 To UBound($a,2)+1 Step 1
            $hTreeNets[$i]=GUICtrlCreateListViewItem($a[$i][1] & "|" & StringTrimLeft ($a[$i][0],11),$treeNets)
        Next

; GUI MESSAGE LOOP
GuiSetState()
While 1
    $msg = GUIGetMsg()
    Switch $msg
    Case $msg = $treeNets
         ;$adapters=GUICtrlGetState($treeNets)
         MsgBox(4096,"Info selected net", "List")
         ;GUICtrlGetState($treeNets))
    Case $AcceptButton
         ExitLoop
    EndSwitch
WEnd

Func _NetAdapterGetProp($sHostName = "localhost")
    Local $objItem, $objWMIService = ObjGet( "winmgmts:\\"& $sHostName &"\root\CIMV2")
    Local $sQuery = 'SELECT Index, Caption, MACAddress, IPAddress FROM Win32_NetworkAdapterConfiguration Where IPEnabled = True'
    Local $colItems = $objWMIService.ExecQuery($sQuery, "WQL", 0x30)
    If IsObj($colItems) Then
        Local $aRes[1][3], $i=0
        For $colItem In $colItems
            ReDim $aRes[$i+1][3]
            $aRes[$i][0] = $colItem.Caption
            $aRes[$i][1] = $colItem.IPAddress(0)
            $aRes[$i][2] = $colItem.MACAddress
            $i+=1
        Next
        Return $aRes
    EndIf
    Return SetError(1)
EndFunc  ;==> _NetAdapterGetProp
Exit

[Maza Faka]

NikLok
Не считая ошибок с массивом и ошибок, которых я не заметил- не нашёл...

Код:

While 1
    $msg = GUIGetMsg()
    Switch $msg
    Case $msg = $treeNets
         ;$adapters=GUICtrlGetState($treeNets)
         MsgBox(4096,"Info selected net", "List")

Здесь ошибка указания значения, правильно будет так:

Код:

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $treeNets
            ;$adapters=GUICtrlGetState($treeNets)
            MsgBox(4096,"Info selected net", "List")

Как я понял ты используешь старую версию AutoIt-а, попробуй этот код:

Код:

#include <GuiConstants.au3>
#include <GuiListView.au3>

;Global Const $WM_NOTIFY = 0x004E
;Global Const $tagNMHDR = "hwnd hWndFrom;int IDFrom;int Code"
;Global Const $NM_DBLCLK = -3

$hGui = GUICreate("Test GUI", 300, 200)

$hListView = GUICtrlCreateListView("Items|SubItems", 10, 10, 280, 180)

GUICtrlSendMsg(-1, 0x101E, 0, 150)
GUICtrlSendMsg(-1, 0x101E, 1, 125)

$Item1 = GUICtrlCreateListViewItem("Item1|SubItem1", $hListView)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHDR, $IdFrom, $iCode

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $IdFrom = DllStructGetData($tNMHDR, "IdFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $IdFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    ConsoleWrite("Double click" & @LF)
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc

Если будет ругаться на необьявленные переменные - раскомментируй закоментированные строчки.

[NikLok]

Maza Faka,

Case $msg = $treeNets »

Да это глупая очепятка! Ночью надо отдыхать а не код гнать!

Как я понял ты используешь старую версию AutoIt-а, »

Уже выровнял! А по какому признаку заключение - по отсутсвию подчеркивания в _GUICtrlListView_SetColumnWidth ?

Если будет ругаться на необьявленные переменные - раскомментируй закоментированные строчки. »

Все прекрасно работает, только вот не понял как понять какой из N итемов выбран!

[Maza Faka]

Да это глупая очепятка! Ночью надо отдыхать а не код гнать! »

Бывает

А по какому признаку заключение - по отсутсвию подчеркивания в _GUICtrlListView_SetColumnWidth ? »

Ага

не понял как понять какой из N итемов выбран! »

Код:

#include <GuiConstants.au3>
#include <GuiListView.au3>

;Global Const $WM_NOTIFY = 0x004E
;Global Const $tagNMHDR = "hwnd hWndFrom;int IDFrom;int Code"
;Global Const $NM_DBLCLK = -3
;Global Const $tagNMLISTVIEW = "hwnd hWndFrom;int IDFrom;int Code;int Item;int SubItem;int NewState;int OldState;int Changed;" & _
        ;"int ActionX;int ActionY;int Param"

$hGui = GUICreate("Test GUI", 300, 200)

$hListView = GUICtrlCreateListView("Items|SubItems", 10, 10, 280, 180)

GUICtrlSendMsg(-1, 0x101E, 0, 150)
GUICtrlSendMsg(-1, 0x101E, 1, 125)

$Item1 = GUICtrlCreateListViewItem("Item1|SubItem1", $hListView)
$Item2 = GUICtrlCreateListViewItem("Item2|SubItem2", $hListView)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_NOTIFY($hWnd, $Msg, $wParam, $lParam)
    Local $tNMHDR, $IdFrom, $iCode, $tInfo, $iItem

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $IdFrom = DllStructGetData($tNMHDR, "IdFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $IdFrom
        Case $hListView
            Switch $iCode
                Case $NM_DBLCLK
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                    $iItem = DllStructGetData($tInfo, "Item")
                    If $iItem <> -1 Then ConsoleWrite("Double click on " & $iItem & " item" & @LF)
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc

Всё это описано в справке, не ленись туда заглядывать

[NikLok]

Maza Faka,

Всё это описано в справке, не ленись туда заглядывать »

Да у меня, пока не накоплена критическая масса знаний, барьер вхождения в тему. То есть в руководство смотрю а мысли то ли ошибочные то ли отсутствуют.

Извини исчо вопрос:

Код:

$iItem = DllStructGetData($tInfo, "Item")

Смотрел описание GUICtrlCreateListView а так же GuiCtrlCreateListView и уж само собой DllStructGetData.
Так там нигде не описано что такое "Item". Ну интуитивно понятно название.
Теперь же мне нужно значение значение этого итема. А они у нас не в массиве а $Item1 $Item2 ......
Как теперь выбрать нужный? И кстати каково его мнемоническое название?!
Чуствую что нужно использовать _GUICtrlListView_GetItem но как его увязать в функции ....
Тем более что не могу понять а эти строки зачем?

Код:

     $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $IdFrom = DllStructGetData($tNMHDR, "IdFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

[Creat0R]

Maza Faka,

Пытаюсь получить подстроку i_hate_this_key.zip

Замени \s на реальный пробел, \s подбирает не только пробел

Кстати http:// можно не указывать:

Код:

$string = "Location: http://game.chirkom.uz/download/game/warcraft3/i_hate_this_key.zip [following]" & @CRLF & "Checking..."

$result = StringRegExpReplace($string, "(?s)^.*/(.*) .*$", "\1")

MsgBox(0, "", $result)

NikLok,

нигде не описано что такое "Item"

Это параметр в структуре, ему присваивается значение при создании структуры на событии двойного нажатия по айтему. Есть также в этой структуре ещё параметры:

Код:

$tagNMLISTVIEW = "hwnd hWndFrom;int IDFrom;int Code;int Item;int SubItem;int NewState;int OldState;int Changed;int ActionX;int ActionY;int Param"

К примеру «OldState» возвращает состояние элемента до нажатия на него. ActionX/Y вернёт координаты места нажатия по элементу.

Теперь же мне нужно значение значение этого итема

Код:

ConsoleWrite("Double click on [" & _GUICtrlListView_GetItemText($IdFrom, $iItem) & "] item" & @LF)

не могу понять а эти строки зачем?

$tNMHDR переменная содержит созданную структуру для получения идентификаторов событий и элементов.
$IdFrom идентификатор элемента который вызвал событие (эквивалентно $hListView).
$iCode код события (при двойном клике в списке он ровняется $NM_DBLCLK).

[NikLok]

Creat0R, Maza Faka, Вот еще забыл спросить а строки:

Код:

GUICtrlSendMsg(-1, 0x101E, 0, 150)
GUICtrlSendMsg(-1, 0x101E, 1, 125)

Для чего нужны? И как узнать то когда нужно посылать сообщ а когда нет! И какие именно!??

[Creat0R]

NikLok,

Для чего нужны? И как узнать то когда нужно посылать сообщ а когда нет!

Эти строки для определения ширены колонок. Maza Faka, имо, плохая идея использовать значения вместо констант - при большом объеме кода можно долго сидеть пытаясь понять что же за такое магическое значение

Если использовать GUICtrlSendMsg($hListView, $LVM_SETCOLUMNWIDTH, 0, -1) то колонка (первая, это определяет 0 в третьем параметре) выровняется по максимуму (чтобы были видны все символы в айтемах).

[Maza Faka]

а строки: GUICtrlSendMsg(-1, 0x101E, 0, 150) GUICtrlSendMsg(-1, 0x101E, 1, 125) Для чего нужны? »

Это для указания ширины колонок, аналог функции _GUICtrlListView_SetColumnWidth

И как узнать то когда нужно посылать сообщ а когда нет! И какие именно!?? »

Ты имеешь в виду сообщения Windows? Для элемента ListView это WM_NOTIFY. Для например элемента Button это WM_COMMAND.

Замени \s на реальный пробел, \s подбирает не только пробел »

Вот спасибо, а то замучился совсем Кстати, что означает параметр замены "\1", в справке не нашёл.

имо, плохая идея использовать значения вместо констант »

Знаю и сам никогда так не делаю, просто поторопился