[wolkow70]

wolkow70, сколько раз говорил, код в тег заключать(выделяем код, жмем кнопочку #), противно читать... »

Да знаю я, мне в тегах неудобно читать.

Код:

${If} $8 == ""
 ${OrIf} $8 == "$ClassName"
 ${OrIf} $8 == "Applications\AIMP3.exe"
 ${Else}
 WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\UserChoice" "Progid" "$8"

В том и дело, что тут, наоборот, при восстановлении ассоциаций, параметр реестра должен прописываться, если $8 не равна:
1. "" - пустому значению
2. значению "$ClassName" (текущему значению)
3. значению "Applications\AIMP3.exe" (назначению приложения)
Поэтому и разделил ${Else}. Может как-то по другому можно сформулировать?

[kotkovets]

В том и дело, что тут, наоборот, при восстановлении ассоциаций, параметр реестра должен прописываться, если $8 не равна: »

Код:

${Select} $8
   ${Case3} "" "$ClassName" "Applications\AIMP3.exe"
   ${CaseElse}
        MessageBox MB_OK "$8" IDOK
${EndSelect}

Вот это согласно поставленному условию

[wolkow70]

Из справки:
Здесь макрос ${Case} может срабатывать до пяти значений переменной $0
Имеется в виду в один ${Case} можно включать до пяти значений?
Самих ${Case} может быть множество?
Почему в примере присвоено 3 ${Case3} - потому, что три значения, или любую нумерацию можно поставить?
Обладает ли такая формула преимуществами перед тем, что я написал?

[kotkovets]

Здесь макрос ${Case} может срабатывать до пяти значений переменной $0 Имеется в виду в один ${Case} можно включать до пяти значений? »

до 5 идин Case, правкой хедера можно и больше.. а можно и так:

Код:

----
   ${Case3} "" "$ClassName" "Applications\AIMP3.exe"
   ${Case5} "1" "---" "test" "nsis" "yyy" 
----

Почему в примере присвоено 3 ${Case3} - потому, что три значения, или любую нумерацию можно поставить? »

потому что, 3 значения одной переменной сравниваются.

Обладает ли такая формула преимуществами перед тем, что я написал? »

в каждой из поставленной задач, подбирается путем проб оптимальное и простое решение,
данный макрос удобнее применять, когда сравнивается множество значений одной выбранной переменной.

[wolkow70]

kotkovets,

При совместном применении в макросе ${Select} и ${Switch} ${extenstion} скрипт не компилируется.

Код:

!macro RegisterExtension extenstion
Push $1
Push $2		
StrCpy $ClassName "AIMP.${extenstion}"
;
ReadRegStr $1 HKCU "Software\Classes\.${extenstion}" ""
${Select} $1
${Case2} "" "$ClassName"
${CaseElse}
WriteRegStr HKCU "Software\Classes\.${extenstion}" "AIMP.Backup" "$1" 
${EndSelect}
;
WriteRegStr HKCU "Software\Classes\.${extenstion}" "" "$ClassName"
WriteRegStr HKCU "Software\Classes\$ClassName\shell\open\command" "" "$OpenCommand"
WriteRegStr HKCU "Software\Classes\$ClassName\shell\open\DropTarget" "CLSID" "{0041494D-5033-4472-6F70-546172676574}"
WriteRegStr HKCU "Software\Classes\$ClassName\CLSID" "" "{0041494D-5033-4472-6F70-546172676574}"
;
DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "Progid"
DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}" "Application"
WriteRegBin HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\OpenWithProgids" "$ClassName" ""
;
${If} ${AtLeastWinVista}
ReadRegStr $2 HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\UserChoice" "Progid"
DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\UserChoice"
WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\UserChoice" "Progid" "$ClassName"
${Select} $2
${Case2} "" "$ClassName"
${CaseElse}
WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\UserChoice" "AIMP.Backup" "$2"
${EndIf}
; 
${Switch} ${extenstion}	
${Case} "AAC"
StrCpy $IconIndex 0
WriteRegStr HKCU "Software\Classes\$ClassName" "" "AIMP3: Advanced Audio Codec"
${Break} 

${EndSwitch}
WriteRegStr HKCU "Software\Classes\$ClassName\DefaultIcon" "" "$IconFile,$IconIndex"	
 Pop $2
 Pop $1
!macroend

[kotkovets]

${Select} $2 ${Case2} "" "$ClassName" ${CaseElse} »

не закрыт этот макрос перед ${EndIf}, читайте до дыр предыдущее мое сообщение

[wolkow70]

не закрыт этот макрос »

Подправил. Все работает отлично. Сборку обновил.

[wolkow70]

kotkovets,

Использую ваш хедер "RegistryFunc.nsh" , но не могу в нем найти функцию определения пустого ключа.

Станадартная функция из справки
DeleteRegKey /ifempty HKLM "Software\A key that might have subkeys"
несколько раз подводила.

Еще вот нашел такое:

Код:

ClearErrors
EnumRegValue $R0 HKLM "${RegistryKey}" 0
IfErrors +1 +2
DetailPrint "(Registry Key Error: ${RegistryKey})" ; Put your error handling here.
StrCmp $R0 "" +1 +3
DeleteRegKey HKLM "${RegistryKey}" ; This will delete the key if there are no more values...
DetailPrint "Removing Registry Key: ${RegistryKey}"
  ;;Continue your stuff here.

Подскажите как лучше реализовать проверку ключа, и если он пуст, то удалить.
Интересует и возможная логическая конструкция для такого случая.

Пока сам сделал так, но думаю не идеальный вариант...

Код:

ReadRegStr $6 HKCU "Software\Classes\.${extenstion}" ""
${If} $6 == ""
DeleteRegKey HKCU "Software\Classes\.${extenstion}" ""
${EndIf}

[kotkovets]

Пока сам сделал так, но думаю не идеальный вариант... »

это бред, удалять пустой параметр ключа по умолчанию, здесь удаление ключа раздела(подраздела),
если он пуст и нет параметров.

Если прочитать данные невозможно, то в переменную user_var будет записано пустое значение - будет установлен флаг ошибки.

то можно и так, для ключа по умолчанию, если он пуст:

Код:

ClearErrors
ReadRegStr $6 HKCU "Software\Classes\.${extenstion}" ""
${If} ${Errors}
   MessageBox MB_OK "ключ пуст"
${Else}
   MessageBox MB_OK "$6"
${EndIf}

[wolkow70]

kotkovets,
Я так понимаю, что такая конструкция проверит и удалит ключ если он не содержит вообще никаких параметров.

Код:

${If} ${KeyExists} "${HKCU}\Software\Classes\.${extenstion}"
ClearErrors
EnumRegValue $3 HKCU "Software\Classes\.${extenstion}" 0
IfErrors +1 +2
DetailPrint "Ключ не содержит параметров: HKCU Software\Classes\.${extenstion}"
StrCmp $3 "" +1 +3
DeleteRegKey HKCU "Software\Classes\.${extenstion}" ""
DetailPrint "Удаление пустого ключа реестра: HKCU Software\Classes\.${extenstion}"
${EndIf}

http://nsis.sourceforge.net/How_to_d..._has_no_values

А такая конструкция удалит ключ, если нет параметра по умолчанию

Код:

ClearErrors
ReadRegStr $3 HKCU "Software\Classes\.${extenstion}" ""
${If} ${Errors}
DeleteRegKey HKCU "Software\Classes\.${extenstion}" ""
${EndIf}

Или я чего-то не понял?