[K.A.V.]

динозавра, я, конечно, могу ошибаться, т.к. пару лет кодинга вообще не касался, но начиная читать код сразу меня остановил вот этот кусок:

Код:

${If} ${RunningX64}
   SetRegView 64
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\WOW6432Node\Adobe\Adobe Acrobat\DC\Activation" "IsAMTEnforced" 0x1
${Else}
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Adobe\Adobe Acrobat\DC\Activation" "IsAMTEnforced" 0x1
${EndIf}

А зачем вам команда SetRegView, если вы принудительно ветку прописываете? Могу скромно посоветовать сразу приучаться писать "логичный код", когда будут у вас скрипты большие, потом придётся переучиваться/переписывать и копаться в лишних строках.
SetRegView как раз нужна для того, чтобы скрипт сам определял, в какую ветку будет записывать данные, таким образом можно избавиться от лишних строк в коде.

либо так (без SetRegView):

Код:

${If} ${RunningX64}
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\WOW6432Node\Adobe\Adobe Acrobat\DC\Activation" "IsAMTEnforced" 0x1
${Else}
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Adobe\Adobe Acrobat\DC\Activation" "IsAMTEnforced" 0x1
${EndIf}

либо так:

Код:

${If} ${RunningX64}
SetRegView 32 ; переключаем на запись в WOW6432Node раздел
${EndIf}
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Adobe\Adobe Acrobat\DC\Activation" "IsAMTEnforced" 0x1

Но в последнем случае, вам придётся постоянно мучать команду SetRegView, если хотите постоянно писать в разные разделы "на автомате", тут уже смотря от проекта
Вообще, если нет надобности постоянно писать в разные разделы, то лучше бы при запуске определиться с командой SetRegView...Так вы сами себя избавите в дальнейшем как минимум от лишних конструкций с ${If}

[динозавра]

iglezz, По самому коду

Моей благодарности нету границ. Буду опробывать..... Но, ведь тогда не было вас, чтобы мне помочь http://forum.oszone.net/post-2857985-2254.html , и, если вы прочтете все дальнейшие решения начиная с сообщения 2254 , то они свелись к ссылке на "чужой" сайт, чем я воспользовался и оттуда взял примеры.

K.A.V., но начиная читать код сразу меня остановил вот этот кусок

Огромное спасибо за дополнительные решения.
Я тогда (очень давно) строго воспользовался вашей инструкцией и не отступал ни на децл http://forum.oszone.net/post-2541218-1741.html и дальнейшее после сообщения 1740

[f0r_ce]

Исходные данные: дан список

string1
string2
string3
string4

Как выбрать из этого списка рандомно, одну из строк и записать в переменную?

StrCry "$1" string?

[K.A.V.]

f0r_ce, какой ответ вы хотите получить с таким вопросом?

Исходные данные: дан список string1 string2 string3 string4 »

Откуда список? В каком он в формате? Список в элементе управления (List/TreeView, Combobox и т.д.) или в текстовом файле?

[f0r_ce]

K.A.V., список там же в скрипте

StrCry $1 string1
StrCry $2 string2
StrCry $3 string3
StrCry $4 string4

Далее выбор рандомно одну из них и заносим в переменную

StrCry "$5" string(?)

[iglezz]

f0r_ce,
NsRandom, StdUtils

[f0r_ce]

iglezz, StdUtils работает только с числами, строки не рандомит, NsRandom тоже.

[iglezz]

f0r_ce, Понятное дело, самое интересное - получить строку относительно её номера.

Например так

Код грязноват ибо не заботится о перезаписи переменных

Код:

Name "RandomStringTest"
OutFile "RandomStringTest.exe"
ShowInstDetails show
AutoCloseWindow false
RequestExecutionLevel user
Page instfiles

Section ""
	StrCpy $0 string0
	StrCpy $1 string1
	StrCpy $2 string2
	StrCpy $3 string3
	
	DetailPrint "input 0 = $0"
	DetailPrint "input 1 = $1"
	DetailPrint "input 2 = $2"
	DetailPrint "input 3 = $3"
	
	Push $0
	Push $1
	Push $2
	Push $3

	Push 4 ; (число строк)
	nsRandom::GetRandom
	Pop $R0 ; random 0 <= N < 4)
	
	DetailPrint "random = $R0"
	
	StrCpy $R1 3
	
	loop:
	IntCmp $R1 0 0 exitloop 0
	IntCmp $R0 $R1 0 +2 +2
		Exch $5
	Pop $4
	IntOp $R1 $R1 - 1
	Goto loop
	exitloop:
	
	DetailPrint "result = $5"
	DetailPrint " "
	
SectionEnd

Более корректный вариант, оформлен как функция:

Скрытый текст

Код:

Name "RandomStringTesFunc"
OutFile "RandomStringTesFunc.exe"
ShowInstDetails show
AutoCloseWindow false
RequestExecutionLevel user
Page instfiles

Section ""
	StrCpy $R0 0
	LoopS:
		Push string1
		Push string2
		Push string3
		Push string4
		Push string5
		Push 5
		Call GetRandomString
		Pop $0
		
		DetailPrint "result = $0"
		
		IntOp $R0 $R0 + 1
		InTCmp $R0 20 +2 0
		Goto LoopS
SectionEnd


Function GetRandomString
	Exch $0 ; stack size input for nsRandom::GetRandom
	Push $1 ; stack size, counts from zero
	Push $2 ; temp
	Push $3 ; output string
	
	IntOp $1 $0 - 1
	
	Push $0
	nsRandom::GetRandom
	Pop $0 ; get random (0 <= $0 <= $1)
	
	loop:
		IntCmp $1 0 0 exitloop 0
		Exch 4
		IntCmp $0 $1 0 +3 +3
			Pop $3
			Goto +2
		Pop $2
		Exch
		Exch 2
		Exch 3
		IntOp $1 $1 - 1
		Goto loop
	exitloop:
	
	Exch 3
	Pop $0
	Pop $2
	Pop $1
	Exch $3
FunctionEnd

[MKN]

Можно ещё проще генерить рандомное число номера переменной в коде:
Пример - до 20 :

Код:

OutFile RandomTest.exe

Function Random
Exch $0
Push $1
System::Call 'kernel32::QueryPerformanceCounter(*l.r1)'
System::Int64Op $1 % $0
Pop $0
Pop $1
Exch $0
FunctionEnd

Section
Push 20
call Random
Pop $0
MessageBox MB_OK "Random $0"
SectionEnd

[iglezz]

AlekseyPopovv,

Код:

${GetOptions} "$CMDLINE" "/U=" $R0
${If} $R0 == 1

Заменить на

Код:

${GetOptions} "$CMDLINE" "/U" $R0
${IfNot} ${Errors}